Personal tools
Document Actions

odra.15 trains

by Paul McJones last modified 2019-05-20 16:52

Interactive Railway Guide by S. SZPAKOWICZ, M. SWIDZINSKI.

<* * * * * * * * * * * * * * * * * * * * * * *
* * * * * * * * * * * * * * * * * * * * * * *
*                                           *
* KONWERSACYJNY SYSTEM INFORMACJI KOLEJOWEJ *
*                                           *
* AUTORZY:                                  *
* S SZPAKOWICZ, M SWIDZINSKI                *
* OPIS W PRACACH:                           *
* SZPAKOWICZ S, SWIDZINSKI M : PROGRAMOWANIE*
* W PROLOGU - INFORMATOR KOLEJOWY^          *
* INFORMATYKA NO 12,1979^                   *
* SZPAKOWICZ S ,SWIDZINSKI M : A SIMPLE     *
* DIALOGUE IN POLISH^ INTERACTIVE RAILWAY   *
* GUIDE, POCITACE A UMELA INTELIGENCIA,     *
* VOL  1(1982) NO 5, TAKZE W: J S BIEN(ED ) *
* PAPERS IN COMPUTATIONAL LINGUISTICS II,   *
* SPRAWOZDANIA IINF UW NR 110^              *
*                                           *
* * * * * * * * * * * * * * * * * * * * * * *
* * * * * * * * * * * * * * * * * * * * * * *.


* * * * * * * * * * * * * * * * * * * * * * * * * * *
* DEKLARACJE OPERATOROW I PODPROGRAMOW POMOCNICZYCH *
* * * * * * * * * * * * * * * * * * * * * * * * * * *.

-AJOP(".",1,"X'(X'X)")!
-AJOP("&",2,"X'(X'X)")!

+ALT(*1,*1.*2).
+ALT(*1,*2.*3) -/ -ALT(*1,*3).
+ALT(*1,*1).

+FIX(*W1,*W2,*W1&*W2) -INF(*W1,*W2)  .
+FIX(*W1,*W2,*W2&*W1) -INF(*W2,*W1)  .
+FIX(*W,*W,*W) .
+COMMA(",").
+QMARK("?").
+PERIOD(".").

+PYSZ(*X) -LIGNE -SORM("******   ") -SORM(*X) -SORM("   ******") -LIGNE .

* * * * * * * * * * * * * * * * * * * * * * * *
* WCZYTYWANIE TEKSTU DO KROPKI LUB PYTAJNIKA^ *
* ZNAKI PRZESTANKOWE OTACZAC SPACJAMI         *
* * * * * * * * * * * * * * * * * * * * * * * *.

+WORDS(*WORDS) -WORD(*WORD) -WORDS(*WORD,*WORDS) -/.

+WORDS(".",".".NIL)  .
+WORDS("?","?".NIL)  .
+WORDS(*HOUR,H(*HH,*MM).*REST)
   -HOUR(*HOUR,*HH,*MM)
   -WORD(*NEXT) -WORDS(*NEXT,*REST) .
+WORDS(*WORD,*WORD.*REST)
   -WORD(*NEXT) -WORDS(*NEXT,*REST) .

+WORD(*WORD) -LUB(*FIRST) -WORD(*FIRST,*WORD)-/.

+WORD(*BLANK,NIL) -BLANC(*BLANK) .
+WORD(*CHAR,*CHAR.*REST) -LU(*NEXT) -WORD(*NEXT,*REST) .

+HOUR(*H.*POINT.*MINUTES,*HH,*MM)
   -POINT(*POINT)  -HOUR(0.*H.*POINT.*MINUTES,*HH,*MM).
+HOUR(*H1.*H2.*POINT.*MINUTES,*HH,*MM)
   -POINT(*POINT)
   -UNIV(*HH,(*H1.*H2.NIL).NIL) -UNIV(*MM,*MINUTES.NIL) .

* DRUKOWANIE TEKSTU.
+WRITE(H(*HH,*MM).*REST)
   -/ -SORT(H(*HH,*MM)) -SORM(" ") -WRITE(*REST) .
+WRITE(*WORD.*REST)
   -/ -SORM(*WORD) -SORM(" ") -WRITE(*REST) .
+WRITE(NIL) .

-NETT!

* * * * * * * * * * * * * * * * * * *
*                                   *
* PODPROGRAM STERUJACY KONWERSACJA  *
*                                   *
* * * * * * * * * * * * * * * * * * *.

+INFORMACJA
     -INFO(NO,*PLEC).
+INFO(*DAN,*PLEC)
     -ZACZNIJ(*DAN) -/  -WORDS(*PYTANIE)  -PRZETWORZ(*PYTANIE,*PLEC).

+ZACZNIJ(PS) .
+ZACZNIJ(NO)       -PYSZ("CZYM MOGE SLUZYC?") .
+ZACZNIJ(ST) -PYSZ("CZYM JESZCZE MOGE SLUZYC?").

+PRZETWORZ(*PYTANIE,*PLEC)
     -SYNTAXE(KWERENDA(*STRUKTURA,*PLEC).NIL,*PYTANIE)
     -/  -REAKCJA(*STRUKTURA,*PLEC) .
+PRZETWORZ(*PYTANIE,*PLEC)
     -LIGNE -PYSZ("NIE ROZUMIEM, PROSZE ZAPYTAC JESZCZE RAZ.") -INFO(PS,*PLEC) .

+REAKCJA(CHWATIT,*PLEC)
     -PYSZ("PROSZE O NAS NIE ZAPOMINAC.") -/ .
+REAKCJA(Q(*W,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*M)  +VAR(*K)  +VAR(*W)  -ZGODA(*G,*P) -/
     -OBROBKA(Q(*W,*M,*K,*D,*G,*P,*T),*PLEC).
+REAKCJA(Q(*W,*M,*K,*D,*G,*P,*T),*PLEC)
     -PYSZ("PROSZE ZAPYTAC PONOWNIE,")
     -PYSZ("PODAJAC CEL I/LUB KIERUNEK PODROZY I/LUB WLASCIWA PORE.")
     -INFO(PS,*PLEC).

* UZGODNIENIE PORY I GODZINY.

+ZGODA(*G,*P)  -VAR(*G) .
+ZGODA(*G,*P)  -DOPAS(*G,*P).

+DOPAS(H(*GG,*MM),*P)
     -ALT(*P,RANO.RANNY.PORANNY.PRZEDPOLUDNIOWY.PRZED)
     -INF(*GG,12)  -INF(4,*GG) .
+DOPAS(H(*GG,*MM),*P)
     -ALT(*P,POPOLUDNIOWY.PO)  -INF(*GG,18)  -INF(11,*GG) .
+DOPAS(H(*GG,*MM),*P)
     -ALT(*P,WIECZOR.WIECZORNY)  -INF(*GG,23)  -INF(17,*GG)  .
+DOPAS(H(*GG,*MM),*P)
     -ALT(*P,NOC.NOCNY)  -INF(*GG,24)  -INF(18,*GG) .
+DOPAS(H(*GG,*MM),*P)
     -ALT(*P,NOC.NOCNY)  -INF(*GG,5)  .
+DOPAS(H(*GG,*MM),*P)
     -ALT(*P,DZIEN.DZIENNY)  -INF(*GG,16)  -INF(4,*GG) .

* PRZELACZNIK - WYBOR JEDNEGO Z PODPROGRAMOW PRZYGOTOWANIA ODPOWIEDZI.

+OBROBKA(Q(G,*M,*K,*D,*G,*P,*T),*PLEC)
     -VAR(*G) -/  -OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBROBKA(Q(D,*M,*K,*D,*G,*P,*T),*PLEC)
     -VAR(*D) -/  -OBRD(Q(D,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBROBKA(Q(T,*M,*K,*D,*G,*P,*T),*PLEC)
     -VAR(*T) -/  -OBRT(Q(T,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBROBKA(Q(*W,*M,*K,*D,*G,*P,*T),*PLEC) -ALT(*W,P . G&P)
     -VAR(*P)  -VAR(*G)  -/  -OBRP(Q(P,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBROBKA(Q(D&*W2,*M,*K,*D,*G,*P,*T),*PLEC)
   -VAR(*D) -/ -OBROBKA(Q(*W2,*M,*K,OBOJETNE,*G,*P,*T),*PLEC) .
+OBROBKA(Q(*W1&T,*M,*K,*D,*G,*P,*T),*PLEC)
   -VAR(*T) -/ -OBROBKA(Q(*W1,*M,*K,*D,*G,*P,OBOJETNE),*PLEC) .
+OBROBKA(Q(*W,*M,*K,*D,*G,*P,*T),*PLEC)
     -PYSZ("PYTANIE ZAWIERA ODPOWIEDZ.") -INFO(ST,*PLEC) .

-NETT!
* * * * * * * * * * * * *
* PO PYTANIU O GODZINE  *
* * * * * * * * * * * * *.

+OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*D)  +VAR(*P)  +VAR(*T)  -/
     -ODPOWIEDZ(Q(G,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*D)  +VAR(*P)  -/  -DOPYT(T,*T,*PLEC)
     -ODPOWIEDZ(Q(G,*M,*K,*D,*G,*P,*T),*PLEC).
+OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*D)  +VAR(*T)  -/  -DOPYT(P.*K,*P,*PLEC)
     -ODPOWIEDZ(Q(G,*M,*K,*D,*G,*P,*T),*PLEC).
+OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*D)            -/  -DOPYT(T,*T,*PLEC)
     -OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*P)  +VAR(*T)  -/  -DOPYT(D.*K,*D,*PLEC)
     -ODPOWIEDZ(Q(G,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC)
     -DOPYT(D.*K,*D,*PLEC)
     -OBRG(Q(G,*M,*K,*D,*G,*P,*T),*PLEC) .

* * * * * * * * * * * * * *
* PO PYTANIU O PORE DNIA  *
* * * * * * * * * * * * * *.

+OBRP(Q(P,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*D)  +VAR(*T)  -/
     -ODPOWIEDZ(Q(P,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRP(Q(P,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*D)  -/  -DOPYT(T,*T,*PLEC)
     -ODPOWIEDZ(Q(P,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRP(Q(P,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*T)  -/  -DOPYT(D.*K,*D,*PLEC)
     -ODPOWIEDZ(Q(P,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRP(Q(P,*M,*K,*D,*G,*P,*T),*PLEC)
     -DOPYT(D.*K,*D,*PLEC)
     -OBRP(Q(P,*M,*K,*D,*G,*P,*T),*PLEC).

* * * * * * * * * * * * *
* PO PYTANIU O DWORZEC  *
* * * * * * * * * * * * *.

+OBRD(Q(D,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*G)  +VAR(*T)  -/
     -ODPOWIEDZ(Q(D,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRD(Q(D,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*G)  -/  -DOPYT(T,*T,*PLEC)
     -ODPOWIEDZ(Q(D,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRD(Q(D,*M,*K,*D,*G,*P,*T),PLEC)
     +VAR(*T) -/  -DOPYT(G,*G,*PLEC)
     -ODPOWIEDZ(Q(D,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRD(Q(D,*M,*K,*D,*G,*P,*T),*PLEC)
     -DOPYT(G,*G,*PLEC)
     -OBRD(Q(D,*M,*K,*D,*G,*P,*T),*PLEC).

* * * * * * * * * * * * * * *
* PO PYTANIU O TYP POCIAGU  *
* * * * * * * * * * * * * * *.

+OBRT(Q(T,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*G)  +VAR(*D)  -/
     -ODPOWIEDZ(Q(T,*M,*K,*D,*G,*P,*T),*PLEC).
+OBRT(Q(T,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*G)  -/  -DOPYT(D.*K,*D,*PLEC)
     -ODPOWIEDZ(Q(T,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRT(Q(T,*M,*K,*D,*G,*P,*T),*PLEC)
     +VAR(*D)  -/  -DOPYT(G,*G,*PLEC)
     -ODPOWIEDZ(Q(T,*M,*K,*D,*G,*P,*T),*PLEC) .
+OBRT(Q(T,*M,*K,*D,*G,*P,*T),*PLEC)
     -DOPYT(G,*G,*PLEC)
     -OBRT(Q(T,*M,*K,*D,*G,*P,*T),*PLEC) .

-NETT!

* UZYSKANIE OD KLIENTA PEWNYCH BRAKUJACYCH INFORMACJI^
  GRAMATYKI OPISUJACE DIALOG - PONIZEJ.

+DOPYT(*W,*INFO,*PLEC) -USTAL(*PLEC,*SEKS) -WYPYT(*W,*SEKS)
   -DOPYTAJ(*W,*INFO,*PLEC) -/ .

+USTAL(*PLEC,NEUTR)  -VAR(*PLEC) .
+USTAL(*L.*R,NEUTR) -VAR(*R)  .
+USTAL(*PLEC,*PLEC) .

+WYPYT(*X,*Y) -SYNTAXE(WYPYT(*X,*Y).NIL,*TXT)  -LIGNE -SORM("******   ")
   -WRITE(*TXT) -SORM("   ******") -LIGNE .
+WYPYT(*X,*Y) -PYSZ("??? BLAD W SYNTEZIE WYPYTU ???") -/(-(INFORMACJA))-IMPASSE.

+DOPYTAJ(*W,*INFO,*PLEC)
   -WORDS(*ODP) -SYNTAXE(DOPZN(*W,*INFO,*PLEC).NIL,*ODP) +VAR(*INFO)
   -ZBADAJ(*W,*INFO,*PLEC)  .
+DOPYTAJ(*W,*INFO,*PLEC)
   -PYSZ("PROSZE ZMIENIC SWOJA ODPOWIEDZ.") -DOPYTAJ(*W,*INFO,*PLEC) .

+ZBADAJ(*W,KONCOWKA,*PLEC)
   -PYSZ("??? DOPYT=KONCOWKA ???") -/(-(INFORMACJA)) -IMPASSE .
+ZBADAJ(*W,*INFO,*PLEC) .


* PRZEJRZENIE ROZKLADU JAZDY I ODPOWIEDZ.

+ODPOWIEDZ(Q(*W,*M,*K,*D,*G,*P,*T),*PLEC)
   -KIER(*K,*KK) -DGPT(*D,*DD) -DGPT(*G,*GG) -DGPT(*P,*PP) -DGPT(*T,*TT)
   -LIGNE -ZNAJDZ(*M,*KK,*DD,*GG,*PP,*TT) .
+ODPOWIEDZ(Q(*W,*M,*K,*D,*G,*P,*T),*PLEC)
   -DEFAJKA -INFO(ST,*PLEC) .

+KIER(KZ,Z) -/.
+KIER(KD,DO).

+DGPT(*X,*X) -VAR(*X) -/ .
+DGPT(OBOJETNE,*X) -/ .
+DGPT(EKSPRESOWY,EKSPRES) -/ .
+DGPT(*X,*X) .

+FAJKA -JEST -/ .
+FAJKA -AJOUT(+(JEST).NIL) .
+DEFAJKA -JEST -/ -SUPP(+(JEST).NIL) .
+DEFAJKA -PYSZ("NIE MA TAKIEGO POCIAGU.") .

+ZNAJDZ(*M,*K,*D,H(*GG,*MM),*P,*T)
     -R(*T,*K,*M,*GG.*MM,*D)  -DOPAS(H(*GG,*MM),*P) -FAJKA
     -ODP(*T,*K,*M,*GG.*MM,*P,*D)  -IMPASSE .
+ODP(*T,*K,*M,*GG.*MM,*P,*D)
   -SORM("******   ") -SORT(*T) -SORM(" ") -SORT(*K) -SORM(" ") -SORT(*M)
   -SORM(" O ") -SORT(*GG.*MM) -SORM(" ") -FINIS(*K,*D) -SORM("   ******")
   -LIGNE .
+FINIS(DO,*D)
     -SORM(" Z DWORCA ")  -S(*F,PRZYM,DOP.POJ.MES,D,*D)  -SORM(*F) -/.
+FINIS(Z,*D)
     -SORM(" NA DWORZEC ") -SORT(*D) .


-NETT!

* * * * * * * * * * * * * * * * * *
* * * * * * * * * * * * * * * * * *
*                                 *
* SKLADNIA WYPOWIEDZI UZYTKOWNIKA *
*                                 *
* * * * * * * * * * * * * * * * * *
* * * * * * * * * * * * * * * * * *.

%KWERENDA(CHWATIT,*PLEC) == %KONCOWKA(*PLEC) .
%KWERENDA(*STRUKT,*PLEC) == %INTRODUKCJA(*PLEC) %KOMA %PYTANIE(*STRUKT)  .
%KWERENDA(*STRUKT,*PLEC) == %PYTANIE(*STRUKT) .

%KONCOWKA(*L.*R) == %CZAS(*F, 1OS.*L.*R,KONC,DZIEKOWAC) %ZNAK.

%KOMA == #*C  -COMMA(*C).
%KOMA == %PUSTE .
%PUSTE == .


* INTRODUKCJA.

%INTRODUKCJA(*PLEC) == %PART("CZY",-,-,CZY)
                       %MOZE(*PLEC) %OBIEKT .
%INTRODUKCJA(*PLEC) == %PART("CZY",-,-,CZY)
                       %MOZE(*PLEC)  %CZAS(*F,BEZOK,PR,*IR) %INFOR(*PLEC).
%INTRODUKCJA(*PLEC) == %MODAL(*PLEC) %OBIEKT .
%INTRODUKCJA(*PLEC) == %MODAL(*PLEC)  %CZAS(*F,BEZOK,PR,*IR) %INFOR(*PLEC).
%INTRODUKCJA(*PLEC) == %PROSZ(*PLEC) %INFOR(*PLEC).

%MOZE(*LICZ.*RODZ) == %CZAS(*F,1OS.*LICZ.*RODZ,-,MOC).
%PROSZ(*LICZ.*RODZ) == %CZAS(*F,1OS.*LICZ.*RODZ,PR,*IR).
%MODAL(*LICZ.*RODZ) == %CZAS(*F,1OS.*LICZ.*RODZ,-,CHCIEC).
%OBIEKT == %CZAS(*F1,BEZOK,INF,*IR1) %RZECZ(*F2,BIER.*LICZ.*RODZ,INF,*IR2).
%OBIEKT == %CZAS(*F,BEZOK,*SEM,*IR) -ALT(*SEM,DOW.PYT)
           %ZAIMZWROT("SIE",-,-,SIE).
%OBIEKT == %ZAIMZWROT("SIE",-,-,SIE)
           %CZAS(*F,BEZOK,*SEM,*IR)  -ALT(*SEM,DOW.PYT).
%OBIEKT == %CZAS(*F,BEZOK,*SEM,*IR) -ALT(*SEM,PYT.WIE).
%INFOR(*LICZ.*RODZ) == %PRZIM("O",BIER,-,O)
                       %RZECZ("POINFORMOWANIE",BIER.POJ.NIJ,I,POINFORMOWANIE)
                       %ZAIM(*F,DOP.*LICZ.*RODZ,-,*IR) .
%INFOR(*LICZ.*RODZ) ==%PRZIM("O",BIER,-,O)
                       %RZECZ(*F,BIER.POJ.ZEN,*SEM,*IR) -ALT(*SEM,INF.I).

%ZYCZNIK(*PLEC) == %MODAL(*PLEC) %CZAS(*F,BEZOK,*SEM,*IR) -ALT(*SEM,KD.KZ).
%POMOC(*LICZ1.*RODZ1,*LICZ2.*RODZ2) ==
                         %CZAS(*F1,3OS.*LICZ1.*RODZ1,-,INTERESOWAC)
                         %ZAIM(*F2,BIER.*LICZ2.*RODZ2,-,*IR).
%CHODZI(BIER,*LICZ.*RODZ) == %CZAS("CHODZI",3OS.POJ.NIJ,-,CHODZIC)
                             %ZAIM(*F,CEL.*LICZ.*RODZ,-,*IR)
                             %PRZIM("O",BIER,-,O).
%CHODZI(BIER,*LICZ.*RODZ) == %CZAS("CHODZI",3OS.POJ.NIJ,-,CHODZIC)
                             %PRZIM("O",BIER,-,O).

-NETT!

* PYTANIE.

%PYTANIE(Q(*W,*M,*K,*D,*G,*P,*T)) == %PYTACZ(*W)%ZDANIE(*M,*K,*D,*G,*P,*T)%ZNAK.
%ZNAK == #*Z  -PERIOD(*Z).
%ZNAK == #*Z  -QMARK(*Z).

* PYTAJNIK - USTALENIE WATKU.

%PYTACZ(*W) == %PYTAJNIK(*W1) %SPOJNIK("I",-,-,I) %PYTAJNIK(*W2)
                -FIX(*W1,*W2,*W) .
%PYTACZ(*W) == %PYTAJNIK(*W).

%PYTAJNIK(G) ==%ZPRZYS("KIEDY",-,G,KIEDY) .
%PYTAJNIK(G) == %PRZIM("O",MIEJ,-,O) %ZAIMPYT(*F1,MIEJ.*LICZ.ZEN,-,*IREF)
               %RZECZ(*F2,MIEJ.*LICZ.ZEN,G,GODZINA) .
%PYTAJNIK(G) == %PRZIM("O",MIEJ,-,O)%ZAIMPYT("KTOREJ",MIEJ.POJ.ZEN,-,KTORY).
%PYTAJNIK(D) == %ZPRZYS(*F,-,D,*IREF) -ALT(*IREF,GDZIE.SKAD.DOKAD) .
%PYTAJNIK(D) == %PRZIM(*F1,*PRZYP,*K,*IR1) -ALT(*K&*IR1,KZ&NA . KD&Z)
        %ZAIMPYT(*F2,*PRZYP.*LI.*RODZ,-,*IREF2)
          %RZECZ(*F3,*PRZYP.*LI.*RODZ,D,*IREF3).
%PYTAJNIK(T) == %ZAIMPYT(*F,MIAN.*LICZ.MES,-,JAKI) .
%PYTAJNIK(P) == %PRZIM("O",MIEJ,-,O) %ZAIMPYT(*F1,*PRZYP.*LICZ.*RODZ,-,JAKI)
   %RZECZ(*F2,*PRZYP.*LICZ.*RODZ,P,PORA).

* ZASADNICZA CZESC WYPOWIEDZI - ZDANIE.

%ZDANIE(*M,*K,*D,*G,*P,*T) == %CZAS(*F,*OS.*KTF,*K,*IR)
                              %GGODZ(*PRZYP1,*G)
                              %GPOR(*KATEG ,*P)
                              %KONIEC(*PRZYP.*KTF,*M,*K,*D,*P,*T).
%ZDANIE(*M,*K,*D,*G,*P,*T) == %GPOC(*PRZYP.*KTF,*P,*T)
                              %SRODEK(*KTF,*M,*K,*D)
                              %GGODZ(*PRZYP1,*G)
                              %GPOR(*KATEG ,*P).

%KONIEC(*KAT,*M,*K,*D,*P,*T) == %GPOC(*KAT,*P,*T)
                                %GMIAS(*M,*K)
                                %GDWOR(*K,*D) .
%KONIEC(*KAT,*M,*K,*D,*P,*T) == %GMIAS(*M,*K)
                                %GPOC(*KAT,*P,*T)
                                %GDWOR(*K,*D) .
%KONIEC(*KAT,*M,*K,*D,*P,*T) == %GDWOR(*K,*D)
                                %GPOC(*KAT,*P,*T)
                                %GMIAS(*M,*K).
%SRODEK(*KTF,*M,*K,*D) == %CZAS(*F,*OS.*KTF,*K,*IR)
                          %GDWOR(*K,*D)
                          %GMIAS(*M,*K) .
%SRODEK(*KTF,*M,*K,*D) == %CZAS(*F,*OS.*KTF,*K,*IR)
                          %GMIAS(*M,*K)
                          %GDWOR(*K,*D).
%SRODEK(*KTF,*M,*K,*D) == %GMIAS(*M,*K)
                          %CZAS(*F,*OS.*KTF,*K,*IR)
                          %GDWOR(*K,*D).


* DEFINICJE GRUP "RZECZOWNIKOWYCH".

* USTALENIE PORY DNIA I/LUB TYPU POCIAGU.

%GPOC(*KAT,*IR1,*IR2) ==
      %POR(*KAT,*IR1)
     %POC(*KAT,*IR)
      %TYP(*KAT,*IR2)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %TYP(*KAT,*IR2)
     %POC(*KAT,*IR)
      %POR(*KAT,*IR1)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %POR(*KAT,*IR1)
      %POC(*KAT,*IR)  .
%GPOC(*KAT,*IR1,*IR2) ==
     %POC(*KAT,*IR)
      %POR(*KAT,*IR1)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %TYP(*KAT,*IR2)
      %POC(*KAT,*IR)  .
%GPOC(*KAT,*IR1,*IR2) ==
     %POC(*KAT,*IR)
      %TYP(*KAT,*IR2)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %POR(*KAT,*IR1)
      %TYP(*KAT,*IR2)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %TYP(*KAT,*IR2)
      %POR(*KAT,*IR1)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %POC(*KAT,*IR)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %POR(*KAT,*IR1)
      %EKS(*KAT,*IR2)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %EKS(*KAT,*IR2)
      %POR(*KAT,*IR1)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %EKS(*KAT,*IR2)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %POR(*KAT,*IR1)  .
%GPOC(*KAT,*IR1,*IR2) ==
      %TYP(*KAT,*IR2) .

%POC(*KAT,POCIAG) == %RZECZ(*F,*KAT,PO,POCIAG).
%EKS(*KAT,EKSPRES) == %RZECZ(*F,*KAT,T,EKSPRES).
%POR(*KAT,*IR) == %PRZYM(*F,*KAT,P,*IR).
%TYP(*KAT,*IR) == %PRZYM(*F,*KAT,T,*IR).

-NETT!

* USTALENIE GODZINY.

%GGODZ(*PRZYP,*G) == %PRZIM("O",*PRZYP,-,O) %GGODZI(*PRZYP,*G) .
%GGODZ(*PRZYP,*G) == %PUSTE.
%GGODZI(*PRZYP,*G) == %RZECZ(*F,*PRZYP.POJ.ZEN,G,GODZINA) %LICZBA(*G) .
%GGODZI(*PRZYP,*G) == %LICZBA(*G).

* USTALENIE PORY DNIA.

%GPOR(*KATEG,*IR) == %PRZYS(*F,-,P,*IR) .
%GPOR(*PRZYP.POJ.NIJ,*IR) == %PRZIM(*F1,*PRZYP,P,*IR) -ALT(*IR,PRZED.PO)
                             %RZECZ(*F2,*PRZYP.POJ.NIJ,P,POLUDNIE) .
%GPOR(*PRZYP.*KATE,*P) == %PRZIM(*F,*PRZYP,P,*IR) %GPORA(*PRZYP.*KATE,*P) .
%GPOR(*PRZYP.POJ.*RODZ,*IR) == %PRZIM(*F1,*PRZYP,P,*IR1)
                        %RZECZ(*F2,*PRZYP.POJ.*RODZ,P,*IR) .
%GPOR(*KATEG,*P) == %PUSTE.
%GPORA(*PRZYP.*LICZ.*RODZ,*IR)== %RZECZ(*F,*PRZYP.*LICZ.*RODZ,*SEM,*IR1)
                                 -ALT(*SEM,P.G)
                                 %PRZYM(*F1,*PRZYP.*LICZ.*RODZ,P,*IR) .
%GPORA(*PRZYP.*LICZ.*RODZ,*IR)== %RZECZ(*F,*PRZYP.*LICZ.*RODZ,P,*IR).

* USTALENIE DWORCA, USTALENIE NAZWY MIASTA.

%GDWOR(*SEM,*D) == %PRZIM(*F,*PRZYP,*SEM,*IR) -ALT(*SEM&*IR,KD&Z . KZ&NA)
                   %GDWO(*PRZYP,*D) .
%GDWOR(*K,*D) == %PUSTE.
%GDWO(*PRZYP,*IR) == %RZECZ(*F1,*PRZYP.*LICZ.*RODZ,D,*IR1)
                     %PRZYM(*F2,*PRZYP.*LICZ.*RODZ,D,*IR) .
%GDWO(*PRZYP,*IR) == %PRZYM(*F,*PRZYP.*LICZ.*RODZ,D,*IR).
%GMIAS(*IREF,*K) == %PRZIM(*F1,DOP,*K,*IREF1) -ALT(*K&*IREF1,KD&DO . KZ&Z)
                    %RZECZ(*F2,DOP.*L.*R,M,*IREF) .


* * * * * * * * * * * * * * * * * * * * * *
* SKLADNIA DODATKOWYCH WYPOWIEDZI KLIENTA *
* * * * * * * * * * * * * * * * * * * * * *.

* PRZELACZNIKI.

%DOPZN(*W,OBOJETNE,*PLEC) == %OBOJETNE(*PLEC)  .
%DOPZN(*W,KONCOWKA,*PLEC) == %KONCOWKA(*PLEC)  .
%DOPZN(*W.*K,*INFO,*PLEC) ==
                             %DOPYT(*W,*INFO,*PLEC) %ZNAK .
%DOPZN(*W   ,*INFO,*PLEC) ==
                             %DOPYT(*W,*INFO,*PLEC) %ZNAK .
%OBOJETNE(*PLEC) == %PRZYM("OBOJETNE",*K,*S,*I) %ZNAK .

%DOPYT(T,*T,*PLEC) ==  %DOPYTOT(*T,*PLEC) .
%DOPYT(P,*P,*PLEC) ==  %DOPYTOP(*P,*PLEC) .
%DOPYT(D,*D,*PLEC) ==  %DOPYTOD(*D,*PLEC) .
%DOPYT(G,*G,*PLEC) ==    %DOPYTOG(*G,*PLEC) .

* TYP POCIAGU.
%DOPYTOT(*T,*PLEC) == %ZYCZNIK(*PLEC) %GPOC(NARZ.*LICZ.*RODZ,*P,*T) .
%DOPYTOT(*T,*PLEC) == %POMOC(*LICZ.*RODZ,*PLEC) %GPOC(MIAN.*LICZ.*RODZ,*P,*T).
%DOPYTOT(*T,*PLEC) == %CHODZI(*PRZYP,*PLEC) %GPOC(*PRZYP.*LICZ.*RODZ,*P,*T).
%DOPYTOT(*T,*PLEC) == %PRZIM("O",BIER,-,O) %GPOC(BIER.*LICZ.*RODZ,*P,*T).
%DOPYTOT(*T,*PLEC) == %GPOC(*PRZYP.*LICZ.*RODZ,*P,*T) .

* DWORZEC.
%DOPYTOD(*D,*PLEC) == %ZYCZNIK(*PLEC) %GDWOR(*K,*D) .
%DOPYTOD(*D,*PLEC) == %POMOC(*LICZ.*RODZ,*PLEC) %GDWO(MIAN,*D) .
%DOPYTOD(*D,*PLEC) == %CHODZI(*PRZYP,*PLEC) %GDWO(*PRZYP,*D) .
%DOPYTOD(*D,*PLEC)== %PRZIM("O",BIER,-,O) %GDWO(BIER,*D).
%DOPYTOD(*D,*PLEC) == %GDWOR(*K,*D) .

* PORA DNIA.
%DOPYTOP(*P,*PLEC) == %POMOC(*LICZ.*RODZ,*PLEC) %GPORA(MIAN.*LICZ.*RODZ,*P) .
%DOPYTOP(*P,*PLEC) == %CHODZI(*PRZYP,*PLEC) %GPORA(*PRZYP.*LICZ.*RODZ,*P) .
%DOPYTOP(*P,*PLEC) == %POMOC(*LICZ.*RODZ,*PLEC) %GPOC(MIAN.*LICZ.*RODZ,*P,*T).
%DOPYTOP(*P,*PLEC) == %CHODZI(*PRZYP,*PLEC) %GPOC(*PRZYP.*LICZ.*RODZ,*P,*T).
%DOPYTOP(*P,*PLEC) == %PRZIM("O",BIER,-,O) %GPORA(BIER.*LICZ.*RODZ,*P).
%DOPYTOP(*P,*PLEC) == %ZYCZNIK(*PLEC) %GPOC(NARZ.*LICZ.*RODZ,*P,*T).
%DOPYTOP(*P,*PLEC) == %ZYCZNIK(*PLEC) %GPOR(*KATEG,*P) .
%DOPYTOP(*P,*PLEC) == %GPOR(*KATEG,*P) .

-NETT!
* GODZINA.
%DOPYTOG(*G,*PLEC) == %ZYCZNIK(*PLEC) %GGODZ(*PRZYP,*G) .
%DOPYTOG(*G,*PLEC) == %ZYCZNIK(*PLEC) %GPOC(NARZ.*LICZ.*RODZ,*P,*T)
                      %GGODZ(*PRZYP,*G) .
%DOPYTOG(*G,*PLEC) == %POMOC(*LICZ.*RODZ,*PLEC) %GGODZI(*PRZYP,*G) .
%DOPYTOG(*G,*PLEC) == %POMOC(*LICZ.*RODZ,*PLEC) %GPOC(MIAN.*LICZ.*RODZ,*P,*T)
           %GGODZ(*PRZYP,*G) .
%DOPYTOG(*G,*PLEC) == %CHODZI(*PRZYP,*PLEC) %GGODZI(*PRZYP,*G) .
%DOPYTOG(*G,*PLEC) == %CHODZI(*PRZYP,*PLEC) %GPOC(*PRZYP.*LICZ.*RODZ,*P,*T)
                      %GGODZ(*PRZYP,*G) .
%DOPYTOG(*G,*PLEC) == %PRZIM("O",BIER,-,O) %GGODZI(BIER,*G).


* ODESLANIE DO SLOWNIKA.

%SPOJNIK(*F,-,-,*IREF) == #*F-S(*F,SPOJNIK,-,-,*IREF).
%ZPRZYS(*F,-,*SEM,*IREF) == #*F-S(*F,ZPRZYS,-,*SEM,*IREF).
%PRZIM(*F,*PRZYP,*SEM,*IREF) == #*F-S(*F,PRZIM,*PRZYP,*SEM,*IREF).
%ZAIMPYT(*F,*PRZYP.*LICZ.*RODZ,*SEM,*IREF) ==
     #*F-S(*F,ZAIMPYT,*PRZYP.*LICZ.*RODZ,*SEM,*IREF).
%RZECZ(*F,*PRZYP.*LICZ.*RODZ,*SEM,*IREF) ==
      #*F-S(*F,RZECZ,*PRZYP.*LICZ.*RODZ,*SEM,*IREF).
%CZAS(*F,*KATEGORIE,*SEM,*IR) ==
      #*F-S(*F,CZAS,*KATEGORIE,*SEM,*IR).
%PRZYM(*F,*PRZYP.*LICZ.*RODZ,*SEM,*IREF) ==
      #*F-S(*F,PRZYM,*PRZYP.*LICZ.*RODZ,*SEM,*IREF).
%PRZYS(*F,-,*SEM,*IREF) == #*F -S(*F,PRZYS,-,*SEM,*IREF).
%ZAIMZWROT(*F,-,-,*IR) == #*F -S(*F,ZAIMZWROT,-,-,*IR).
%LICZBA(H(*HH,*MM)) == #H(*HH,*MM).
%PART(*F,-,-,*IR) == #*F -S(*F,PART,-,-,*IR).
%ZAIM(*F,*K,*S,*IR) == #*F -S(*F,ZAIM,*K,*S,*IR).


* * * * * * * * * * * * * * * * * * * * *
* SKLADNIA PYTAN O DODATKOWE INFORMACJE *
* * * * * * * * * * * * * * * * * * * * *.

%WYPYT(*SEM.*K,NEUTR) == %PYTON(*SEM.*K)  %CHODZY(NEUTR) #*Q  -QMARK(*Q).
%WYPYT(*SEM.*K,*SEKS) == %PYTOL(*SEM.*K)  %RESZT(*K,*SEKS) #*Q  -QMARK(*Q).
%WYPYT(*GOT,*SEKS) ==  %PYTON(*GOT) -ALT(*GOT,G.T)
                       %CHODZY(*SEKS) #*W -QMARK(*W) .

%PYTOL(D.*K) == %PRZIM(*F1,*PRZYP,*K,*IR1) -ALT(*K&*IR1,KZ&NA . KD&Z)
      %ZAIMPYT(*F2,*PRZYP.POJ.MES,-,*IR2) %RZECZ(*F3,*PRZYP.POJ.MES,D,*IR3)  .
%PYTOL(P.*K)  ==%PRZIM(*F1,MIEJ,-, O  )  %ZAIMPYT(*F2,MIEJ.*LICZ.*RODZ,-,*IR2)
                 %RZECZ(*F3,MIEJ.*LICZ.*RODZ,P,PORA) .

%PYTON(G)  == %PRZIM(*F1,BIER,-,O) %ZAIMPYT(*F2,BIER.POJ.ZEN,-,*IR2)
               %RZECZ(*F3,BIER.POJ.ZEN,G,*IR3)  .
%PYTON(*W)  == %PRZIM(*F1,BIER,-, O  ) %ZAIMPYT(*F2,BIER.POJ.MES,-,*IR2)
               %WATEK(*W,BIER.POJ.MES)  .
%PYTON(*W)  == %PRZIM(*F1,BIER,-, O  ) %ZAIMPYT(*F2,BIER.POJ.ZEN,-,*IR2)
               %WATEK(*W,BIER.POJ.ZEN) .

%WATEK(D.*K,BIER.*KAT) == %RZECZ(*F,BIER.*KAT,D,*IR) .
%WATEK(P.*K,BIER.*KAT) == %RZECZ (*F1,BIER.*KAT,P,PORA)
                          %RZECZ (*F2,DOP.POJ.MES,*K,*IR2) .
%WATEK(T,BIER.*KAT)  == %RZECZ (*F1,BIER.*KAT,T,RODZAJ)
                        %RZECZ (*F2,DOP.POJ.MES,PO,*IR) .

%RESZT(*K,*SEKS) == %CZAS (*F1,3OS.*SEKS,-,CHCIEC)
                    %RZECZ(*F2,MIAN.*SEKS,CZL,*IR1)
                    %CZAS (*F3,BEZOK,*K,*IR2) .

%CHODZY(NEUTR) == %CZAS(*F,3OS.POJ.NIJ,-,CHODZIC)  .
%CHODZY(*SEKS) == %RZECZ(*F1,CEL.*SEKS,CZL,*IR1)
                  %CZAS(*F2,3OS.POJ.NIJ,-,CHODZIC) .



-NETT!
* * * * * *
*         *
* SLOWNIK *
*         *
* * * * * *.

+S(*NAZWA,RZECZ,DOP.*L.*R,M,*IREF) -UNIV(*IREF,*NAZWA.NIL)  .
+S("O",PRZIM,BIER,-,O).
+S("O",PRZIM,MIEJ,-,O) .
+S("PO",PRZIM,MIEJ,P,PO) .
+S("PRZED",PRZIM,NARZ,P,PRZED) .
+S("W",PRZIM,*PRZYP,P,W) -ALT(*PRZYP,MIEJ.BIER)  .
+S("Z",PRZIM,DOP,KZ,Z).
+S("Z",PRZIM,DOP,KD,Z) .
+S("NA",PRZIM,BIER,KZ,NA) .
+S("DO",PRZIM,DOP,KD,DO) .

+S("JAKIEJ",ZAIMPYT,MIEJ.POJ.ZEN,-,JAKI) .
+S("JAKI",ZAIMPYT,MIAN.POJ.MES,-,JAKI) .
+S("JAKIEJ",ZAIMPYT,DOP.POJ.ZEN,-,JAKI) .
+S("JAKI",ZAIMPYT,BIER.POJ.MES,-,JAKI) .
+S("JAKIE",ZAIMPYT,MIAN.MNO.MES,-,JAKI)  .
+S("JAKIEGO",ZAIMPYT,DOP.POJ.MES,-,JAKI) .
+S("JAKA",ZAIMPYT,BIER.POJ.ZEN,-,JAKI) .
+S("JAKICH",ZAIMPYT,MIEJ.MNO.ZEN,-,JAKI)  .
+  S("KTORA",ZAIMPYT,BIER.POJ.ZEN,-,KTORY)  .
+S("KTOREJ",ZAIMPYT,MIEJ.POJ.ZEN,-,KTORY).
+S("KTOREJ",ZAIMPYT,DOP.POJ.ZEN,-,KTORY) .
+S("KTORY",ZAIMPYT,BIER.POJ.MES,-,KTORY) .
+S("KTOREGO",ZAIMPYT,DOP.POJ.MES,-,KTORY) .

+S("KIEDY",ZPRZYS,-,G,KIEDY) .
+S("SKAD",ZPRZYS,-,D,SKAD) .
+S("GDZIE",ZPRZYS,-,D,GDZIE) .
+S("DOKAD",ZPRZYS,-,D,DOKAD) .

+S("SIE",ZAIMZWROT,-,-,SIE)  .
+S("CZY",PART,-,-,CZY)  .
+S("I",SPOJNIK,-,-,I) .

+S("DWORZEC",RZECZ,*PRZ.POJ.MES,D,DWORZEC) -ALT(*PRZ,MIAN.BIER)  .
+S("STACJE",RZECZ,BIER.POJ.ZEN,D,STACJA) .
+S("DWORCA",RZECZ,DOP.POJ.MES,D,DWORZEC) .
+S("STACJI",RZECZ,DOP.POJ.ZEN,D,STACJA) .

+S("ODJEZDZA",CZAS,3OS.POJ.MES,KD,ODJEZDZAC) .
+S("ODJEZDZAJA",CZAS,3OS.MNO.MES,KD,ODJEZDZAC) .
+S("ODCHODZI",CZAS,3OS.POJ.MES,KD,ODCHODZIC) .
+S("ODCHODZA",CZAS,3OS.MNO.MES,KD,ODCHODZIC) .
+S("WYJEZDZA",CZAS,3OS.POJ.MES,KD,WYJEZDZAC) .
+S("WYJEZDZAJA",CZAS,3OS.MNO.MES,KD,WYJEZDZAC) .
+S("PRZYJEZDZA",CZAS,3OS.POJ.MES,KZ,PRZYJEZDZAC) .
+S("PRZYJEZDZAJA",CZAS,3OS.MNO.MES,KZ,PRZYJEZDZAC) .
+S("PRZYCHODZI",CZAS,3OS.POJ.MES,KZ,PRZYCHODZIC) .
+S("PRZYCHODZA",CZAS,3OS.MNO.MES,KZ,PRZYCHODZIC) .
+S("JEST",CZAS,3OS.POJ.MES,*SEM,BYC) -ALT(*SEM,KD.KZ) .
+S("SA",CZAS,3OS.MNO.MES,*SEM,BYC) -ALT(*SEM,KD.KZ) .
+  S("ODJAZDU",RZECZ,DOP.POJ.MES,KD,ODJAZD)  .
+  S("PRZYJAZDU",RZECZ,DOP.POJ.MES,KZ,PRZYJAZD)  .
+S("ODJECHAC",CZAS,BEZOK,KD,ODJECHAC) .
+S("WYJECHAC",CZAS,BEZOK,KD,WYJECHAC) .
+S("PRZYJECHAC",CZAS,BEZOK,KZ,PRZYJECHAC) .
+S("JECHAC",CZAS,BEZOK,*SEM,JECHAC) -ALT(*SEM,KD.KZ) .

+S("POCIAG",RZECZ,*PRZ.POJ.MES,PO,POCIAG)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("POCIAGI",RZECZ,*PRZ.MNO.MES,PO,POCIAG)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("POCIAGIEM",RZECZ,NARZ.POJ.MES,PO,POCIAG) .
+  S("POCIAGU",RZECZ,DOP.POJ.MES,PO,POCIAG)  .

+S("GODZINA",RZECZ,MIAN.POJ.ZEN,G,GODZINA) .
+S("GODZINY",RZECZ,*PRZYP.MNO.ZEN,G,GODZINA)   -ALT(*PRZYP,MIAN.BIER) .
+S("GODZINE",RZECZ,BIER.POJ.ZEN,G,GODZINA) .
+S("GODZINIE",RZECZ,MIEJ.POJ.ZEN,G,GODZINA) .
+S("GODZINACH",RZECZ,MIEJ.MNO.ZEN,G,GODZINA) .

+S("CENTRALNEGO",PRZYM,DOP.POJ.MES,D,CENTRALNY) .
+S("CENTRALNY",PRZYM,*PRZ.POJ.MES,D,CENTRALNY) -ALT(*PRZ,MIAN.BIER) .
+S("CENTRALNEJ",PRZYM,DOP.POJ.ZEN,D,CENTRALNY) .
+S("CENTRALNA",PRZYM,*PRZ.POJ.ZEN,D,CENTRALNY) -ALT(*PRZ,MIAN.BIER) .
+S("WSCHODNIEGO",PRZYM,DOP.POJ.MES,D,WSCHODNI) .
+S("WSCHODNI",PRZYM,*PRZ.POJ.MES,D,WSCHODNI) -ALT(*PRZ,MIAN.BIER) .
+S("WSCHODNIEJ",PRZYM,DOP.POJ.ZEN,D,WSCHODNI) .
+S("WSCHODNIA",PRZYM,*PRZ.POJ.ZEN,D,WSCHODNI) -ALT(*PRZ,MIAN.BIER) .
+S("ZACHODNIEGO",PRZYM,DOP.POJ.MES,D,ZACHODNI) .
+S("ZACHODNIEJ",PRZYM,DOP.POJ.ZEN,D,ZACHODNI) .
+S("ZACHODNI",PRZYM,*PRZ.POJ.MES,D,ZACHODNI) -ALT(*PRZ,MIAN.BIER) .
+S("ZACHODNIA",PRZYM,*PRZ.POJ.ZEN,D,ZACHODNI) -ALT(*PRZ,MIAN.BIER) .
+S("GDANSKIEGO",PRZYM,DOP.POJ.MES,D,GDANSKI) .
+S("GDANSKIEJ",PRZYM,DOP.POJ.ZEN,D,GDANSKI) .
+S("GDANSKI",PRZYM,*PRZ.POJ.MES,D,GDANSKI) -ALT(*PRZ,MIAN.BIER) .
+S("GDANSKA",PRZYM,*PRZ.POJ.ZEN,D,GDANSKI) -ALT(*PRZ,MIAN.BIER) .

+S("WARSZAWA",RZECZ,MIAN.POJ.ZEN,D,WARSZAWA) .
+S("WARSZAWY",RZECZ,DOP.POJ.ZEN,D,WARSZAWA) .
+S("WARSZAWE",RZECZ,BIER.POJ.ZEN,D,WARSZAWA) .

+S("OSOBOWY",PRZYM,*PRZ.POJ.MES,T,OSOBOWY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("OSOBOWE",PRZYM,*PRZ.MNO.MES,T,OSOBOWY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("OSOBOWYM",PRZYM,NARZ.POJ.MES,T,OSOBOWY) .
+S("POSPIESZNY",PRZYM,*PRZ.POJ.MES,T,POSPIESZNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("POSPIESZNE",PRZYM,*PRZ.MNO.MES,T,POSPIESZNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("POSPIESZNYM",PRZYM,NARZ.POJ.MES,T,POSPIESZNY) .
+S("EKSPRESOWY",PRZYM,*PRZ.POJ.MES,T,EKSPRESOWY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("EKSPRESOWE",PRZYM,*PRZ.MNO.MES,T,EKSPRESOWY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("EKSPRESOWYM",PRZYM,NARZ.POJ.MES,T,EKSPRESOWY) .
+S("EKSPRES",RZECZ,*PRZ.POJ.MES,T,EKSPRES)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("EKSPRESY",RZECZ,*PRZ.MNO.MES,T,EKSPRES)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("EKSPRESEM",RZECZ,NARZ.POJ.MES,T,EKSPRES) .

+  S("RODZAJ",RZECZ,BIER.POJ.MES,T,RODZAJ)  .

+S("DZIENNY",PRZYM,*PRZ.POJ.MES,P,DZIENNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("DZIENNE",PRZYM,*PRZ.MNO.MES,P,DZIENNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("DZIENNYM",PRZYM,NARZ.POJ.MES,P,DZIENNY) .
+S("PORANNY",PRZYM,*PRZ.POJ.MES,P,RANNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("PORANNE",PRZYM,*PRZ.MNO.MES,P,RANNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("PORANNYM",PRZYM,NARZ.POJ.MES,P,RANNY) .
+S("RANNY",PRZYM,*PRZYP.POJ.MES,P,RANNY) -ALT(*PRZYP,MIAN.BIER) .
+S("RANNE",PRZYM,*PRZYP.MNO.MES,P,RANNY) -ALT(*PRZYP,MIAN.BIER) .
+S("RANNE",PRZYM,*PRZYP.MNO.ZEN,P,RANNY) -ALT(*PRZYP,MIAN.BIER) .
+S("RANNYM",PRZYM,NARZ.POJ.MES,P,RANNY) .
+S("RANNYCH",PRZYM,MIEJ.MNO.ZEN,P,RANNY) .
+S("PRZEDPOLUDNIOWY",PRZYM,*PRZYP.POJ.MES,P,PRZEDPOLUDNIOWY)
                                                -ALT(*PRZYP,MIAN.BIER) .
+S("PRZEDPOLUDNIOWA",PRZYM,*PRZ.POJ.ZEN,P,PRZEDPOLUDNIOWY)
                                                -ALT(*PRZ  ,MIAN.BIER) .
+S("PRZEDPOLUDNIOWE",PRZYM,*PRZYP.MNO.*RODZ,P,PRZEDPOLUDNIOWY)
                         -ALT(*PRZYP,MIAN.BIER) -ALT(*RODZ,MES.ZEN) .
+S("PRZEDPOLUDNIOWYM",PRZYM,NARZ.POJ.MES,P,PRZEDPOLUDNIOWY) .
+S("PRZEDPOLUDNIOWYCH",PRZYM,MIEJ.MNO.ZEN,P,PRZEDPOLUDNIOWY) .
+S("PRZEDPOLUDNIOWEJ",PRZYM,MIEJ.POJ.ZEN,P,PRZEDPOLUDNIOWY) .
+S("POPOLUDNIOWY",PRZYM,*PRZ.POJ.MES,P,POPOLUDNIOWY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("POPOLUDNIOWE",PRZYM,*PRZ.MNO.MES,P,POPOLUDNIOWY)
                                                  -ALT(*PRZ,MIAN.BIER).
+S("POPOLUDNIOWE",PRZYM,*PRZYP.MNO.ZEN,P,POPOLUDNIOWE) -ALT(*PRZYP,MIAN.BIER).
+S("POPOLUDNIOWYM",PRZYM,NARZ.POJ.MES,P,POPOLUDNIOWY)  .
+S("POPOLUDNIOWEJ",PRZYM,MIEJ.POJ.ZEN,P,POPOLUDNIOWY) .
+S("POPOLUDNIOWYCH",PRZYM,MIEJ.MNO.ZEN,P,POPOLUDNIOWY)  .
+S("POPOLUDNIOWA",PRZYM,*PRZ.POJ.ZEN,P,POPOLUDNIOWY) -ALT(*PRZ,MIAN.BIER) .
+S("WIECZORNY",PRZYM,*PRZ.POJ.MES,P,WIECZORNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("WIECZORNE",PRZYM,*PRZ.MNO.MES,P,WIECZORNY)
                                                    -ALT(*PRZ,MIAN.BIER).
+S("WIECZORNE",PRZYM,*PRZYP.MNO.ZEN,P,WIECZORNY) -ALT(*PRZYP,MIAN.BIER) .
+S("WIECZORNYM",PRZYM,NARZ.POJ.MES,P,WIECZORNY) .
+S("WIECZORNEJ",PRZYM,MIEJ.POJ.ZEN,P,WIECZORNY) .
+S("WIECZORNYCH",PRZYM,MIEJ.MNO.ZEN,P,WIECZORNY) .
+S("WIECZORNA",PRZYM,*PRZYP.POJ.ZEN,P,WIECZORNY) -ALT(*PRZYP,MIAN.BIER) .
+S("NOCNY",PRZYM,*PRZ.POJ.MES,P,NOCNY)
                                                         -ALT(*PRZ,MIAN.BIER).
+S("NOCNE",PRZYM,*PRZ.MNO.MES,P,NOCNY)
                                                       -ALT(*PRZ,MIAN.BIER).
+S("NOCNE",PRZYM,*PRZYP.MNO.ZEN,P,NOCNY) -ALT(*PRZYP,MIAN.BIER) .
+S("NOCNYM",PRZYM,NARZ.POJ.MES,P,NOCNY) .
+S("NOCNEJ",PRZYM,MIEJ.POJ.ZEN,P,NOCNY) .
+S("NOCNYCH",PRZYM,MIEJ.MNO.ZEN,P,NOCNY) .
+S("NOCNA",PRZYM,*PRZ.POJ.ZEN,P,NOCNY) -ALT(*PRZ,MIAN.BIER) .

+S("POLUDNIE",RZECZ,BIER.POJ.NIJ,P,POLUDNIE) .
+S("POLUDNIEM",RZECZ,NARZ.POJ.NIJ,P,POLUDNIE) .
+S("POLUDNIU",RZECZ,MIEJ.POJ.NIJ,P,POLUDNIE) .
+S("NOCY",RZECZ,MIEJ.POJ.ZEN,P,NOC) .
+S("NOCA",RZECZ,NARZ.POJ.ZEN,P,NOC) .
+S("DZIEN",RZECZ,BIER.POJ.MES,P,DZIEN) .
+S("WIECZOREM",PRZYS,-,P,WIECZOR) .
+S("RANO",PRZYS,-,P,RANO) .
+S("RANO",RZECZ,*PRZYP.POJ.NIJ,P,RANO) -ALT(*PRZYP,MIAN.BIER).
+S("PORA",RZECZ,MIAN.POJ.ZEN,P,PORA) .
+S("PORE",RZECZ,BIER.POJ.ZEN,P,PORA) .
+S("PORZE",RZECZ,MIEJ.POJ.ZEN,P,PORA) .

+S("MOGE",CZAS,1OS.POJ.*RODZ,-,MOC)  .
+S("MOZEMY",CZAS,1OS.MNO.*RODZ,-,MOC)  .
+S("MOGLABYM",CZAS,1OS.POJ.ZEN,-,MOC) .
+S("MOGLIBYSMY",CZAS,1OS.MNO.MES,-,MOC) .
+S("MOGLYBYSMY",CZAS,1OS.MNO.ZEN,-,MOC) .
+S("CHCE",CZAS,1OS.POJ.*RODZ,-,CHCIEC)  .
+S("CHCEMY",CZAS,1OS.MNO.*RODZ,-,CHCIEC)  .
+S("CHCIALBYM",CZAS,1OS.POJ.MES,-,CHCIEC) .
+S("CHCIALABYM",CZAS,1OS.POJ.ZEN,-,CHCIEC) .
+S("CHCIELIBYSMY",CZAS,1OS.MNO.MES,-,CHCIEC) .
+S("CHCIALYBYSMY",CZAS,1OS.MNO.ZEN,-,CHCIEC) .
+S("CHCIALBY" ,CZAS,3OS.POJ.MES,-,CHCIEC)  .
+S("CHCIALABY",CZAS,3OS.POJ.ZEN,-,CHCIEC)  .
+S("CHCIELIBY",CZAS,3OS.MNO.MES,-,CHCIEC)  .
+S("CHCIALYBY",CZAS,3OS.MNO.ZEN,-,CHCIEC)  .
+S("MOGLBYM",CZAS,1OS.POJ.MES,-,MOC) .

+S("PROSZE",CZAS,1OS.POJ.*RODZ,PR,PROSIC)  .
+S("PROSIMY",CZAS,1OS.MNO.*RODZ,PR,PROSIC)  .
+S("PROSILBYM",CZAS,1OS.POJ.MES,PR,PROSIC) .
+S("PROSILABYM",CZAS,1OS.POJ.ZEN,PR,PROSIC) .
+S("PROSILIBYSMY",CZAS,1OS.MNO.MES,PR,PROSIC) .
+S("PROSILYBYSMY",CZAS,1OS.MNO.ZEN,PR,PROSIC) .
+S("PROSIC",CZAS,BEZOK,PR,PROSIC) .
+S("POPROSZE",CZAS,1OS.POJ.*RODZ,PR,POPROSIC) .
+S("POPROSIMY",CZAS,1OS.MNO.*RODZ,PR,POPROSIC)  .
+S("POPROSILBYM",CZAS,1OS.POJ.MES,PR,POPROSIC) .
+S("POPROSILABYM",CZAS,1OS.POJ.ZEN,PR,POPROSIC) .
+S("POPROSILIBYSMY",CZAS,1OS.MNO.MES,PR,POPROSIC) .
+S("POPROSILYBYSMY",CZAS,1OS.MNO.ZEN,PR,POPROSIC) .
+S("POPROSIC",CZAS,BEZOK,PR,POPROSIC) .

+S("OTRZYMAC",CZAS,BEZOK,INF,OTRZYMAC) .
+S("DOSTAC",CZAS,BEZOK,INF,DOSTAC) .
+S("UZYSKAC",CZAS,BEZOK,INF,UZYSKAC) .
+S("DOWIEDZIEC",CZAS,BEZOK,DOW,DOWIEDZIEC) .
+S("POINFORMOWAC",CZAS,BEZOK,DOW,POINFORMOWAC) .
+S("SPYTAC",CZAS,BEZOK,PYT,SPYTAC) .
+S("ZAPYTAC",CZAS,BEZOK,PYT,ZAPYTAC) .
+S("WIEDZIEC",CZAS,BEZOK,WIE,WIEDZIEC) .

+S("INTERESUJE",CZAS,3OS.POJ.*RODZ,-,INTERESOWAC)  .
+S("INTERESUJA",CZAS,3OS.MNO.*RODZ,-,INTERESOWAC)  .
+S("CHODZI",CZAS,3OS.POJ.NIJ,-,CHODZIC) .

+S("MI",ZAIM,CEL.POJ.*RODZ,-,JA)   .
+S("NAM",ZAIM,CEL.POJ.*RODZ,-,MY)  .
+S("MNIE",ZAIM,*PRZYP.POJ.*RODZ,-,JA)  -ALT(*PRZYP,DOP.BIER)  .
+S("NAS",ZAIM,*PRZYP.MNO.*RODZ,-,MY) -ALT(*PRZYP,DOP.BIER)  .

+S("INFORMACJE",RZECZ,BIER.POJ.ZEN,INF,INFORMACJA) .
+S("WIADOMOSC",RZECZ,BIER.POJ.ZEN,INF,WIADOMOSC) .
+S("POINFORMOWANIE",RZECZ,BIER.POJ.NIJ,I,POINFORMOWANIE) .

+  S("PAN",RZECZ,MIAN.POJ.MES,CZL,PAN)  .
+  S("PANU",RZECZ,CEL.POJ.MES,CZL,PAN)  .
+  S("PANI",RZECZ,MIAN.POJ.ZEN,CZL,PANI)  .
+  S("PANI",RZECZ,CEL.POJ.ZEN,CZL,PANI)  .
+  S("PANSTWO",RZECZ,MIAN.MNO.MES,CZL,PANSTWO)  .
+  S("PANSTWU",RZECZ,CEL.MNO.MES,CZL,PANSTWO)  .
+  S("PANIE",RZECZ,MIAN .MNO.ZEN,CZL,PANI)  .
+  S("PANIOM",RZECZ,CEL.MNO.ZEN,CZL,PANI)  .

+S("OBOJETNE",PRZYM,MIAN.POJ.NIJ,-,OBOJETNE)   .
+S("DZIEKUJE",CZAS, 1OS.POJ.*RODZ,KONC,DZIEKOWAC) .
+S("DZIEKUJEMY",CZAS, 1OS.MNO.*RODZ,KONC,DZIEKOWAC) .


-NETT!
* * * * * * * * *
* ROZKLAD JAZDY *
* * * * * * * * *.

+R(EKSPRES,DO,KATOWIC,17.43,CENTRALNY) .
+R(POSPIESZNY,Z,KATOWIC,17.41,CENTRALNY).
+R(POSPIESZNY,Z,KATOWIC,17.36,ZACHODNI).
+R(POSPIESZNY,Z,KATOWIC,17.56,WSCHODNI).
+R(EKSPRES,Z,KATOWIC,9.54,CENTRALNY).
+R(EKSPRES,Z,KATOWIC,10.10,WSCHODNI).
+R(EKSPRES,DO,GLIWIC,5.54,WSCHODNI).
+R(EKSPRES,DO,GLIWIC,17.04,WSCHODNI).
+R(POSPIESZNY,DO,GLIWIC,13.44,CENTRALNY).
+R(EKSPRES,DO,GLIWIC,20.00,GDANSKI).
+R(EKSPRES,Z,GLIWIC,9.54,CENTRALNY).
+R(EKSPRES,Z,GLIWIC,10.33,CENTRALNY).
+R(OSOBOWY,Z,GLIWIC,4.25,CENTRALNY).
+R(POSPIESZNY,Z,GLIWIC,19.17,CENTRALNY).
+R(OSOBOWY,DO,KRAKOWA,8.24,ZACHODNI).
+R(OSOBOWY,DO,KRAKOWA,8.00,WSCHODNI).
+R(POSPIESZNY,DO,KRAKOWA,15.59,CENTRALNY).
+R(OSOBOWY,Z,PSZCZYNY,6.00,CENTRALNY) .
+R(OSOBOWY,DO,AUGUSTOWA,8.58,CENTRALNY) .
+R(OSOBOWY,DO,AUGUSTOWA,14.55,WSCHODNI) .
+R(OSOBOWY,DO,AUGUSTOWA,17.23,WSCHODNI) .
+R(EKSPRES,DO,BYDGOSZCZY, 6.03,CENTRALNY) .
+R(EKSPRES,DO,BYDGOSZCZY,17.44,WSCHODNI) .
+R(OSOBOWY,DO,BYDGOSZCZY,17.44,WSCHODNI) .
+R(OSOBOWY,DO,BYDGOSZCZY,23.59,WSCHODNI) .
+R(POSPIESZNY,Z,BYDGOSZCZY,21.49,CENTRALNY) .
+R(POSPIESZNY,Z,BYDGOSZCZY,21.44,ZACHODNI) .
+R(EKSPRES,Z,BYDGOSZCZY,9.27,CENTRALNY).
+R(OSOBOWY,DO,WROCLAWIA,20.00,ZACHODNI) .
+R(POSPIESZNY,DO,WROCLAWIA,20.00,WSCHODNI) .
+R(OSOBOWY,DO,WROCLAWIA,19.37,WSCHODNI) .
+R(OSOBOWY,DO,PILY,16.43,CENTRALNY) .
+R(OSOBOWY,DO,PILY,17.44,WSCHODNI) .
+R(POSPIESZNY,Z,RZESZOWA,9.23,CENTRALNY) .
+R(POSPIESZNY,Z,RZESZOWA,9.38,WSCHODNI) .
+R(POSPIESZNY,Z,RZESZOWA,7.34,WSCHODNI) .
+R(OSOBOWY,DO,MALKINI,8.03,GDANSKI) .
+R(POSPIESZNY,DO,MALKINI,22.53,WSCHODNI) .
+R(OSOBOWY,DO,MALKINI,22.53,ZACHODNI) .
+R(EKSPRES,DO,GDYNI,5.44,ZACHODNI) .
+R(EKSPRES,DO,GDYNI,5.58,WSCHODNI) .
+R(OSOBOWY,DO,GDYNI,22.40,ZACHODNI) .
+R(OSOBOWY,DO,GDYNI,23.12,WSCHODNI) .
+R(EKSPRES,DO,OLSZTYNA,17.43,ZACHODNI) .
+R(OSOBOWY,DO,OLSZTYNA,9.20,CENTRALNY) .

-NETT!
-STOP!

/pre>
        
« November 2020 »
Su Mo Tu We Th Fr Sa
1 2 3 4 5 6 7
8 9 10 11 12 13 14
15 16 17 18 19 20 21
22 23 24 25 26 27 28
29 30
 

Powered by Plone CMS, the Open Source Content Management System

This site conforms to the following standards: