Personal tools
You are here: Home Projects FORTRAN and FORTRAN II Source Code ibsys FORTRAN 32K 709/7090 FORTRAN - SECTION TWO
Document Actions

32K 709/7090 FORTRAN - SECTION TWO

by Paul McJones last modified 2005-06-01 20:11

Click here to get the file

Size 589.9 kB - File type text/plain

File contents

$JOB   ASSEMBLY OF MONITOR, COMPILER SECTIONS 1 THROUGH 6 OF           $00000010
$*     FORTRAN II PROCESSOR, 7090-FO-928                                00000020
$*     VERSION 3, MODIFICATION LEVEL 35                             (35)00000030
$EXECUTE       IBSFAP                                                  $00000050
*      32K 709/7090 FORTRAN SECTION TWO                                 F2A00000
*      FAP                                                              F2A00020
*      32K 709/7090 FORTRAN SECTION TWO                                 F2A00030
       COUNT   7400                                                     F2A00040
       LBL     9F18,M                                                   F2A00050
       TTL     BLOCK A.                                                 F2A00060
       SST     FORTRAN                                                 $F2A00070
*     SECTION TWO OF 709/7090 32K FORTRAN, BLOCK A.                     F2A00080
       HEAD    1                                                        F2A00090
       ABS                                                             $F2A00100
       ORG     SYSCUR                                                  $F2A00110
       BCI     1,9F1800                                                $F2A00120
       ORG     (LODR)                                                  $F2A00121
       TXI     TAP00,,180                                               F2A00130
       REM     PERFORMS THE PRELIM DO NEST STRUCTURE ANALYSIS           F2A00150
       REM REQUIRED FOR THE SUCCEEDING BLOCKS. IT AXSIGNS               F2A00160
       REM LEVEL NUMBERS AND THE POSSIBILITY OF CARRY.                  F2A00170
       REM TRANSFERS OUT OF THE RANGE OF DOS ARE NOTED AND ENTERED      F2A00180
       REM INTO TABLE TRALEV. IF THERE IS A VARIABLE                    F2A00190
       REM PARAMETER OF A DO ITS HIGHEST LEVEL OF DEFINITION            F2A00200
       REM IS ASSIGNED.                                                 F2A00210
       REM FINALLY, A SEARCH IS MADE TO DETERMINE                       F2A00220
       REM WHETHER A DO INDEX COUNTER IS                                F2A00230
       REM NECESSARY TO KEEP CURRENT THE VALUES                         F2A00240
       REM OF THE DO INDEX.                                             F2A00250
TOP    SYN     BOTIOP-1             UPPERMOST CORE FOR SEC. 2.          F2A00260
M      SYN     7             M/N IS RATIO OF TABLE SIZES.              $F2A00270
N      SYN     8             TO NORMAL 32 K TABLE SIZE                 $F2A00280
FTAPE1 SYN     SYSTAP                                                   F2A00290
FTAPE2 SYN     FINTAP                                                   F2A00300
FTAPE3 SYN     SINTAP                                                   F2A00310
FTAPE4 SYN     TINTAP                                                   F2A00320
ENDCOR SYN     TOP+1                LAST POSIT IN CORE +1               F2A00330
TDOZ   SYN     ENDCOR               DEFINITIONS OF TABLE                F2A00340
TDO    SYN     TDOZ-600*M/N*5       POSITIONS IN MEMORY.                F2A00350
TDOWC  SYN     TDO-1                WHEN Z FOLLOWS THE TABLE            F2A00360
TIFZ   SYN     TDOWC                NAME, THE LOCATION IS THE           F2A00370
TIFGO  SYN     TIFZ-1200*M/N*2      LAST LOC +1 IN THE TABLE.           F2A00380
TIFGWC SYN     TIFGO-1              WHEN WC FOLLOWS THE TABLE           F2A00390
TRADZ  SYN     TIFGWC               NAME, THE LOCATION IS THAT          F2A00400
TRAD   SYN     TRADZ-1000*M/N       OF THE TABLE WORD COUNT.            F2A00410
TRADWC SYN     TRAD-1                                                   F2A00420
FIXCN  SYN     TRADWC-400*M/N-2                                         F2A00430
FIXWC  SYN     FIXCN-1                                                  F2A00440
TAU3   SYN     FIXWC-300*M/N*6                                          F2A00450
TAU2   SYN     TAU3-360*M/N*4                                           F2A00460
TAU1   SYN     TAU2-400*M/N*2                                           F2A00470
DRMTGZ SYN     TAU1-2                                                   F2A00480
DMTGTB SYN     DRMTGZ-400*M/N*4                                         F2A00490
DMTGWC SYN     DMTGTB-1                                                 F2A00500
4VALZ  SYN     DMTGWC                                                   F2A00510
FORVAL SYN     4VALZ-2000*M/N*2                                         F2A00520
4VALWC SYN     FORVAL-1                                                 F2A00530
DOTGZ  SYN     4VALWC                                                   F2A00540
DOTAG  SYN     DOTGZ-600*M/N*9                                          F2A00550
DOTGWC SYN     DOTAG-1                                                  F2A00560
4VARZ  SYN     DOTGWC                                                   F2A00570
FORVAR SYN     4VARZ-3000*M/N*2                                         F2A00580
FRVRWC SYN     FORVAR-1                                                 F2A00590
FORTZ  SYN     DOTGZ-200*M/N*9-1                                        F2A00600
FORTAG SYN     FORTZ-3000*M/N*2                                         F2A00610
FRTGWC SYN     FORTAG-1                                                 F2A00620
TLTZ   SYN     ENDCOR               TRALEV BUFFER USED AFTER TDO        F2A00630
TRALEV SYN     TLTZ-2400*M/N        IS EXPANDED AND MOVED               F2A00640
TRLVWC SYN     TRALEV-1             TO DOTAG.                           F2A00650
RTTBNR SYN     FRVRWC-2                                                 F2A00660
RT90   SYN     RTTBNR-1                                                 F2A00670
       HEAD    0                                                        F2A00680
M      SYN     1$M                                                      F2A00690
N      SYN     1$N                                                      F2A00700
       REM BLOCK ONE COMMON AREA. CELLS TO BE SHARED WITH LATER BLOCKS. F2A00710
       ORG     BOTTOM+10            TEN INFO CELLS BELOW ORG FOR SEC. 3.F2A00720
ERRORM TXI     (DIAG),,0            MACHINE ERROR HAS OCCURRED.         F2A00730
ERROR1 TXI     (DIAG),,-1244        4.NESTS WRONG OR                    F2A00740
       PZE     1$LIST               A HIGHER THAN B.                    F2A00750
ERROR2 TXI     (DIAG),,-306         5.N3 OF DO EQUALS ZERO.             F2A00760
       PZE     1$DOTGZ                                                  F2A00770
ERROR3 TXI     (DIAG),,-468         6.TRA TO DO OF LEVEL OVER 20.       F2A00780
ERROR4 TXI     (DIAG),,-485         7.TRANSFER INTO A DO FROM           F2A00790
       PZE     1$TIFZ               OUTSIDE ITS RANGE.                  F2A00800
ERROR5 TXI     (DIAG),,-719         8.N1,2,OR 3 REDEFINED INSIDE DO.    F2A00810
ERROR6 TXI     (DIAG),,-404         9.MORE THAN 200 DOS IN A NEST.      F2A00820
ERROR7 TXI     (DIAG),,-858         10.TABLE HAS OVERFLOWED.            F2A00830
ERROR8 TXI     (DIAG),,-1005        11.INTERMEDIATE TABLE IS FULL.      F2A00840
       PZE     2$DOTAG                                                  F2A00850
ERROR9 TXI     (DIAG),,-542         12.CORE TABLE IS FULL.              F2A00860
ERRO10 TXI     (DIAG),,-13438       13.FIXCON HAS OVERFLOWED.           F2A00870
ERRO11 TXI     (DIAG),,-13391       14.TAGTAG HAS OVERFLOWED.           F2A00880
ERRO12 TXI     (DIAG),,-13496       15.TOO MANY DOS ENDING AT THE       F2A00890
       PZE     5$VCTR               SAME STATEMENT.                     F2A00900
ERRO13 TXI     (DIAG),,-7           DOFILE HAS OVERFLOWED.              F2A00910
       PZE     5$DOTAG                                                  F2A00920
ERRO14 TXI     (DIAG),,-8           TRALEV TOO LARGE.                   F2A00930
REWIND PZE     ,,-1                                                     F2A00940
MAXFTG PZE     ,,3000*M/N*2         MAX SIZE FORTAG.                    F2A00950
MAXFVL PZE     ,,2000*M/N*2         MAX SIZE FORVAL.                    F2A00960
MAXDTG PZE     ,,600*M/N*9          MAX SIZE DOTAG.                     F2A00970
DORCCT PZE                          COMMON CELL TO CARRY                F2A00980
       REM                          COUNT OF DOTAG B RECORDS.           F2A00990
ADDMSK OCT     77777                                                    F2A01000
DECMSK OCT     77777000000                                              F2A01010
BITONE OCT     200000000000                                             F2A01020
BITTWO OCT     100000000000                                             F2A01030
       HEAD    1                                                        F2A01040
       REM PROGRAM CONSTANTS                                            F2A01050
       ORG     BITTWO+1                                                 F2A01060
L(0)           0,0,0                                                    F2A01070
L(1)           0,0,1                                                    F2A01080
L(3)           0,0,3                                                    F2A01090
MAXTIF PZE     ,,1200*M/N*2         MAX SIZE TIFGO.                     F2A01100
MAXFVR PZE     ,,3000*M/N*2         MAX SIZE FORVAR.                    F2A01110
MAXTDO PZE     ,,600*M/N*5          MAX SIZE TDO.                       F2A01120
L(MZ)  MZE                                                              F2A01130
DECADD OCT     77777077777                                              F2A01140
TAGMSK OCT     700000                                                   F2A01150
NCMSK  OCT     -377777477777                                            F2A01160
CR1    OCT     100000                                                   F2A01170
CR2    OCT     200000                                                   F2A01180
TBCHK  PZE                                                              F2A01190
       PZE                                                              F2A01200
       REM BEGIN BLO CK ONE.                                            F2A01210
TAP00  SLF                          ALL LIGHTS OFF.                     F2A01220
       SLN     2                    TRALEV LIGHT ON.                    F2A01230
       DCT                                                              F2A01240
       NOP                                                              F2A01250
       CLA     MAXTIF               COMPUTE NEXT                        F2A01260
       SUB     TIFGWC               UNUSED INDEX FOR                    F2A01270
       STD     TIFGWC               TIFGO, AND STORE.                   F2A01280
       CLA     MAXTDO               COMPUTE NEXT UNUSED                 F2A01290
       SUB     TDOWC                INDEX FOR TDO,                      F2A01300
       STD     TDOWC                AND STORE.                          F2A01310
       LXD     TDOWC,1              LOAD XR AND                         F2A01320
       TXL     TAP15,1,600*M/N*5-1  TEST FOR EMPTY TDO.                 F2A01330
       SLN     3                    TDO IS EMPTY, SET                   F2A01340
       CLA     MAXDTG               SDNSE LIGHT, STORE                  F2A01350
       STD     DOTAG-1              UNUSED INDEX                        F2A01360
       TRA     TS4VAL               VALUE, AND TRANSTER.                F2A01370
TAP15  SXD     TAP35,1              THIS ROUTINE                        F2A01380
       LXD     MAXTDO,1             MOVES FIVE-WORD                     F2A01390
       LXD     MAXDTG,2             TDO ENTRIES                         F2A01400
TAP20  AXT     5,4                  TO DOTAG                            F2A01410
TAP21  CLA     TDOZ,1               AND EXPANDS TO                      F2A01420
       STO     DOTGZ,2              A NINE-WORD PER                     F2A01430
       TXI     *+1,1,-1             ENTRY TABLE.                        F2A01440
       TXI     *+1,2,-1                                                 F2A01450
       TIX     TAP21,4,1                                                F2A01460
       AXT     4,4                                                      F2A01470
TAP30  STZ     DOTGZ,2              ZERO OUT FOUR                       F2A01480
       TXI     *+1,2,-1             WORDS AFTER                         F2A01490
       TIX     TAP30,4,1            EACH TDO.                           F2A01500
TAP35  TXH     TAP20,1,**           DEC. CONTAINS LAST TDO+1            F2A01510
       SXD     DOTAG-1,2            SAVE UNUSED INDEX.                  F2A01520
       TRA     MR00                                                     F2A01530
       REM MROO COMPUTES LEVEL, X, CARRY BITS.                          F2A01540
MR00   LXD     DOTAG-1,1            INITIALIZE TEST                     F2A01550
       SXD     MR70,1               INSTRUCTION.                        F2A01560
       LXD     MAXDTG,1             INITIALIZE XRA TO MAX DOTAG.        F2A01570
MR05   CLA     L(1)                 INITIALIZE LEVEL TO ONE             F2A01580
MR10   PDX     0,2                  PUT LEVEL IN XRB                    F2A01590
       STO     DOTGZ+5,1            STORE LEVEL IN L WORD               F2A01600
       CLA     DOTGZ,1              INSPECT TAG OF FIRST WORD.          F2A01610
       SXD     MR14,4                                                   F2A01620
       PAX     0,4                                                      F2A01630
       STD     MR12                                                     F2A01640
MR12   TXH     MR15,4,0                                                 F2A01650
       TRA     ERBETA                                                   F2A01660
MR14   PZE                                                              F2A01670
MR15   LXD     MR14,4                                                   F2A01680
       ANA     TAGMSK               IF ZERO( TRA TO MR20)               F2A01690
       TZE     MR20                 IF NOT ZERO( PUT BIT                F2A01700
       CLA     BITTWO               IN L WORD FOR X NOT                 F2A01710
       ORS     DOTGZ+5,1            COMPUTABLE AND GO TO                F2A01720
       TRA     MR60                 END.                                F2A01730
MR20   CLA     DOTGZ+3,1            COMPUTE X AND XTORE IN              F2A01740
       SUB     DOTGZ+2,1            L WORD                              F2A01750
       ADD     DOTGZ+4,1                                                F2A01760
       LRS     35                                                       F2A01770
       DVP     DOTGZ+4,1                                                F2A01780
       DCT                                                              F2A01790
       TSX     ERROR2,4             SOURCE PROGRAM ERROR.               F2A01800
       MPY     DOTGZ+4,1                                                F2A01810
       LLS     35                                                       F2A01820
       STA     DOTGZ+5,1                                                F2A01830
       TXL     MR60,2,1             IF L IS ONE( SKIP CARRY TEST)       F2A01840
       CLA     DOTGZ,4              OBTAIN NEXT BACK SUBNEST            F2A01850
       ARS     15                   DO( FIRST WORD. IN SPECT TAG        F2A01860
       LBT                          FOR VARIABLE N3) IF NOT             F2A01870
       TRA     MR30                 0) VARIABLE( CONTINUE WITH MR30,    F2A01880
       TRA     MR60                 1) OTHERWISE GO TO END.             F2A01890
MR30   CLA     DOTGZ,4              OBTANN FIRST WORD OF NEXT           F2A01900
       ANA     DECADD               BACK SUBNEST DO, REMOVE             F2A01910
       ADD     L(1)                 TAG, AND ADD ONE TO ALPHA.          F2A01920
       SUB     DOTGZ,1              SUB 1ST WD OF CURRENT DO            F2A01930
       TNZ     MR40                 (TAG IS ZERO). IF RESULT IS         F2A01940
       CLA     CR1                  ZERO, CARRY IS TYPE ONE,            F2A01950
       TRA     MR50                 IF NOT ZERO, CARRY IS TYPE          F2A01960
MR40   CLA     CR2                  TWO. INDICATE TYPE IN               F2A01970
MR50   ORS     DOTGZ+5,1            L WORD OF CURRENT DO.               F2A01980
MR60   PXD     0,1                  MAKE CURRENT DO NEXT BACK           F2A01990
       PDX     0,4                  SUBNEST DO.                         F2A02000
       TXI     MR70,1,-9            TAKE NEXT DO IN DOTAG.              F2A02010
MR70   TXL     ERTST,1,0            NO MORE DOS, EXIT TO TEST IF ERRORS F2A02020
       CLA     DOTGZ,1              OBTAIN 1ST WD OF NEW DO.            F2A02030
       ANA     ADDMSK               OBTAIN BETA                         F2A02040
       STO     MRES                 AND SAVE                            F2A02050
MR75   CLA     DOTGZ,4              OBTAIN BETA OF XRC DO,              F2A02060
       ANA     ADDMSK               AND SUBTRCT NEW BETA.               F2A02070
       STO     MRES1                                                    F2A02080
       SUB     MRES                 IF NOT NEGATIVE, XRC DO             F2A02090
       TMI     MR80                 CONTAINS NEW DO. OTHERWISE, TRA.    F2A02100
       CLA     DOTGZ+5,4            XRC CONTAINS NEW DO.                F2A02110
       ANA     DECMSK               OBTAIN LEVEL OF XRC DO,             F2A02120
       ADD     L(1)                 ADD ONE, STORE IN L.                F2A02130
       TRA     MR10                 GO TO MRIO                          F2A02140
MR80   CLA     DOTGZ,1                                                  F2A02150
       ANA     DECMSK                                                   F2A02160
       ARS     18                                                       F2A02170
       CAS     MRES1                                                    F2A02180
       TRA     MR85                 ALPHA(XRA) GREATER THAN BETA(XRC)   F2A02190
       TRA     ERLIST                                                   F2A02200
       TRA     ERLIST                                                   F2A02210
MR85   CLA     DOTGZ+5,4                                                F2A02220
       PDX     0,2                  NEWDO. IF XRL DO IS OF              F2A02230
       TXL     MR05,2,1             LEVEL ONE, START NEW NEST           F2A02240
       TXI     MR75,4,9             BY TRA TO MR05. ELSE TRA MR75.      F2A02250
MRES   PZE                                                              F2A02260
MRES1  PZE                                                              F2A02270
       REM FLOW, TRANSFER ANALYSIS.                                     F2A02280
FLOW   LXD     TIFGO-1,4            TEST FOR EMPTY TIFGO                F2A02290
       TXH     SV00,4,1200*M/N*2-1  TEST FOR EMPTY TIFGO.               F2A02300
       LXD     DOTAG-1,1            INITIALIZE                          F2A02310
       SXD     FL030,1              TEST                                F2A02320
       SXD     FL060,4              INSTRUCTIONS                        F2A02330
       SXD     ADL60,1                                                  F2A02340
       SXD     INC40,1                                                  F2A02350
       SXD     RNC70,1                                                  F2A02360
       AXT     0,1                  INITIALIZE TRALEV                   F2A02370
       SXD     TLT50,1              INDEX VALUE                         F2A02380
FLO10  LXD     MAXTIF,4             INITIALIZE                          F2A02390
       SXD     TIFX,4               CURRENT TIFGO INDEX                 F2A02400
       LXD     MAXDTG,1             INITIALIZE XRA, DOTAG IX            F2A02410
FL015  CLA     DOTGZ+5,1            INITIALIZE XRA, DOTAG IX            F2A02420
       PDX     0,2                  AND                                 F2A02430
       TXL     FL040,2,1            TRA IF LEVEL ONE. IF NOT            F2A02440
FL020  TXI     FL030,1,-9           LEVEL ONE, FIND NEXT                F2A02450
FL030  TXH     FL015,1,0            LEVEL ONE, IF ANY.                  F2A02460
       TRA     FLOEND                                                   F2A02470
FL040  SXD     BNX,1                SAVE BEGINNING OF NEST INDEX.       F2A02480
       CLA     DOTGZ,1              INITIALIZE                          F2A02490
       PAX     0,2                  BEGINNING OF NEST                   F2A02500
       ANA     DECMSK               AND                                 F2A02510
       STO     BNA                  END OF NEST                         F2A02520
       PXD     0,2                  ADDRESSES                           F2A02530
       LXD     TIFX,4               OBTAIN CURRENT TIFGO INDEX          F2A02540
       STO     ENA                                                      F2A02550
FL050  CLA     TIFZ,4               AND SEARCH FOR TIFGO                F2A02560
       ANA     DECMSK               ENTRY IN NEST.                      F2A02570
       CAS     BNA                  COMPARE WITH BNA                    F2A02580
       TRA     FL070                GREATER THAN OR EQUAL TO            F2A02590
       TSX     ERRORM,4             DECR OF TIFGO WORD (XR VALUE        F2A02600
       REM                          IN TIFX) SHOULD BE UNEQUAL TO       F2A02610
       REM                          BNA, WHICH CAME FROM THE IFN        F2A02620
       REM                          IN THE XR1 DOTAG WORD. TIFGO        F2A02630
       REM                          IS REC 6 FILE 5 TAPE2, AND THE      F2A02640
       REM                          DOTAG WORD IS PICKED UP FROM        F2A02650
       REM                          TDO (REC 8 FILE5 TAPE B2).          F2A02660
FL055  TXI     FL060,4,-2           LESS THAN BNA, GO BACK              F2A02670
FL060  TXH     FL050,4,0            FOR NEXT TIFGO ENTRY,               F2A02680
       TRA     FLOEND               IF ANY. IF NONE, EXIT               F2A02690
FL065  LXD     BNX,1                                                    F2A02700
       TRA     FL020                                                    F2A02710
FL070  SXD     TIFX,4               SAVE CURRENT TIFGO INDEX            F2A02720
       CAS     ENA                  COMPARE G AND ENA                   F2A02730
       TRA     FL065                G GREATER, GO BACK FOR NEXT NEST.   F2A02740
       NOP                          G EQUAL TO                          F2A02750
       STO     G                    OR LESS THAN G, SAVE G.             F2A02760
       CLA     TIFZ,4               TEST FOR THREE ADDRESS IF.          F2A02770
       TMI     FL075                USE ADDRESS TO DETERMINE            F2A02780
       PAX     0,2                  WHETHER OR NOT THIS IS AN           F2A02790
       TXL     FL075,2,5            ASSIGN FORMULA. IF IT IS,           F2A02800
       TXL     FL055,2,6            IGNORE, TAKE NEXT TIFGO ENTRY       F2A02810
       TXL     FL075,2,7            TEST FOR ADD. GREATER THAN          F2A02820
       TSX     ERRORM,4             THE ADDRESS OF TIFGO WORD(XR VALUE  F2A02830
       REM                          IN TIFX) SHOULD BE 7 OR LESS.       F2A02840
       REM                          TIFGO IS FROM REC 6.FILE5 TAPE 2.   F2A02850
FL075  CLA     G                    OBTAIN G                            F2A02860
       LXD     BNX,1                OBTAIN CURRENT NEST INDEX           F2A02870
       TSX     ADLOC,4              OBTAIN XDG AND LDG                  F2A02880
       CLA     BITONE               PUT BIT IN DOTAG FOR TRA            F2A02890
       ORS     DOTGZ+6,1            IN IMMEDIATE RANGE                  F2A02900
       PXD     0,1                  SAVE                                F2A02910
       STO     XDG                  XDG                                 F2A02920
       PXD     0,2                  AND                                 F2A02930
       STO     LDG                  LDG                                 F2A02940
       CLS     G                    LIST MINUS G                        F2A02950
       TSX     TLT00,4              IN TRALEV BUFFER.                   F2A02960
       LXD     TIFX,4               OBTAIN FIRST WORD OF                F2A02970
       CLA     TIFZ,4               TIFGO ENTRY                         F2A02980
       TMI     3ADIF                TRA IF 3ADIF                        F2A02990
       PAX     0,2                  PUT ADDRESS IN XRB                  F2A03000
FL080  TRA     FL080+8,2            INDEXED TRA.                        F2A03010
       TSX     ERRORM,4             TIFGO ADDRESS IN XR2 IS SIX         F2A03020
       TRA     DT050                                                (20)F2A03030
       REM                          OR LESS. TIFGO WORD IS PICKED       F2A03040
       REM                          UP WITH XR VALUE IN TIFX.           F2A03050
       REM                          TIFGO IS REC 6 FILE 5 TAPE2.        F2A03060
       TRA     2ADIF                5, 2 ADDRESS TYPE                   F2A03070
       TRA     2ADIF                4, 2 ADIF                           F2A03080
       TRA     2ADIF                3, 2ADIF                            F2A03090
       TRA     GOTOVN               2 VECTOR TYPE TRA                   F2A03100
       TRA     GOTOVN               1 GO TO N (ASSIGN)                  F2A03110
       TRA     GOTOK                0 GO TO CONSTANT                    F2A03120
FL090  LXD     TIFX,4               GO BACK FOR NEXT                    F2A03130
       TXI     FL060,4,-2           TIFGO ENTRY.                        F2A03140
FLOEND LXD     TLT50,1              TEST IF ANY TRALEV ENTRIES          F2A03150
       TXL     SV00,1,0                                                 F2A03160
       TSX     TLT20,4              IF SO, GO TO WRITE ROUTINE          F2A03170
       TRA     SV00                                                     F2A03180
       REM CONTROL ROUTINES                                             F2A03190
3ADIF  ANA     ADDMSK               THE FOLLOWING ROUTINES              F2A03200
       ALS     18                   ARRANGE TO PROCESS ALL OF           F2A03210
       TSX     FA000,4              THE ADDRESSES ASSOCIATED            F2A03220
       LXD     TIFX,4               WITH THE TIFGO ENTRY,               F2A03230
2ADIF  CLA     TIFZ+1,4             ONE AT A TIME.                      F2A03240
       ANA     DECMSK               WHEN ALL ADDRESSES                  F2A03250
       TSX     FA000,4              ARE PROCESSED,                      F2A03260
       LXD     TIFX,4               CONTROL IS RETURED TO               F2A03270
GOTOK  CLA     TIFZ+1,4             FL090 FOR NEXT                      F2A03280
       ANA     ADDMSK               TIFGO ENTRY.                        F2A03290
       ALS     18                                                       F2A03300
       TSX     FA000,4                                                  F2A03310
       TRA     FL090                                                    F2A03320
GOTOVN CLA     TIFZ+1,4             FOR GOTOV TRANSFERS,                F2A03330
       PAX     0,4                  USE WORD TWO                        F2A03340
       SXD     GTV20,4              FOR INDEXING                        F2A03350
       PDX     0,4                  VALUES NECESSARY                    F2A03360
       TRA     GTV20                                                    F2A03370
GTV10  CLA     TRADZ,4              TO GET ADDRESSES                    F2A03380
       ALS     18                   FROM TABLE TRAD.                    F2A03390
       SXD     GTV30,4              FOR GOTON (ASSIGN) TYPE             F2A03400
       TSX     FA000,4              TRANSFERS, ALL ADDRESSES            F2A03410
       LXD     GTV30,4              MUST BE PROCESSED EVEN              F2A03420
       TXI     GTV20,4,-1           THOUGH THEY ARE ON SAME             F2A03430
GTV20  TXH     GTV10,4,0            LEVEL BECAUSE OF                    F2A03440
GTV30  TXL     FL090,,0             CARRY RESTRICTIONS.                 F2A03450
       REM ANALYSIS OF ADDRESS                                          F2A03460
FA000  SXD     RS60,4               SAVE TSX SET                        F2A03470
       TRA     FA000A                                               (20)F2A03480
       LXD     BNX,1                OBTAIN                              F2A03490
       TSX     ADLOC,4              INDEX OF DO CONTAINING              F2A03500
       PXD     0,1                  ADDRESS AND LEVEL OF                F2A03510
       STO     XDA                  THAT DO.                            F2A03520
       PXD     0,2                  SAVE IN                             F2A03530
       STO     LDA                  XDA AND LDA.                        F2A03540
       TXL     FA010,2,20           TEST LEVEL                          F2A03550
       TSX     ERROR3,4             LEVEL ADD. OF TRA EXCEEDS 20.       F2A03560
FA010  SXA     FA020,2                                                  F2A03570
       CAL     L(MZ)                LEVEL IN                            F2A03580
       LXD     XDG,1                XDG DO.                             F2A03590
FA020  ARS     **                                                       F2A03600
       ORS     DOTGZ+7,1                                                F2A03610
       CLA     LDA                  LIST                                F2A03620
       ARS     18                   ADDRESS AND LEVEL                   F2A03630
       ADD     A                    IN                                  F2A03640
       TSX     TLT00,4              TLT. CONTINUE WITH RS00             F2A03650
       REM TRANSFER BIT INSERTION IN DO FORMULA                         F2A03660
RS00   LXD     XDG,1                XRA CONTAINS XDG                    F2A03670
       LXD     LDG,2                XRB CONTAINS LDG                    F2A03680
RS10   PXD     0,2                  IF G AND A IN SAME DO,              F2A03690
       SUB     LDA                  EXIT. THIS ROUTINE INSERTS          F2A03700
       TZE     INC00                BIT MEANING THERE IS A JUMP         F2A03710
       TPL     RS20                 OUT OF THE RANGE OF THIS DO.        F2A03720
       LXD     TIFX,1                                                   F2A03730
       TSX     ERROR4,4             SOURCE PROGRAM ERROR.               F2A03740
RS20   CAL     L(MZ)                                                    F2A03750
       ORS     DOTGZ+5,1                                                F2A03760
       TXL     INC00,2,1            FIND NEXT BACK SUBNEST              F2A03770
RS30   TXI     RS40,1,9             DO FORMULA                          F2A03780
RS40   CLA     DOTGZ+5,1            AND RETURN                          F2A03790
       STD     RS50                 TO TEST                             F2A03800
RS50   TXL     RS30,2,0             LEVEL                               F2A03810
       PDX     0,2                  AT                                  F2A03820
RS60   TXL     RS10,,0              RS10                                F2A03830
       REM INDEXING NO CARRY CONDITION                                  F2A03840
INC00  CLA     LDA                  EXIT IF                             F2A03850
       TZE     RNC00                LDA IS ZERO.                        F2A03860
       CLA     G                    PLACE G ANDA                        F2A03870
       LDQ     A                    IN                                  F2A03880
       TLQ     INC20                INCX AND INCY SO THAT               F2A03890
       STO     INCX                 INCX IS LESS THAN INCY.             F2A03900
       STQ     INCY                                                     F2A03910
       TRA     INC30                                                    F2A03920
INC20  STQ     INCX                                                     F2A03930
       STO     INCY                                                     F2A03940
INC30  LXD     XDA,1                INITIALIZE XRA                      F2A03950
INC35  TXI     INC40,1,-9           FIND DO OF LEVEL LDA                F2A03960
INC40  TXL     RNC00,1,0            PLUS ONE.                           F2A03970
       CLA     DOTGZ+5,1                                                F2A03980
       ANA     DECMSK                                                   F2A03990
       SUB     LDA                                                      F2A04000
       SUB     L(1)                                                     F2A04010
       TZE     INC50                DO OF LEVEL LDA PLUS ONE FOUND.     F2A04020
       TPL     INC35                LEVEL TO HIGH, GO BACK.             F2A04030
       TRA     RNC00                LEVEL TO LOW, DA EXHAUSTED.         F2A04040
INC50  CLA     DOTGZ,1              OBTAIN BETA OF                      F2A04050
       PAX     0,2                  THIS DO IN DECREMENT.               F2A04060
       PXD     0,2                                                      F2A04070
       CAS     INCY                 COMPARE WITY INCY.                  F2A04080
       TRA     RNC00                GREATER THAN OR EQUAL TO            F2A04090
       TRA     RNC00                GREATEST OF G, A, EXIT.             F2A04100
       CAS     INCX                 LESS THAN INCY, COMPARE             F2A04110
       TRA     INC60                WITH INCX. GREATER THAN             F2A04120
       TRA     INC60                OR EQUAL TO INCX, GO TO INC60.      F2A04130
       TRA     INC35                LESS THAN INCX, GET NEXT DO.        F2A04140
INC60  CAL     NCMSK                AND OUT CARRY BITS.                 F2A04150
       ANS     DOTGZ+5,1                                                F2A04160
       TRA     INC35                GO BACK FOR NEXT DO.                F2A04170
INCX   PZE                          ES.                                 F2A04180
INCY   PZE                          ES.                                 F2A04190
       REM RESET NO CARRY CONDITION. NO CARRY TRANSFER LEVEL            F2A04200
RNC00  CLA     LDA                  EXIT IF LDA IS ZERO                 F2A04210
       TZE     RNC95                                                    F2A04220
       CLA     LDG                  EXIT IF                             F2A04230
       SUB     LDA                  LDA EQUALS                          F2A04240
       TZE     RNC95                LDG                                 F2A04250
       PDX     0,4                  INITIALIZE COUNTER XR6              F2A04260
       LXD     XDG,1                INITIALIZE XRA                      F2A04270
       CLA     LDG                  AND                                 F2A04280
       PDX     0,2                  XRB. C(ACC) LDG.                    F2A04290
       TXI     RNC50,2,1            C(XRB) LDG PLUS ONE.                F2A04300
RNC20  TXI     RNC30,1,9            FIND NEXT BACK                      F2A04310
RNC30  TXH     RNC95,1,600*M/N*9    SUBNEST DO.                         F2A04320
       CLA     DOTGZ+5,1                                                F2A04330
       STD     RNC40                                                    F2A04340
RNC40  TXL     RNC20,2,0                                                F2A04350
RNC50  SXD     RNC75,1              SAVE XRA                            F2A04360
       STD     RNC85                SAVE LEVEL OF THIS DO               F2A04370
       PXD     0,2                  SAVE LEVEL OF NEXT INNER            F2A04380
       STO     RNC90                SUBNEST DO.                         F2A04390
RNC60  TXI     RNC70,1,-9           TAKE NEXT DOWN DO IF ANY.           F2A04400
RNC70  TXL     RNC80,1,0                                                F2A04410
       CLA     DOTGZ,1              IF BETA                             F2A04420
       ANA     ADDMSK               OF THIS DO                          F2A04430
       ALS     18                   IS LESS                             F2A04440
       SUB     G                    THAN G,                             F2A04450
       TPL     RNC80                TEST LEVEL                          F2A04460
       CLA     DOTGZ+5,1            TO SEE IF                           F2A04470
       ANA     DECMSK               THIS DO IS OF SAME                  F2A04480
       SUB     RNC90                LEVEL AS NEXT INNERMOST             F2A04490
       TNZ     RNC60                SUBNEST DO. IF NOT, GET NEXT DO.    F2A04500
       CLA     DOTGZ+6,1            IF SO, MAKE NO CARRY                F2A04510
       ANA     DECMSK               TRANSFER LEVEL OF THIS              F2A04520
       SUB     LDA                  DO EQUAL TO GREATER                 F2A04530
       TPL     RNC60                OF PREVIOUS VALUE                   F2A04540
       CLA     LDA                  AND CURRENT LDA.                    F2A04550
       STD     DOTGZ+6,1                                                F2A04560
RNC75  TXL     RNC60,,0             GO BACK FOR NEXT TEST DO.           F2A04570
RNC80  LXD     RNC75,1              GO BACK FOR NEXT SUBNEST DO,        F2A04580
       LXD     RNC85,2              IF COUNTER PERMITS.                 F2A04590
       TIX     RNC20,4,1            OTHERWISE, EXIT.                    F2A04600
RNC85  TXL     RNC95,,0                                                 F2A04610
RNC90  PZE                          ES                                  F2A04620
RNC95  LXD     RS60,4               GO BACK TO CONTROL ROUTINE          F2A04630
       TRA     1,4                  FOR NEXT ADDRESS.                   F2A04640
       REM INDEX AND LEVEL OF ADDRESS                                   F2A04650
ADLOC  SXD     ADL20,4              SAVE TSX SET                        F2A04660
       LXD     L(0),4               INITIALIZE XRC,                     F2A04670
       SXD     ADL30,4              AND DEC OF ADL30, PUT ADDRESS       F2A04680
       STO     ADL90                IN ADL90. XRA CONTAINS BNX          F2A04690
ADL10  CLA     DOTGZ,1              OBTAIN FIRST WORD.                  F2A04700
       PAX     0,2                  SAVE BETA                           F2A04710
       ANA     DECMSK               GET ALPHA ALONE.                    F2A04720
       CAS     ADL90                COMPARE WITH ADDRESS. IF            F2A04730
ADL20  TXL     ADL70,,0             ALPHA NOT LESS THAN ADD, THEN       F2A04740
ADL30  TXL     ADL70,,0             ADD IN LAST CHOSEN DO.              F2A04750
       PXD     0,2                  IF ALPHA LESS THAN ADD,             F2A04760
       CAS     ADL90                COMPARE WITH BETA.                  F2A04770
       NOP                          IF BETA IS NOT LESS THAN            F2A04780
       TRA     ADL40                ADDRESS, THIS DO CONTAINS           F2A04790
       TXH     ADL50,4,0            ADDRESS. EXIT IF OUT OF NEST        F2A04800
       TRA     ADL70                TO ADL 70. OTHERWISE, GO TO 50      F2A04810
ADL40  SXD     ADL30,1              IF DO IN THIS NEST, SXD.            F2A04820
ADL50  TXI     ADL60,1,-9           IN ANY CASE, TAKE NEXT DOWN         F2A04830
ADL60  TXL     ADL70,1,0            DO, IF ANY.                         F2A04840
       CLA     DOTGZ+5,1            PUT LEVEL IN XRC.                   F2A04850
       PDX     0,4                  AND GO BACK FOR TEST                F2A04860
       TXH     ADL10,4,1            UNLESS NGW DO HAS LEVEL ONE.        F2A04870
ADL70  LXD     ADL30,3              OBTAIN XDA IN XRA, XRB.             F2A04880
       TXL     ADL80,1,0            EXIT IF ZERO.                       F2A04890
       CLA     DOTGZ+5,1            IF NOT ZERO, GET LDA IN             F2A04900
       PDX     0,2                  XRB, PUT                            F2A04910
ADL80  LXD     ADL20,4              TSX SET IN XRC                      F2A04920
       TRA     1,4                  AND RETURN.                         F2A04930
ADL90  PZE                                                              F2A04940
       REM TRALEV LISTING                                               F2A04950
TLT00  LXD     TRLCT,1              TEST IF TWO RECORDS OF              F2A04960
       TXL     *+2,1,1              TRALEV ALREADY WRITTEN.             F2A04970
       TSX     ERRO14,4             YES, SEC. 3 SPACE UNAVAILABLE.      F2A04980
       LDC     TLT50,1              OBTAIN CURRENT TRALEV               F2A04990
       STO     TRALEV,1             INDEX STORE ENTRY.                  F2A05000
       LXD     TLT50,1              UPDATE                              F2A05010
       TXI     *+1,1,1              WORD                                F2A05020
       SXD     TLT50,1              COUNT. IF TABLE FULL,               F2A05030
       TXH     TLT20,1,2400*M/N-1   GO TO WRITING ROUTINE.              F2A05040
       TRA     1,4                  OTHERWISE, RETURN.                  F2A05050
TLT20  SXA     TLT30,4              SAVE XRC.                           F2A05060
*      ***                                                              F2A05070
TLT200 TSX     (TAPE),4             WRITE                               F2A05080
       PZE     TLT50,,(WBNC)        THE TRALEV                          F2A05090
       PZE     TRLVL,,FTAPE4        BUFFER.                             F2A05100
       MSE     98                   TURN OFF TRALEV TAPE                F2A05110
       NOP                          EMPTY LITE.                         F2A05120
       AXT     0,1                  REINITIALIZE                        F2A05130
       SXD     TLT50,1              WORD COUNT OF TRALEV CONT WD.       F2A05140
       LXD     TRLCT,4              UPDATE TRALEV                       F2A05150
       TXI     *+1,4,1              RECORD COUNT                        F2A05160
       SXD     TRLCT,4              AND SAVE.                           F2A05170
TLT30  AXT     0,4                  RESTORE XRC.                        F2A05180
       TRA     1,4                  RETURN.                             F2A05190
TLT50  IOCT    TRALEV,,**          DSC COMMAND WD.                     $F2A05200
TRLVL  BCI     1,TRALEV                                                 F2A05210
TRLCT  PZE                                                              F2A05220
       REM ES FORFLOW                                                   F2A05230
BNX    PZE                          BEGINNING OF NEST INDEX.            F2A05240
BNA    PZE                          BEGINNING OF NEST ADDRESS.          F2A05250
ENA    PZE                          END OF NEST ADDRESS.                F2A05260
G      PZE                          GAMMA OF SOME TIFGO ENTRY.          F2A05270
XDG    PZE                          INDEX OF DO WITH G IN IMMED.        F2A05280
LDG    PZE                          RANGE. LEVEL OF XDG.                F2A05290
A      PZE                          AN ADD. TO WHICH G TRANSFERS.       F2A05300
XDA    PZE                          INDEX OF DO WITH A IN IMMED.        F2A05310
LDA    PZE                          RANGE. LEVEL OF XDA.                F2A05320
TIFX   PZE                          CURRENT TIFGO INDEX.                F2A05330
       REM DO SYMBOL DEFINITION OF VARIABLE RANGES AND INCREMENTS.      F2A05340
SV00   LXD     DOTAG-1,1                                                F2A05350
       SXD     SV80,1                                                   F2A05360
       SXD     SV95,1                                                   F2A05370
       SXD     TRA40,1                                                  F2A05380
       LXD     MAXDTG,1             INITIALIZE XRA                      F2A05390
       SXD     SV44,1               SAVE CURRENT DO INDEX               F2A05400
SV10   SXD     SV98,1               SAVE NEST INDEX                     F2A05410
SV20   CLA     DOTGZ,1              GET 1ST WD CURRENT                  F2A05420
       ANA     TAGMSK               DO AND INSPECT TAG.                 F2A05430
       TZE     SV90                 IF ZERO, GO TO INDEXING.            F2A05440
       LXD     SV98,4               OTHERWISE, NEST INDEX IN XRC.       F2A05450
SV30   CLA     DOTGZ+1,4            GET SYM OF XRG,                     F2A05460
       LXD     L(3),2               INITIALIZE XRB COUNTER              F2A05470
SV40   CAS     DOTGZ+4,1            AND TEST FOR SYM=VAR. N.            F2A05480
SV44   TXL     SV50,,0              CURRENT DO INDEX STORAGE.           F2A05490
SV48   TXL     SF00,,0              INDEX STO. OF N IN CUR. DO.         F2A05500
SV50   TXI     SV60,1,1             TAKE NEXT N, COUNT                  F2A05510
SV60   TIX     SV40,2,1             IN XRB AND GO BACK.                 F2A05520
SV65   LXD     SV44,1               SYM NOT VAR.N., PUT CURRENT         F2A05530
SV70   TXI     SV80,4,-9            DO INDEX IN XRA AND INDEX           F2A05540
SV80   TXL     SV90,4,0             XRC. IF TABLE ENDS, GO TO SV90.     F2A05550
       CLA     DOTGZ+5,4            OTHERWISE, TEST FOR NEW NEST.       F2A05560
       PDX     0,2                  IF NOT NEW NEST, GO BACK TO         F2A05570
       TXH     SV30,2,1             TEST SYM. OTHERWISE.                F2A05580
SV90   TXI     SV95,1,-9            TAKE NEXT DOWN DO IF                F2A05590
SV95   TXL     TS4VAL,1,0           POSSIBLE. OTHERWISE, EXIT.          F2A05600
       SXD     SV44,1               SAVE CURRENT DO INDEX.              F2A05610
       CLA     DOTGZ+5,1                                                F2A05620
       PDX     0,2                  INSPECT LEVEL.                      F2A05630
       TXH     SV20,2,1             IF NOT NEW NEST, TRA SV20           F2A05640
SV98   TXL     SV10,,0              IF NEW NEST, SV10 (NEST INDEX STO.) F2A05650
SF00   SXD     SV48,1               SAVE INDEX OF N IN CURRENT DO.      F2A05660
       SXD     SF10,2               SAVE N COUNTER.                     F2A05670
       SXD     SF15,4                                                   F2A05680
       PXD     0,4                  SAVE INDEX OF SYMBOL DO             F2A05690
       STO     SFES1                IN FULL WORD.                       F2A05700
       LXD     SV44,1               OBTAIN INDEX OF CURRENT DO          F2A05710
       PXD     0,1                  IN ACC. AND COMPARE                 F2A05720
       CAS     SFES1                WITH INDEX OF SYMBOL DO.            F2A05730
SF10   TXL     SF20,,0              CURRENT INDEX GREATER.              F2A05740
       TRA     SF79                 EQUALITY                            F2A05750
       PSE     97                   SYMBOL INDEX GREATER,               F2A05760
SF15   TXL     SF30,,0              TURN ON LIGHT 97.                   F2A05770
SF20   LXD     SV44,4               CUR. IND. GREATER, PUT IN XRC       F2A05780
       LXD     SFES1,1              SYM. IND. IN XRA.                   F2A05790
       MSE     97                   LIGHT 97 OFF.                       F2A05800
       NOP                          AT SF30, XRA CONTAIN LEAST          F2A05810
SF30   PXD     0,4                  OF CUR. IND, SYM. IND. XRC          F2A05820
       STO     SFES1                CONTAINS GREATER. PUT IN ES.        F2A05830
SF35   CLA     DOTGZ+5,1            PUT LEVEL OF D(XRA) IN              F2A05840
       PDX     0,2                  XRB. HALT IF                        F2A05850
       TXH     SF40,2,1             LEVEL                               F2A05860
       TSX     ERRORM,4             AN INNER DO HAS LEVEL OF 1.         F2A05870
       REM                          SIXTH WD OF DOTAG ENTRY (XR         F2A05880
       REM                          VALUE IN SFES1) HAS LEVEL IN        F2A05890
       REM                          DECR. THIS WORD IS FORMED IN CORE.  F2A05900
SF40   TXI     SF50,1,9             BACK UP IN XRA                      F2A05910
SF50   TXL     SF60,1,600*M/N*9     ERROR IF TOP OF                     F2A05920
       TSX     ERRORM,4             DOTAG PASSED. IF LEVEL OF DO        F2A05930
       REM                          (XR VALUE IN SFES1) IS OVER 1,      F2A05940
       REM                          THERE MUST BE ANOTHER DO            F2A05950
       REM                          BEFORE THE END OF THE DOTAG TABLE.  F2A05960
SF60   CLA     DOTGZ+5,1            THIS ROUTINE BY RAISING             F2A05970
       STD     SF70                 XRA, EXITS TO SF80 OR               F2A05980
SF70   TXL     SF40,2,0             SF90 UPON FINDING A DO.             F2A05990
       PXD     0,1                  IN THE SUBNEST OF XRA               F2A06000
       CAS     SFES1                WHICH IS THE DO OF XRC OR           F2A06010
       TRA     SF73                 CONTAINS THE DO OF XRC              F2A06020
       TRA     SF80                 AND CURRENT DO.                     F2A06030
       TRA     SF35                 GO BACK FOR NEXT DO                 F2A06040
SF73   SXD     SF76,1               THIS ROUTINE (THROUGH SF76)         F2A06050
SF74   LXD     SF15,1                                                   F2A06060
       TSX     TRA00,4              USES TRA00                          F2A06070
       TZE     SFEND                                                    F2A06080
       STO     SF78                 TO DETERMINE THE                    F2A06090
       LXD     SF76,1               GREATEST EXIT LEVEL OF              F2A06100
       CLA     DOTGZ+5,1            DEFINITION FROM A                   F2A06110
       ANA     DECMSK               DO SYM NOT IN THE                   F2A06120
       CAS     SF78                 SUBNEST OF A DO WITH                F2A06130
       CLA     SF78                 VARIABLE NS, BUT IN A               F2A06140
       NOP                          SUBNEST WHICH HAS A                 F2A06150
SF76   TXL     SF90,,0              NON EMPTY INTERSECTION              F2A06160
SF78   PZE                          WITH THAT SUBNEST.                  F2A06170
SF79   CLA     DOTGZ+5,1                                                F2A06180
       ANA     DECMSK                                                   F2A06190
       SUB     L(1)                                                     F2A06200
       TNZ     SF90                                                     F2A06210
       TRA     SFEND                                                    F2A06220
SF80   MSE     97                   EQUALITY, IF SYM DO IS              F2A06230
       TSX     ERROR5,4             SOURCE PROGRAM ERROR.               F2A06240
       CLA     BITONE                                                   F2A06250
       ORS     DOTGZ+5,1                                                F2A06260
       CLA     DOTGZ+5,1            GET LEVEL OF DEFINITION             F2A06270
       ANA     DECMSK               AND STORE                           F2A06280
SF90   ARS     18                   IN ADDRESS PART                     F2A06290
       STO     SFES1                OF SFESI.                           F2A06300
       LXD     SV48,1               INDEX OF VAR.N. IN CUR. DO.         F2A06310
       CLA     DOTGZ+8,1            GET PREVIOUS LEVEL DEF.             F2A06320
       ANA     ADDMSK               AND COMPARE                         F2A06330
       CAS     SFES1                WITH NEW.                           F2A06340
       TRA     SFEND                EXIT UNLESS                         F2A06350
       TRA     SFEND                NEW LEV.                            F2A06360
       CLA     SFES1                IS LARGGER, IN WHICH CASE           F2A06370
       STA     DOTGZ+8,1            REPLACE OLD WITH NEW                F2A06380
       LXD     SF10,2               OBTAIN N COUNTER IN XRB             F2A06390
SF92   CLA     DOTGZ+4,1            GET VAR. N IN ACC.                  F2A06400
       TRA     SF96                 GO TO INDEXING.                     F2A06410
SF94   CAS     DOTGZ+4,1            COMPARE TO FIND DUPE                F2A06420
       TRA     SF96                 N S.                                F2A06430
       TRA     SF99                 DUPE FOUND.                         F2A06440
SF96   TXI     SF98,1,1             INDEX IN DO FORMULA                 F2A06450
SF98   TIX     SF94,2,1             AND IN COUNTER                      F2A06460
       TRA     SFEND                                                    F2A06470
SF99   CLA     SFES1                REPLACE                             F2A06480
       STA     DOTGZ+8,1            OLD LEVEL                           F2A06490
       TRA     SF92                 OF DEFINITION.                      F2A06500
SFEND  LXD     SF15,4               GO BACK FOR NEXT                    F2A06510
       TRA     SV65                 SYMBOL DO                           F2A06520
SFES1  PZE                          ES.                                 F2A06530
       REM  GREATEST TRANSFER LEVEL OUT OF DO FORMULA                   F2A06540
TRA00  CLA     DOTGZ+5,1            GET LEVEL OF DO                     F2A06550
       PDX     0,2                  USE MAX LEV TWENTY                  F2A06560
TRA10  TXL     TRA20,2,20                                               F2A06570
       LXD     TRA10,2                                                  F2A06580
TRA20  SXD     TRA50,2              INITIALIZE TEST INSTR.              F2A06590
       PXD     0,2                  COMPUTE LEVEL MINUS ONE             F2A06600
       ARS     18                   AND INITIALIZE SHIFT INSTR.         F2A06610
       SUB     TRAN1                COMPUTE 35 MINUS (L MINUS           F2A06620
       STA     TRA70                ONE) AND                            F2A06630
       SUB     TRAN2                INITIALIZE                          F2A06640
       STA     TRA80                SHIFT INSTR.                        F2A06650
       PXD     0,0                  INITIALIZE                          F2A06660
       STO     TRAN5                ES LOCATION TO ZERO                 F2A06670
TRA30  CAL     DOTGZ+7,1            OR INTO TRAN5 ALL THE               F2A06680
       ORS     TRAN5                T2 WORDS OF THIS DO                 F2A06690
       TXI     TRA40,1,-9           AND ALL DOS CONTAINED               F2A06700
TRA40  TXL     TRA60,1,0            BY THIS DO.                         F2A06710
       CLA     DOTGZ+5,1                                                F2A06720
       PDX     0,2                                                      F2A06730
TRA50  TXH     TRA30,2,0                                                F2A06740
TRA60  LDQ     TRAN4                PUT MASK IN QUOTIENT                F2A06750
TRA70  LLS     **                   REGISTER, SHIFT COMPUTED            F2A06760
TRA80  ALS     **                   AMOUNTS TO CONSTRUCT                F2A06770
       ANA     TRAN5                MASK IN ACC. AND IN                 F2A06780
       TZE     TRA95                UNION OF T2 WORDS. EXIT IF ZERO.    F2A06790
       SLW     TRAN5                OBTAIN LOW ORDER BIT            (23)F2A06800
       SUB     TRAN1                IN ACC.                             F2A06810
       STO     TRAN6                                                    F2A06820
       ORA     TRAN5                                                    F2A06830
       SUB     TRAN6                                                    F2A06840
       LXD     L(1),1                                                   F2A06850
TRA85  CAS     TRATAB+19,1          SEARCH TABLE                        F2A06860
       TRA     TRA86                TO OBTAIN                           F2A06870
       TRA     TRA90                LEVEL INTEGER                       F2A06880
TRA86  TXI     TRA87,1,1                                                F2A06890
TRA87  TXL     TRA85,1,19                                               F2A06900
       TRA     TRA88                GO TO PATCH                     (23)F2A06910
TRA90  PXD     0,1                  PUT LEVEL IN ACC DECREMENT          F2A06920
TRA95  TRA     1,4                  EXIT.                               F2A06930
TRAN1  HTR     1                                                        F2A06940
TRAN2  HTR     35                                                       F2A06950
TRAN4  OCT     377777777777                                             F2A06960
TRAN5  PZE                                                              F2A06970
TRAN6  PZE                                                              F2A06980
TRATAB OCT     200000                                                   F2A06990
       OCT     400000                                                   F2A07000
       OCT     1000000                                                  F2A07010
       OCT     2000000                                                  F2A07020
       OCT     4000000                                                  F2A07030
       OCT     10000000                                                 F2A07040
       OCT     20000000                                                 F2A07050
       OCT     40000000                                                 F2A07060
       OCT     100000000                                                F2A07070
       OCT     200000000                                                F2A07080
       OCT     400000000                                                F2A07090
       OCT     1000000000                                               F2A07100
       OCT     2000000000                                               F2A07110
       OCT     4000000000                                               F2A07120
       OCT     10000000000                                              F2A07130
       OCT     20000000000                                              F2A07140
       OCT     40000000000                                              F2A07150
       OCT     100000000000                                             F2A07160
       OCT     200000000000                                             F2A07170
       REM FORVAL TABLE SEARCH FOR VARIABLE RANGES AND INCREMENTS       F2A07180
*      ***                                                              F2A07190
TS4VAL TSX     (TAPE),4             READ                                F2A07200
       PZE     4VALAD,,(RBNC)       IN                                  F2A07210
       PZE     4VALL,,FTAPE2        FORVAL.                             F2A07220
*      ***                                                              F2A07230
       LXA     (SCHU)+FTAPE2,2      COMPUTE                             F2A07240
       SXD     TBLEND,2             NEXT                                F2A07250
       AXT     0,2                  GO TO                               F2A07260
       TSX     CHECK,4              CHECK READ.                         F2A07270
       LXA     4VALAD+1,2           UNUSED                              F2A07280
       PXD     0,2                  INDEX                               F2A07290
       ADD     4VALAD+1             AND                                 F2A07300
       SUB     TBLEND               PLACE                               F2A07310
       PDX     0,1                  IN XR.                              F2A07320
       SXD     FORVAL-1,1           SAVE INDEX.                         F2A07330
       TXL     TSV10,1,2000*M/N*2-1                                     F2A07340
       PSE     100                  IF FORVAL EMPTY, SET                F2A07350
       TRA     T190                 SENSE LIGHT AND EXIT                F2A07360
TSV10  SXD     TS40,1               INITIALIZE TEST INSTRS.             F2A07370
       SXD     TS75,1                                                   F2A07380
       MSE     99                   TEST FOR EMPTY DOTAG                F2A07390
       TRA     TSV20                OFF, NOT EMPTY                      F2A07400
       PSE     99                   ON, DOTAG EMPTY                     F2A07410
       TRA     T190                 EXIT                                F2A07420
TSV20  LXD     DOTAG-1,1            DOTAG TEST INITIALIZING             F2A07430
       SXD     TS35,1                                                   F2A07440
       LXD     MAXDTG,1             INITIALIZE XRA                      F2A07450
       LXD     MAXFVL,4             AND                                 F2A07460
       SXD     XFOR,4               XFOR. CONTINUE WITH TS00            F2A07470
TS00   MSE     97                   SENSE LIGHT 97 OFF                  F2A07480
       NOP                                                              F2A07490
TS10   CLA     DOTGZ+5,1            GET LEVEL OF CURRENT                F2A07500
       PDX     0,2                  DO IN XRB. IF L IS ONE,             F2A07510
       TXL     TS15,2,1             GO TO NEST PROCEDURE. IF            F2A07520
       MSE     97                   L IS NOT ONE AND LIGHT IS           F2A07530
       TRA     TS30,0               OFF, GO TO INNER DO PRECEDURE.      F2A07540
       PSE     97                   IF LIGHT IS ON, CONTINUE            F2A07550
       TXI     TS35,1,-9            INDEXING FOR NEXT NEST.             F2A07560
TS15   MSE     97                                                       F2A07570
       NOP                                                              F2A07580
       CLA     DOTGZ,1              L IS ONE, DO NEST PROCEDURE.        F2A07590
       PAX     0,2                  ESTABLISH BEGINNING OF              F2A07600
       ANA     DECMSK               NEST ADDRESS BNA, AND               F2A07610
       STO     TBNA                 END OF NEST ADDRESS ENA.            F2A07620
       PXD     0,2                  SEARCH IN FORTAG UNTIL              F2A07630
       STO     TENA                 FOR NRS. FOUND GREATER              F2A07640
       LXD     XFOR,4               THAN ENA. IF NONE, EXIT             F2A07650
       CLA     TBNA                 FROM ENTIRE ROUTINE.                F2A07660
TS20   CAS     4VALZ,4              TEST WHETHER FIRST SUCH             F2A07670
       TXI     TS40,4,-2            NR. IS IN NEST IF NOT,              F2A07680
       TSX     ERRORM,4             THE DECR OF FIRST WD OF XR1         F2A07690
       REM                          DOTAG ENTRY IS THE IFN OF THE       F2A07700
       REM                          DO STATEMENT, AND SHOULD NOT        F2A07710
       REM                          BE EQUAL TO THE FORVAL IFN          F2A07720
       REM                          (DECR OF WD WITH XR VALUE           F2A07730
       REM                          IN TBNA). 4VAL IS REC9 FILE5 TP2    F2A07740
       SXD     XFOR,4               GO TO INDEXING INSTRS.              F2A07750
       CLA     TENA                 FOR NEXT DO.                        F2A07760
       SUB     4VALZ,4                                                  F2A07770
       TPL     TS25                                                     F2A07780
       PSE     97                   RECORD NO FORVAL FALLS IN THIS NEST.F2A07790
TS25   TXI     TS35,1,-9                                                F2A07800
TS30   CLA     DOTGZ,1              INNER DO PROCEDURE                  F2A07810
       ANA     TAGMSK               TEST FOR NON ZERO TAG,              F2A07820
       TNZ     TS50                 IN WHICH CASE TRA FOR               F2A07830
TS33   TXI     TS35,1,-9            TABLE SEARCH. OTHERWISE,            F2A07840
TS35   TXH     TS10,1,0             INDEX FOR NEXT DO, IF POSSIBLE.     F2A07850
TS38   TXL     T190,,0              EXIT,STORAGE FOR INDEX CUR. DO.     F2A07860
TS40   TXH     TS20,4,0             INDEX TEST FOR FORVAL.              F2A07870
       TRA     T190                 EXIT                                F2A07880
TS50   SXD     TS38,1               SAVE INDEX OF CURRENT DO            F2A07890
       SXD     T110,2               SAVE LEVEL OF CURRENT DO            F2A07900
       LXD     XFOR,4               OBTAIN FORVAL INDEX IN XRC          F2A07910
TS55   LXD     L(3),2               PUT THREE IN XRC                    F2A07920
       LXD     TS38,1               CURRENT DO IN XRA                   F2A07930
       CLA     TENA                 TEST FOR END OF NEST                F2A07940
       SUB     4VALZ,4                                                  F2A07950
       TMI     TS33                 NOT IN NEST,TRA FOR NEXT DO.        F2A07960
       CLA     4VALZ+1,4            IN NEST OBTAIN FORTAG               F2A07970
TS60   CAS     DOTGZ+4,1            SYMBOL, COMPARE WITH VAR.           F2A07980
       TRA     TS65                 N SYMBOLS.                          F2A07990
       TRA     TS80                 EQUALITY                            F2A08000
TS65   TXI     TS70,1,1             INDEX IN XRA,                       F2A08010
TS70   TIX     TS60,2,1             COUNT IN XRB                        F2A08020
       TXI     TS75,4,-2            TAKE NEXT FORTAG ENTRY,             F2A08030
TS75   TXH     TS55,4,0             IF ANY.                             F2A08040
       LXD     TS38,1               RESTORE CURRENT DO INDEX            F2A08050
       TXI     TS35,1,-9            AND TRA FOR NEXT DO.                F2A08060
TS80   SXD     T148,2               SAVE VAR. N. COUNTER.               F2A08070
       SXD     T144,1               SAVE COUNTER OF SYM IN DO           F2A08080
       LXD     TS38,1               CURRENT DO INDEX IN XRA             F2A08090
       LXD     T110,2               CURRENT DO LEVEL IN XRB             F2A08100
       TXI     TS85,2,1             ADJUST XRB FOR CURRENT DO TEST.     F2A08110
TS85   CLA     DOTGZ+5,1            GET NEXT BACK DO IN                 F2A08120
       STD     TS90                 SUBNEST. ON FIRST TIME              F2A08130
TS90   TXH     T100,2,0             THROUGH, CURRENT DO IS              F2A08140
TS92   TXI     TS85,1,9             PRODUCED.                           F2A08150
TS94   TIX     TS92,2,1             ADJUST LEVEL.                       F2A08160
       TSX     ERRORM,4             LEVEL OF CURRENT DO (IN XR2)        F2A08170
       REM                          SHOULD BE MORE THAN LEVEL OF        F2A08180
       REM                          BACK DO IN SAME NEST (DECR OF       F2A08190
       REM                          SIXTH WD OF DOTAG ENTRY WITH        F2A08200
       REM                          XR VALUE IN XR1.                    F2A08210
T100   CLA     DOTGZ,1              NEXT BACK DO FOUND.                 F2A08220
       ANA     DECMSK               TEST TO SEE IF FORTAG               F2A08230
       SUB     4VALZ,4              FORMULA NR. IS IN THIS              F2A08240
       TPL     TS94                 DO. IF NOT, GO TO TS94              F2A08250
       CLA     DOTGZ,1              TO ADJUST LEVEL FOR                 F2A08260
       ANA     ADDMSK               OBTAINING NEW SUBNEST DO.           F2A08270
       ALS     18                                                       F2A08280
       SUB     4VALZ,4                                                  F2A08290
       TMI     TS94                                                     F2A08300
T110   TXL     T120,2,0             DEC CONTAINS CURRENT LEVEL.         F2A08310
       TRA     T170                 APPARENT DEF OF A VAR N WITHIN      F2A08320
       REM               RANGE OF THE DO WITH VARIABLE N. IGNORE AND    F2A08330
       REM               GET NEXT FORVAL.                               F2A08340
T120   LXD     T144,1               PUT CUR. VAR. DO INDEX IN           F2A08350
       CLA     DOTGZ+8,1            XRA, AND GET LEV. DEF               F2A08360
       PAX     0,2                  OF VAR. N.                          F2A08370
       SXD     T130,2               STORE IN DEC OF T130.               F2A08380
       LXD     TS90,2               OBTAIN LEVEL OF DO CONTAINING       F2A08390
T130   TXL     T170,2,0             FORTAG FOR. NR.                     F2A08400
       PXD     0,2                  CHOOSE LARGER AND PUT IN            F2A08410
       ARS     18                   LEV. DEF. FIELD OF CURRENT DO.      F2A08420
       STA     DOTGZ+8,1            IF CHANGE MADE, SAVE                F2A08430
       STO     T195                 LEVEL,                              F2A08440
       LXD     T148,2               AND TEST TO SEE IF THIS             F2A08450
       CLA     DOTGZ+4,1            SYMBOL                              F2A08460
       TXI     T160,1,1             DUPLICATED                          F2A08470
T140   CAS     DOTGZ+4,1            IN DO VAR. N S.                     F2A08480
T144   TXL     T150,,0              IF SO, REPLACE LEVEL OF DEF.        F2A08490
T148   TXL     T180,,0              BY THIS. DEC OF T144 HAS IX FOR     F2A08500
       REM                          VAR N, AND DEC OF T148 HAS 3,2,1    F2A08510
       REM                          IF 4VAL MATCHES N3,N2,N1.           F2A08520
       REM               MATCHES VARIABLE N3,N2,N1)                     F2A08530
T150   TXI     T160,1,1             NEW LEVEL.                          F2A08540
T160   TIX     T140,2,1                                                 F2A08550
T170   TXI     TS75,4,-2                                                F2A08560
T180   CLA     T195                                                     F2A08570
       STA     DOTGZ+8,1                                                F2A08580
       CLA     DOTGZ+4,1                                                F2A08590
       TXI     T160,1,1                                                 F2A08600
T190   TRA     RH00                 EXIT                                F2A08610
T195   PZE                          ES                                  F2A08620
XFOR   PZE                          FORTAG INDEX                        F2A08630
TBNA   PZE                          ES                                  F2A08640
TENA   PZE                          ES                                  F2A08650
4VALAD IOCP    TBCHK,,2                                                 F2A08660
       IORT    FORVAL,,2000*M/N*2                                       F2A08670
       REM USE OF SYMBOL WITHIN RANGE AS FXD POINT VAR. FORVAR SEARCH.  F2A08680
*      ***                                                              F2A08690
RH00   TSX     (TAPE),4             READ                                F2A08700
       PZE     4VARAD,,(RBNC)       IN                                  F2A08710
       PZE     4VARL,,FTAPE2        FORVAR.                             F2A08720
*      ***                                                              F2A08730
       LXA     (SCHU)+FTAPE2,2      COMPUTE                             F2A08740
       SXD     TBLEND,2             NEXT                                F2A08750
       AXT     1,2                  GO TO                               F2A08760
       TSX     CHECK,4              CHECK READ.                         F2A08770
       LXA     4VARAD+1,2           UNUSED                              F2A08780
       PXD     0,2                  INDEX                               F2A08790
       ADD     4VARAD+1             AND                                 F2A08800
       SUB     TBLEND               PLACE                               F2A08810
       PDX     0,1                  IN XR.                              F2A08820
       SXD     FORVAR-1,1           SAVE INDEX.                         F2A08830
       TXH     RH95,1,3000*M/N*2-1  EXIT IF FORVAR IS EMPTY.            F2A08840
       MSE     99                   TEST FOR EMPTY DOTAG.               F2A08850
       TRA     RH05                 NOT EMPTY.                          F2A08860
       PSE     99                   EMPTY, RESTORE SENSE LIGHT          F2A08870
       TRA     RH95                 AND EXIT.                           F2A08880
RH05   SXD     RH60,1               FORVAR TEST                         F2A08890
       SXD     RH75,1               INITIALIZING.                       F2A08900
       LXD     DOTAG-1,1            DOTAG TEST                          F2A08910
       SXD     RH90,1               INITIALIZING                        F2A08920
       LXD     MAXFVR,1             MAX WDS IN FORVAR                   F2A08930
       SXD     RHNNX,1              IN NEXT NEST INDEX.                 F2A08940
       MSE     97                   TURN LIGHT 97 OFF.                  F2A08950
       NOP                                                              F2A08960
       LXD     MAXDTG,1             PUT MAX WDS IN DOTAG IN XRA         F2A08970
RH10   CLA     DOTGZ,1              GET 1ST DOTAG WORD.                 F2A08980
       PAX     0,2                  SEPARATE ALPHA AND BETA,            F2A08990
       ANA     DECMSK               STORE IN RFIRST AND RLAST.          F2A09000
       STO     RFIRST                                                   F2A09010
       PXD     0,2                                                      F2A09020
       STO     RLAST                                                    F2A09030
       CLA     DOTGZ+5,1            GET LEVEL IN XRB.                   F2A09040
       PDX     0,2                                                      F2A09050
       TXH     RH30,2,1             TRA IF LEVEL GREATER THAN ONE.      F2A09060
       MSE     97                   LEVEL IS ONE, TEST WHETHER,         F2A09070
       TRA     RH20                 ON LAST LEVEL ONE, FORVAR           F2A09080
       TRA     RH95                 EXHAUSTED. IF SO, EXIT.             F2A09090
RH20   LXD     RHNNX,4              OTHERWISE, ADJUST FORVAR            F2A09100
       SXD     RHCNX,4              INDEX TO SKIP LAST NEST AREA.       F2A09110
RH30   LXD     RHCNX,4              PUT FORVAR INDEX IN XRC.            F2A09120
       CLA     RFIRST               BEGIN SEARCH FOR FIRST              F2A09130
RH40   CAS     4VARZ,4              FORVAR ENTRY IN RANGE.              F2A09140
       TXI     RH60,4,-2                                                F2A09150
       TSX     ERRORM,4             MACHINE ERROR. THE XR4 FORVAR       F2A09160
       REM                          ENTRY IS AN IFN WHICH CANNOT BE     F2A09170
       REM                          EQUAL TO THE IFN OF XR1 DOTAG ENTRY F2A09180
       REM                          FROM WHICH RFIRST IS TAKEN. FORTAG  F2A09190
       REM                          IS REC. 11 FILE 5 TP2, AND DOTAG    F2A09200
       REM                          IFN IS ON TP2 AS TDO(REC 8 FILE 5). F2A09210
       SXD     RHCNX,4              SAVE INDEX AT THIS POINT            F2A09220
RH50   CLA     RLAST                FOR NEXT DO, AND COMPARE            F2A09230
       CAS     4VARZ,4              FORVAR ENTRY WITH RLAST             F2A09240
       NOP                                                              F2A09250
       TRA     RH70                 TRA, IN RANGE.                      F2A09260
       TRA     RH80                 TRA, NOT IN RANGE.                  F2A09270
RH60   TXH     RH40,4,0             IF NO ENTRIES GREATER               F2A09280
       TRA     RH95                 THAN RFIRST, EXIT.                  F2A09290
RH70   CLA     DOTGZ+1,1            IN RANGE, COMPARE SYMBOLS.          F2A09300
       SUB     4VARZ+1,4            IF EQUAL, PUT BIT IN                F2A09310
       TNZ     RH72                 DOTAG ENTRY.                        F2A09320
       CLA     BITONE                                                   F2A09330
       ORS     DOTGZ+5,1                                                F2A09340
       TXH     RH85,2,1                                                 F2A09350
RH72   TXI     RH75,4,-2            INDEX FORVAR AND GO BACK,           F2A09360
RH75   TXH     RH50,4,0             IF POSSIBLE. OTHERWISE,             F2A09370
       TXH     RH85,2,1             TEST LEVEL. IF LEVEL IS             F2A09380
       PSE     97                   ONE, ARRANGE TO EXIT WHEN           F2A09390
       TRA     RH85                 NEXT LEVEL ONE ENCOUNTERED.         F2A09400
RH80   TXH     RH85,2,1             NOT IN RANGE, TEST LEVEL.           F2A09410
       SXD     RHNNX,4              SET NEXT NEST INDEX IF L IS ONE.    F2A09420
RH85   TXI     RH90,1,-9            INDEX IN DOTAG AND GO               F2A09430
RH90   TXH     RH10,1,0             BACK, IF POSSIBLE.                  F2A09440
RH95   TRA     LB00                 EXIT                                F2A09450
RHNNX  PZE                          NEXT NEST INDEX.                    F2A09460
RHCNX  PZE                          CURRENT NEST INDEX.                 F2A09470
RFIRST PZE                          ALPHA ADDRESS.                      F2A09480
RLAST  PZE                          BETA ADDRESS.                       F2A09490
4VARAD IOCP    TBCHK,,2                                                 F2A09500
       IORT    FORVAR,,3000*M/N*2                                       F2A09510
       REM TRANSFER IN EXTENDED RANGE BIT.                              F2A09520
LB00   MSE     99                   TEST FOR EMPTY DOTAG                F2A09530
       TRA     DOTRAN         GO TO TEST FOR ILLEGAL TRA INTO DO    (20)F2A09540
       PSE     99                   ON, EMPTY, RESET LIGHT              F2A09550
       TRA     EB00                 AND EXIT                            F2A09560
LB02   LXD     DOTAG-1,1            OBTAIN NEXT UNUSED INDEX            F2A09570
LB05   TXL     LB60,,0                                                  F2A09580
LB10   CLA     DOTGZ+6,1                                                F2A09590
       TMI     LB60                 TEST SIGN, TRA IF NEG.              F2A09600
       ANA     BITONE               TEST FOR TRA IN IMMED. RANGE.       F2A09610
       TZE     LB60                 IF NONE,TRA.                        F2A09620
       SXD     LB05,1               SAVE XRA                            F2A09630
       CLA     DOTGZ+5,1            PUT LEVEL                           F2A09640
       PDX     0,2                  IN XRB                              F2A09650
LB20   CAL     LMSK                 OR IN                               F2A09660
       ORS     DOTGZ+6,1            MSK                                 F2A09670
       TXL     LB50,2,1             EXIT IF LEVEL ONE.                  F2A09680
LB25   TXI     LB30,1,9             FIND NEXT BACK                      F2A09690
LB30   CLA     DOTGZ+5,1            SUBNEST DO.                         F2A09700
       STD     LB40                                                     F2A09710
LB40   TXL     LB25,2,0                                                 F2A09720
       PDX     0,2                  SAVE NEW LEVEL IN XRB.              F2A09730
       CLA     DOTGZ+6,1            TEST SIGN OF WORD T1.               F2A09740
       TPL     LB20                 IF PLUS GO TO PUT IN MSK.           F2A09750
LB50   LXD     LB05,1               IF NOT, FIND NEXT DO                F2A09760
LB60   TXI     LB70,1,9             IN MAIN PASS.                       F2A09770
LB70   TXL     LB10,1,600*M/N*9     EB00 FOLLOWS.                       F2A09780
*END O F BLOCK ROUTINE. WR DOTAG ON TP , ONE NEST PER RECORD.           F2A09790
EB00   SLT     3                                                        F2A09800
       TRA     EB10                 OFF, NOT EMPTY                      F2A09810
       PSE     99                   ON, EMPTY, RESTORE AND TRA.         F2A09820
       TRA     EB50                                                     F2A09830
EB10   LXD     DOTAG-1,1            INITIALIZE TEST INSTR.              F2A09840
       SXD     EB40,1               AND                                 F2A09850
       SXD     EB48,1                                                   F2A09860
       LXD     MAXDTG,1             XRA                                 F2A09870
       CLA     DOAD                 INITIALIZE COMMAND                  F2A09880
       STA     EBCOM1               ADDRESS,                            F2A09890
       RIR     1                    AND SWITCH.                         F2A09900
EB20   AXT     0,4                  CLEAR COUNTER FOR W.C. IN COMMAND   F2A09910
EB30   TXI     *+1,4,9              BUMP FOR ONE DOTAG ENTRY.           F2A09920
       TXI     *+1,1,-9             BUMP DOTAG XR.                      F2A09930
EB40   TXL     EB45,1,0             DEC HAS DOTAG IX                    F2A09940
       CLA     DOTGZ+5,1            GET LEVEL OF DO                     F2A09950
       PDX     0,2                  INTO XRB AND IF                     F2A09960
       TXH     EB30,2,1             LEVEL IS GREATER THAN 1, GO TO BUMP F2A09970
EB45   LXD     EBCOM1,2             SAVE LAST ADDRESS+1.                F2A09980
       SXA     NSTAD,2                                                  F2A09990
       SXD     EBCOM1,4             SET W.C. OF COMMAND.                F2A10000
EB455  RNT     1                                                        F2A10010
       TRA     EB46                 FIRST TIME ONLY TRA. - SWITCH.      F2A10020
       CLA     NSTAD                COMPUTE NEXT ADDRESS.               F2A10030
       ADM     EBCOM1                                                  $F2A10040
       ADD     L(1)                                                     F2A10050
       STA     EBCOM1                                                   F2A10060
EB46   SIR     1                    SET SWITCH.                         F2A10070
*      ***                                                              F2A10080
EB47   TSX     (TAPE),4             WRITE ONE                           F2A10090
       PZE     EBCOM1,,(WBNP)       NEST OF                             F2A10100
       PZE     DTGL,,FTAPE3         DOTAGA.                             F2A10110
EB48   TXH     EB20,1,0             IF END DOTAG, EXIT                  F2A10120
*      ***                                                              F2A10130
EB50   TSX     (TAPE),4             WRITE EOF                           F2A10140
       PZE     ,,(WEFP)             FOR DOTAG.                          F2A10150
       PZE     FILN1,,FTAPE3                                            F2A10160
*      ***                                                              F2A10170
EB60   TSX     (TAPE),4             READ                                F2A10180
       PZE     4TAGAD,,(RBNC)       IN                                  F2A10190
       PZE     4TAGL,,FTAPE2        FORTAG.                             F2A10200
*      ***                                                              F2A10210
       LXA     (SCHU)+FTAPE2,2      COMPUTE                             F2A10220
       SXD     TBLEND,2             NEXT                                F2A10230
       AXT     2,2                  GO TO                               F2A10240
       TSX     CHECK,4              CHECK READ.                         F2A10250
       LXA     4TAGAD+1,2           UNUSED                              F2A10260
       PXD     0,2                  INDEX.                              F2A10270
       ADD     4TAGAD+1                                                 F2A10280
       SUB     TBLEND                                                   F2A10290
       STD     FORTAG-1             SAVE INDEX VALUE                    F2A10300
       PDX     0,1                  AND PLACE IN XR.                    F2A10310
       MSE     97                   ON IF FORTAG                        F2A10320
       NOP                          EMPTY, OFF IF                       F2A10330
       TXL     EB70,1,3000*M/N*2-1  FORTAG                              F2A10340
       PSE     97                   NOT EMPTY.                          F2A10350
*      ***                                                              F2A10360
EB70   TSX     (TAPE),4             SPACE TAPE                          F2A10370
       PZE     SKTAP,,(SKBP)        TO BEGINNING                        F2A10380
       PZE     DTGBL,,FTAPE2        OF NEXT FILE.                       F2A10390
       TRA     EB90                                                     F2A10400
DOAD   IORT    DOTAG,,6                                                 F2A10410
4TAGAD IOCP    TBCHK,,2                                                 F2A10420
       IORT    FORTAG,,3000*M/N*2                                       F2A10430
DTGL   BCI     1,DOTAGA                                                 F2A10440
DTGBL  BCI     1,DOTAGB                                                 F2A10450
EBCOM1 IOCT    DOTAG,0,0           WD CT INITLZD, ADD INIT + UPDATED.  $F2A10460
EBCOM2 IOCP    L(0),0,1             TRALEV TP CONT WD.                  F2A10470
       IOCT    L(0),0,1                                                $F2A10480
NSTAD  PZE                                                              F2A10490
EB90   MSE     98                   IS TRALEV TALBE EMPTY               F2A10500
       TRA     EB95                                                     F2A10510
*      ***                                                              F2A10520
       TSX     (TAPE),4             WRITE TWO                           F2A10530
       PZE     EBCOM2,,(WBNP)       ZERO WORD COUNT                     F2A10540
       PZE     TRLVL,,FTAPE4        WORDS FOR EMPTY TRALEV.             F2A10550
       SLN     2                    INDICATE EMPTY TRALEV.              F2A10560
*      ***                                                              F2A10570
EB95   TSX     (TAPE),4             WRITE EOF                           F2A10580
       PZE     ,,(WEFP)             FOR TRALEV.                         F2A10590
       PZE     FILN1,,FTAPE4                                            F2A10600
*      ***                                                              F2A10610
       TSX     (LOAD),4             GO TO BLOCK 2.                      F2A10620
       PZE                                                              F2A10630
       REM *CHECK* TESTS READING OF TABLES BY COMPARING LABELS          F2A10640
       REM AND WORD COUNTS READ TO THOSE EXPECTED.                      F2A10650
CHECK  CLA     TABNO,2              COMPARE LABEL WANTED                F2A10660
       ANA     ADDMSK               TO                                  F2A10670
       SUB     TBCHK                LABEL READ.                         F2A10680
       TZE     CK4                                                      F2A10690
       AXT     0,1                  WRONG LABEL,                        F2A10700
       TRA     TAPER                GO TO ERROR.                        F2A10710
CK4    CLA     TABNO,2              COMPUTE                             F2A10720
       ANA     DECMSK               1ST TABLE ADDRESS                   F2A10730
       ADD     TBCHK+1              PLUS WORD COUNT READ                F2A10740
       SUB     TBLEND               MINUS SCHU ADDRESS.                 F2A10750
       TZE     1,4                  NO ERRORS, RETURN.                  F2A10760
       AXT     1,1                                                      F2A10770
*      ***                                                              F2A10780
TAPER  TSX     (TAPE),4             GO TO TAPE                          F2A10790
       PZE     ERIND,1,(TPER)       ERROR                               F2A10800
       PZE     4VALL,2,FTAPE2       DIAGNOSTIC.                         F2A10810
       PZE     4,,FORTAG                                                F2A10820
       PZE     5,,FORVAR                                                F2A10830
TABNO  PZE     6,,FORVAL                                                F2A10840
4TAGL  BCI     1,FORTAG                                                 F2A10850
4VARL  BCI     1,FORVAR                                                 F2A10860
4VALL  BCI     1,FORVAL                                                 F2A10870
       BCI     1,COUNT                                                  F2A10880
ERIND  BCI     1,LABEL                                                  F2A10890
ERLIST SXD     ERIR2,2              SAVE X R  B                         F2A10900
       LXD     ERNBR,2              GET ERROR NUMBER                    F2A10910
       CLA     DOTGZ,4              SAVE ALPHA DO BETA                  F2A10920
       STO     LIST,2               IN LIST                             F2A10930
       CLA     DOTGZ+1,4            AND SYMBOL                          F2A10940
       STO     LIST-1,2                                                 F2A10950
       CLA     DOTGZ,1              SAVE OTHER ALPHA DO BETA            F2A10960
       STO     LIST-2,2                                                 F2A10970
       CLA     DOTGZ+1,1            AND SYMBOL                          F2A10980
       STO     LIST-3,2                                                 F2A10990
       TXI     ERNXT,2,4                                                F2A11000
ERNXT  SXD     ERNBR,2                                                  F2A11010
       LXD     ERIR2,2                                                  F2A11020
       TRA     MR60                                                     F2A11030
ERIR2                                                                   F2A11040
ERNBR                                                                   F2A11050
ERBETA SXD     ERIR2,2              SAVE ALPHA DO BETA                  F2A11060
       LXD     ERNBR,2              WHERE ALPHA                         F2A11070
       STZ     LIST,2               IS GREATER THAN                     F2A11080
       CLA     DOTGZ,1              ITS BETA                            F2A11090
       STO     LIST-1,2                                                 F2A11100
       CLA     DOTGZ+1,1                                                F2A11110
       STO     LIST-2,2                                                 F2A11120
       TXI     ERNX,2,3                                                 F2A11130
ERNX   SXD     ERNBR,2                                                  F2A11140
       LXD     ERIR2,2                                                  F2A11150
       TRA     MR15                                                     F2A11160
ERTST  LXD     ERNBR,2                                                  F2A11170
       TXL     FLOW,2,0                                                 F2A11180
       TSX     ERROR1,4             SOURCE PROGRAM ERROR.               F2A11190
LIST   SYN     ENDCOR-1                                                 F2A11200
LMSK   SYN     L(MZ)                                                    F2A11210
SKTAP  PZE     ,,1                                                      F2A11220
CHCK   PZE                                                              F2A11230
       PZE                                                              F2A11240
FILN1  BCI     1,EOF1                                                   F2A11250
TBLEND PZE                                                              F2A11260
DOTRAN AXT     DT050,1        SET                                   (20)F2A11270
       SXA     GOTOVN-1,1     EXIT                                  (20)F2A11280
       SXA     GTV30,1        FROM FLOW                             (20)F2A11290
       ZSD     FA000A+1       SET EXIT FROM FA000                   (20)F2A11300
       LXD     TIFGO-1,4      IS TIFGO EMPTY                        (20)F2A11310
       TXH     LB02,4,1200*M/N*2-1      YES, EXIT                   (20)F2A11320
       SXD     DTEND,4        NO,STO NO. OF TIFGO ENTRIES           (20)F2A11330
       LXD     MAXTIF,4                                             (20)F2A11340
 DT000 SXD     TIFX,4         STO  CURRENT POINTER TO TIFGO         (20)F2A11350
       CLA     TIFZ,4         PICK UP TIFGO ENTRY                   (20)F2A11360
       STD     G              STO ORIGIN OF THE TRA                 (20)F2A11370
       TRA     FL080-2        PICK UP THE DESTINATION OF THE TRA    (20)F2A11380
FA000A STO     A              STO DESTINATION OF TRA                (20)F2A11390
       TXL     FA000+2,4,-1   FLOW SWITCH-- EXIT IF IN FLOW SCAN    (20)F2A11400
DTSCAN LXD     DOTAG-1,1      PICK UP NO OF DOES                    (20)F2A11410
       SXD     DT001+1,1                                            (20)F2A11420
       TXI     *+1,1,9        STEP UP POINTER TO DOTAG TABLE        (20)F2A11430
       SXD     XDG,1                                                (20)F2A11440
       CLA     DOTGZ,1        PICK UP THE LAST ENTRY IN DOTAG TABLE (20)F2A11450
       STD     BNA            STO IFN OF BEG OF DO                  (20)F2A11460
       PAX     0,2            PICK UP IFN OF END OF DO              (20)F2A11470
       SXD     ENA,2          STO IT IN DEC OF ENA                  (20)F2A11480
       CLA     A              AC CONTAINS END PT OF TRA             (20)F2A11490
       LDQ     ENA            MQ CONTAINS END PT OF DO              (20)F2A11500
       TLQ     DTDO1          TRA IF END OF TRA AFTER END OF DO     (20)F2A11510
       SUB     BNA                                                  (20)F2A11520
       TMI     DTDO1          TRA IF END OF DO IS BEFORE BEG OF DO  (20)F2A11530
       TZE     DTDO1          TRA IF END OF TRA = BEG OF DO         (20)F2A11540
       CLA     G              AC CONTAINS BEG OF TRA                (20)F2A11550
       TLQ     *+3            TRA FROM OUT OF DO RANGE GO TO TEST   (20)F2A11560
       LDQ     BNA                                                  (20)F2A11570
       TLQ     DTDO1          TRA IF TRA FROM WITHIN DO             (20)F2A11580
       CLA     DOTGZ+5,1      PICK UP LEVEL OF DO                   (20)F2A11590
       STD     DTLEV          SAVE IT FOR TEST                      (20)F2A11600
 DT006 CLA     DOTGZ+7,1      DOES THIS DO CONTAIN A TRA OUT OF NEST(20)F2A11610
       TPL     DT001          NO, CHECK  INNER DOES                 (20)F2A11620
 DTDO1 LXD     XDG,1          YES, TRA LEGAL, GET NEXT DO           (20)F2A11630
       TXL     DTSCAN+2,1,600*M/N*9-9   IS THIS THE LAST DO         (20)F2A11640
       TRA     1,4            YES, GET NEXT A (TRA ENDPOINT)        (20)F2A11650
 DT050 LXD     TIFX,4         PICK UP TIFGO POINTER                 (20)F2A11660
       TXI     *+1,4,-2       STEP UP POINTER                       (20)F2A11670
 DTEND TXH     DT000,4,**     IS THIS END OF TIFGO                  (20)F2A11680
       TRA     LB02           YES, EXIT                             (20)F2A11690
 DT001 TXI     *+1,1,-9       GET NEXT BACK DO                      (20)F2A11700
       TXL     DTERR,1,**     TRA TO ERROR IF LAST DO WAS CHECKED   (20)F2A11710
       CLA     DOTGZ+5,1                                            (20)F2A11720
       PDX     0,2            PICK UP LEVEL OF THIS DO              (20)F2A11730
 DTLEV TXH     DT006,2,**     IS IT CONTAINED WITHIN DO WITH TRA    (20)F2A11740
 DTERR LXD     TIFX,1         NO, GET IFN OF ILLEGAL TRA, TO PRINT  (20)F2A11750
       TSX     ERROR4,4       ILLEGAL TRA INTO THE RANGE OF A DO    (20)F2A11760
 TRA88 PBT                          IS LEVEL GREATER THAN 20.       (23)F2A11770
       TSX     ERROR3,4             YES, SOURCE PROGRAM ERROR.      (23)F2A11780
       TRA     TRA95                NO                              (23)F2A11790
 ENDB  SYN     *+97                                                 (23)F2A11800
       TCD     -1                                                   (23)F2A11810
       LBL     9F19,M                                               (26)F2A99000
       TTL     BLOCK B.                                                 F2A99010
*     SECTION TWO OF 709/7090 32K FORTRAN, BLOCK B.                     F2B00000
       HEAD    2                                                        F2B00010
       ORG     SYSCUR                                                  $F2B00020
       BCI     1,9F1900                                                $F2B00030
       ORG     (LODR)                                                  $F2B00040
       TXI     BEGIN,,190                                               F2B00060
       REM SUBSCRIPT COMBINATIONS WHICH HAVE SUBSCRIPTS                 F2B00080
       REM SOME OR ALL OF WHICH ARE UNDER CONTROL OF THEIR RESPECTIVE   F2B00090
       REM DOS. THERE IS A CODING BLOCK STARTING AT SYMBOL CORES,       F2B00100
       REM VARIOUSLY TERMED STATE B OR RELCON, WHICH IS RESERVED        F2B00110
       REM FOR THOSE SUBSCRIPT COMBINATIONS                             F2B00120
       REM SOME SUBSCRIPT ELEMENT/S OF WHICH ARE                        F2B00130
       REM NOT UNDER CONTROL OF A DO (RELATIVE                          F2B00140
       REM CONSTANT).                                                   F2B00150
M      SYN     1$M                  M/N IS THE RATIO OF TABLE SIZES     F2B00160
N      SYN     1$N                  TO NORMAL 32K SIZES.                F2B00170
       ORG     BITTWO+1                                                 F2B00180
       HEAD    0                                                        F2B00190
       REM              CELLS AND SUBROUTINES COMMON                    F2B00200
       REM              TO BLOCKS TWO AND THREE.                        F2B00210
L(1)A  OCT     1                                                        F2B00220
L(0)   OCT     0                                                        F2B00230
35ONES OCT     377777777777                                             F2B00240
RSYM1  PZE                                                              F2B00250
RSYM2  PZE                                                              F2B00260
RSYM3  PZE                                                              F2B00270
C1     PZE                                                              F2B00280
S1     PZE                                                              F2B00290
C2     PZE                                                              F2B00300
S2     PZE                                                              F2B00310
C3     PZE                                                              F2B00320
S3     PZE                                                              F2B00330
D1     PZE                                                              F2B00340
D2     PZE                                                              F2B00350
A      PZE                                                              F2B00360
B      PZE                                                              F2B00370
NEXTA  PZE                                                              F2B00380
LASTB  PZE                                                              F2B00390
TAG    PZE                                                              F2B00400
TRABIT PZE                                                              F2B00410
       REM THIS ROUTINE, GIVEN A TAU TAG, OBTAINS THE                   F2B00420
       REM CORRESPONDING SUBSCRIPT COMBINATION FROM THE TAU             F2B00430
       REM TABLE AND POSITIONS IT IN PROPER FORMAT IN WORK SPACE.       F2B00440
TAU1   SYN     1$TAU1                                                   F2B00450
TAU2   SYN     1$TAU2                                                   F2B00460
TAU3   SYN     1$TAU3                                                   F2B00470
FORTZ  SYN     1$FORTZ                                                  F2B00480
DOTGZ  SYN     1$DOTGZ                                                  F2B00490
SUBCOM SXD     SUB085,4             SAVE LINKAGE INDEX                  F2B00500
       LXD     SUBORG+2,4           INITIALIZE                          F2B00510
       PXD     0,0                  SUBSCRIPT COMBO                     F2B00520
SUB020 STO     C1+8,4               SPACE                               F2B00530
       TIX     SUB020,4,1           TO ZERO                             F2B00540
       CLA     TAG                  COMPUTE                             F2B00550
       LRS     9                    TABLE                               F2B00560
       PAX     0,6                  ADDRESS                             F2B00570
       PXD     0,0                  TAU ONE ADD. IS ORG+2 TAU.          F2B00580
       LLS     9                    TAU TWO ADD. IS ORG+4 TAU.          F2B00590
       ALS     1                    TAU THREE ADD. IS ORG+6 TAU.        F2B00600
       STO     SUBES1               STORE TWO TAU                       F2B00610
       CLA     SUBORG+3,4           GET ORG AND                         F2B00620
SUB030 ADD     SUBES1               ADD FACTOR OF TWO TAU               F2B00630
       TIX     SUB030,4,1                                               F2B00640
       STA     SUB038               SET                                 F2B00650
       TXL     SUB032,2,2           UP                                  F2B00660
       ADD     L(1)A                CLA                                 F2B00670
       STA     SUB039               ADDRESSES                           F2B00680
SUB032 ADD     L(1)A                FOR                                 F2B00690
       STA     SUB040               THE                                 F2B00700
       TXL     SUB038,2,1           RETEIEVAL                           F2B00710
       ADD     L(1)A                AND                                 F2B00720
       STA     SUB043               DISPERSAL                           F2B00730
       TXL     SUB034,2,2           OF                                  F2B00740
       ADD     L(1)A                THE                                 F2B00750
       STA     SUB046               TAU                                 F2B00760
SUB034 ADD     L(1)A                TABLE                               F2B00770
       STA     SUB050               ENTRY                               F2B00780
SUB038 CLA     **                   GET C1,C2 WORD FOR                  F2B00790
       STO     C1                   TAU 1,2,3.                          F2B00800
       TXL     SUB040,2,2                                               F2B00810
SUB039 CLA     **                   GET C3 WORD FOR                     F2B00820
       STO     C3                   TAU 3.                              F2B00830
SUB040 CLA     **                   GET S1 WORD FOR                     F2B00840
       STO     S1                   TAU1,2,3                            F2B00850
       TXL     SUB095,2,1                                               F2B00860
SUB043 CLA     **                   GET S2 WORD FOR                     F2B00870
       STO     S2                   TAU 2,3                             F2B00880
       TXL     SUB050,2,2                                               F2B00890
SUB046 CLA     **                   GET S3 WORD FOR                     F2B00900
       STO     S3                   TAU 3                               F2B00910
SUB050 CLA     **                   GET D1, D2 WORD FOR                 F2B00920
       STO     D1                   TAU 2,3                             F2B00930
SUB075 LXD     SUBORG+1,4           REARRANGE C1,C2,D1,D2,              F2B00940
SUB080 CLA     C1+7,4               TO COMPLY WITH CORE                 F2B00950
       PAX     0,2                  STORAGE FORMAT.                     F2B00960
       ANA     DECMSK                                                   F2B00970
       STO     C1+7,4                                                   F2B00980
       PXD     0,2                                                      F2B00990
       TNX     SUB090,4,6                                               F2B01000
       STO     C2                                                       F2B01010
SUB085 TXL     SUB080,,0                                                F2B01020
SUB090 STO     D2                                                       F2B01030
SUB095 LXD     SUB085,4             RESTORE LINKAGE INDEX.              F2B01040
       TRA     1,4                  RETURN.                             F2B01050
SUBORG         TAU3,0,6             ADDRESSES                           F2B01060
               TAU2,0,7             CONTAIN                             F2B01070
               TAU1,0,8             ORIGINS OF TAU.                     F2B01080
SUBES1 PZE                          E.S. FOR 2TAU ADDITIVE FACTOR.      F2B01090
LIST   PDX     0,1                  PUT IX QUANTITY IN XRA              F2B01100
       PAX     0,2                  PUT NR. WDS IN XRB, XRC.            F2B01110
       ADD     LIST50               COMPUTE NUMBER WDS PLUS             F2B01120
       STA     LIST10               ORIGIN E1 AND INITIALIZE ADD.       F2B01130
       SUB     LIST50               SALVAGE ORIGINAL KEY WORD,          F2B01140
       ADD     LADDS+5,1            COMPUTE NR WDS PLUS                 F2B01150
       STA     LIST20               CURRENT TABLE ADD AND INIT. ADD.    F2B01160
       CLA     LADDIN+5,1           TEST                                F2B01170
       ARS     18                   FOR                                 F2B01180
       SUB     LADDS+5,1            FULL                                F2B01190
       TNZ     LIST10               TABLE.                              F2B01200
       SXD     LIST05,1             FULL TABLE ERROR, SAVE              F2B01210
       TSX     ERROR7,4             SOURCE PROGRAM ERROR.               F2B01220
LIST05 PZE                                                              F2B01230
LIST10 CLA     0,2                  PUT ENTRY                           F2B01240
LIST20 STO     0,2                  INTO TABLE.                         F2B01250
       TIX     LIST10,2,1                                               F2B01260
       CLA     LADDS+5,1            COMPUTE                             F2B01270
       ADD     CHATAG+5,1           NEXT                                F2B01280
       ANA     ADDMSK               ENTRY ADDRESS                       F2B01290
       STO     LADDS+5,1                                                F2B01300
       TRA     1,4                  EXIT.                               F2B01310
LIST50 HTR     E1                   L(E1)                               F2B01320
       REM FOUR WORD ENTRY BLOCK.                                       F2B01330
E1     PZE                                                              F2B01340
E2     PZE                                                              F2B01350
E3     PZE                                                              F2B01360
E4     PZE                                                              F2B01370
       REM FIVE KEY WDS, C(DEC)=IX QUAN., C(ADD)=NR. OF WDS.            F2B01380
CHATAG PZE     2,0,5                ACCUMULATOR                         F2B01390
TRASTO PZE     3,0,4                KEY                                 F2B01400
TSXCOM PZE     2,0,3                WORD WHEN                           F2B01410
NAMKEY PZE     2,0,2                TSX TO LIST.                        F2B01420
DRMTAG PZE     4,0,1                (ADTAG).                            F2B01430
       REM FIVE WDS CONTAINING CURRENT TABLE ADDRESSES IN ADD. PART     F2B01440
LADDS  PZE                          CHATAG (INITIALLY ADD IS ADD OF     F2B01450
       PZE                          TRASTO (LADDIN. THEREAFTER, IT      F2B01460
       PZE                          TSXCOM (IS THE ADD OF THE NEXT      F2B01470
       PZE                          NAMKEY (TABLE ENTRY PENDING)        F2B01480
       PZE                          DRMTAG                              F2B01490
       REM FIVE WDS., C(ADD)=ORG, C(DEC)=LAST TABLE LOCAT. PLUS ONE.    F2B01500
LADDIN PZE     CHTGTB,,CHTAGZ       CHANGETAG                           F2B01510
       PZE     TRSTTB,,TRSTOZ       TRASTO                              F2B01520
       PZE     TSCMTB,,TSXCMZ       TSXCOM                              F2B01530
       PZE     NMKYTB,,NAMKYZ       NAMEKEY                             F2B01540
       PZE     DMTGTB,,DRMTGZ       DRUMTAG                             F2B01550
       REM SUBROUTINE SPC000                                            F2B01560
SPC000 SXD     SPC115,1             SAVE INDEX OF DO TO BE SEARCHED.    F2B01570
       SXD     SPC060,2             SAVE TINFOR,LIST INDICATOR          F2B01580
       SXD     SPC105,4             SAVE TSX INDEX.                     F2B01590
       STO     SPCKEY               SAVE LIST KEY WORD                  F2B01600
       CLA     DOTGZ+5,1            OBTAIN L WORD                       F2B01610
       STD     SPC050               INITIALIZE TEST INSTR.              F2B01620
       CLA     DOTGZ,1              GET ALPHA-BETA WORD,                F2B01630
       PAX     0,2                  SAVE BETA,                          F2B01640
       ANA     DECMSK               OBTAIN ALPHA ALONE                  F2B01650
       STO     NEXTA                STO IN NEXTA                        F2B01660
       STO     A                    AND STORE IN A.                     F2B01670
       PXD     0,2                  PUT BETA IN LASTB AND               F2B01680
       STO     LASTB                BETING SEARCH FOR R2                F2B01690
SPC010 LXD     SPC115,1             OBTAIN CURRENT INDEX AND            F2B01700
SPC020 TXI     SPC040,1,-9          GO DOWN ONE DO,IF POSSIBLE,ELSE     F2B01710
SPC040 TXL     SPC110,1,0           GO TO SET UP LAST INTERVAL.         F2B01720
       CLA     DOTGZ+5,1            TEST IF THIS DO                     F2B01730
       PDX     0,2                  IS IN RANGE OF R1(DXL)              F2B01740
SPC050 TXL     SPC110,2,0           IF NOT, EXIT FOR LAST INTERVAL      F2B01750
       CLA     DOTGZ+1,1            IF IN R1, IS THIS DO TO BE          F2B01760
       SUB     RSYM1                SKIPPED. IF NOT,GO BACK TO          F2B01770
       TZE     SPC053               GET NEXT DO.                        F2B01780
       CLA     DOTGZ+1,1                                                F2B01790
       SUB     RSYM2                                                    F2B01800
       TNZ     SPC020                                                   F2B01810
SPC053 CLA     DOTGZ,1              R2 FOUND, FIX TO SKIP THIS          F2B01820
       PAX     0,2                  INTERVAL. USE ALPHA OF R2           F2B01830
       ANA     DECMSK               AS B,PUT BETA OF R2 IN              F2B01840
       STO     B                    NEXTA.                              F2B01850
       PXD     0,2                  DO FORMULAS WITHIN R2 ARE           F2B01860
       STO     NEXTA                ACCOUNTED FOR AFTER SEARCH.         F2B01870
       SXD     SPC115,1             SAVE INDEX OF R2.                   F2B01880
SPC055 LXD     SPC060,2             PUT TINFOR, LIST IND. IN XRB        F2B01890
SPC058 CLA     A                    FOR                                 F2B01900
       SUB     B                    NON EMPTY                           F2B01910
       TZE     SPC065               INTERVALS,                          F2B01920
       TXL     SPCTIN,2,1           GO TO ARRANGE TINFOR SEARCH, OR     F2B01930
SPC060 TXL     SPCSTO,,0            TRA TO USE LIST.                    F2B01940
SPC065 LXD     SPC060,2             RETURN HERE,TEST TINFOR             F2B01950
       TXL     SPC120,2,0           LIST IND. IF ZERO, EXIT.            F2B01960
SPC070 LXD     SPC115,1             TO SET UP NEXT INTERVAL,            F2B01970
       CLA     DOTGZ+5,1            GET INDEX OF LAST R2 AND            F2B01980
       STD     SPC100               STEP DOWN IN DOTAG BY USUAL         F2B01990
SPC080 TXI     SPC090,1,-9          PROCEDURE UNTIL SOME DO IS          F2B02000
SPC090 TXL     SPC110,1,0           FOUND NOT IN R2, OR UNTIL           F2B02010
       CLA     DOTGZ+5,1            DOTAG ENDED. IF DO FOUND            F2B02020
       PDX     0,2                  NOT IN R2,SET A AND GO TO TEST      F2B02030
SPC100 TXH     SPC080,2,0           IF THIS DO IS IN R1.                F2B02040
       CLA     NEXTA                IF IT IS,NEWR2 WILL BE FOUND        F2B02050
       STO     A                    OR EXIT MADE TO SPC110.             F2B02060
SPC105 TXL     SPC050,,0                                                F2B02070
SPC110 CLA     NEXTA                THIS IS SETUP FOR LAST              F2B02080
       STO     A                    INTERVAL. FOR A,USE                 F2B02090
       CLA     LASTB                CONTENTS OF NEXTA. FOR B,           F2B02100
       STO     B                    USE BETA OF R1,FOUND IN             F2B02110
       LXD     SPC060,2             LASTB. OBTAIN TINFOR,STOTAG         F2B02120
       CLA     L(0)                 IND,AND SET LOCATION OF             F2B02130
       STD     SPC060               INDICATOR TO ZERO. GO TO            F2B02140
SPC115 TXL     SPC058,,0            TINFOR OR TRASTO.                   F2B02150
SPC120 LXD     SPC105,4             EXIT,ALL STORES DONE,OR,            F2B02160
       TRA     1,4                  SEARCH MADE,T NOT FOUND.            F2B02170
SPC130 LXD     SPC105,4             EXIT,T FOUND                        F2B02180
       TRA     2,4                  IN SOME INTERVAL                    F2B02190
SPCTIN TSX     TINFXX,4             GO TO SEARCH FORTAG                 F2B02200
       TRA     SPC130               T FOUND                             F2B02210
       TRA     SPC065               T NOT FOUND                         F2B02220
SPCSTO CLA     B                    FOR TRASTO,E2 AND E3 ARE            F2B02230
       ARS     18                   ALREADY SET UP. COLLECT             F2B02240
       ADD     A                    A AND B INTO E1 WORD,               F2B02250
       STO     E1                   PUT TRASTO INDICATOR IN             F2B02260
       CLA     SPCKEY               ACC. AND                            F2B02270
       TSX     LIST,4               TSX TO LISTING ROUTINE.             F2B02280
       TRA     SPC065               ON RETURN,GO TO TEST FINISH.        F2B02290
SPCKEY PZE                          STORAGE FOR TABLE KEY.              F2B02300
       REM SUBROUTINES TINFOR AND TINFXX                                F2B02310
TINFOR CLA     DOTGZ,1              C(XRA) INDEX OF DO TO BE            F2B02320
       PAX     0,1                  SEARCHED. SEPARATE ALPHA            F2B02330
       ANA     DECMSK               AND BETA                            F2B02340
       STO     A                    AND STORE IN A                      F2B02350
       PXD     0,1                                                      F2B02360
       STO     B                    B                                   F2B02370
TINFXX LXD     MAXFTG,1             PUT MAX FORTAG IX IN XRA.           F2B02380
TINF10 CLA     FORTZ,1              OBTAIN FORTAG ENTRY                 F2B02390
       ANA     DECMSK               RETAIN FORMULA NUMBER ONLY          F2B02400
       CAS     A                    COMPARE ALPHA AND FORMULA NR.       F2B02410
       TRA     TINF40               FOR. NR. GREATER THAN ALPHA. TRA.   F2B02420
       NOP                          C(A) MAY BE SOME BETA FROM SPC      F2B02430
TINF20 TXI     TINF30,1,-1          FOR.NR. LESS THAN ALPHA. GO         F2B02440
       REM                           BACK FOR NEXT FORTAG ENTRY         F2B02450
TINF30 TXH     TINF10,1,0           IF POSSIBLE. OTHERWISE,             F2B02460
       TRA     2,4                  RETURN TO CALLING INSTR PLUS TWO.   F2B02470
TINF40 CAS     B                    COMPARE FOR. NR. WITH BETA          F2B02480
       TRA     2,4                  FOR. NR. GREATER THAN BETA,EXIT.    F2B02490
       NOP                          FOR. NR. EQUAL TO OR                F2B02500
       CLA     FORTZ,1              LESS THAN BETA,OBTAIN FORTAG        F2B02510
       TPL     TINF20               TAG AND COMPARE WITH SEARCH TAG.    F2B02520
       ANA     ADDMSK               I.F. NOT EQUAL,GO BACK FOR NEXT TAG F2B02530
       SUB     TAG                                                      F2B02540
       TNZ     TINF20               IF EQUAL,RETURN TO CALLING          F2B02550
       TRA     1,4                                                      F2B02560
       HEAD    2                                                        F2B02570
DBUFSZ EQU     200*M/N*9            SIZE OF BUFFERS FOR DO TABLE.       F2B02580
ADTAGZ SYN     ENDCOR               ADDITIONAL                          F2B02590
ADTAG  SYN     ADTAGZ-200*M/N*2     TABLE DEFINITIONS.                  F2B02600
NAMKYZ SYN     ADTAG                FOR                                 F2B02610
NAMZ   SYN     NAMKYZ               BLOCK 2.                            F2B02620
NMKYTB SYN     NAMKYZ-600*M/N*2                                         F2B02630
NAM    SYN     NMKYTB                                                   F2B02640
NMKYWC SYN     NMKYTB-1                                                 F2B02650
TSXCMZ SYN     NMKYWC                                                   F2B02660
TSCMTB SYN     TSXCMZ-400*M/N*2                                         F2B02670
TSCMWC SYN     TSCMTB-1                                                 F2B02680
RETABZ SYN     TSCMWC-1                                                 F2B02690
RETAB  SYN     RETABZ-1200*M/N                                          F2B02700
TRSTOZ SYN     RETAB                                                    F2B02710
TRSTTB SYN     TRSTOZ-400*M/N*3                                         F2B02720
TRSTWC SYN     TRSTTB-1                                                 F2B02730
CHTAGZ SYN     TRSTWC                                                   F2B02740
CHTGTB SYN     CHTAGZ-400*M/N*2                                         F2B02750
CHTGWC SYN     CHTGTB-1                                                 F2B02760
FIXWC  SYN     1$FIXWC                                                  F2B02770
TAU3   SYN     1$TAU3                                                   F2B02780
TAU2   SYN     1$TAU2                                                   F2B02790
TAU1   SYN     1$TAU1                                                   F2B02800
4VALZ  SYN     1$4VALZ                                                  F2B02810
DOTGZ  SYN     1$DOTGZ                                                  F2B02820
DOTAG  SYN     DOTGZ-200*M/N*9                                          F2B02830
DTGWC  SYN     DOTAG-1                                                  F2B02840
FORTZ  SYN     1$FORTZ                                                  F2B02850
DO     SYN     FORTZ                                                    F2B02860
DOZ    SYN     DO+600*M/N*2                                             F2B02870
TAGZ   SYN     FRTGWC                                                   F2B02880
TAGTAG SYN     TAGZ-1000*M/N*4      ORIGIN TAGTAG TABLE.                F2B02890
DBUF2  SYN     TAGZ-DBUFSZ          USED TO BRING IN DOTAG TO           F2B02900
DBUF1  SYN     DBUF2-DBUFSZ         MAKE DO TABLE.                      F2B02910
       ORG     TINF40+9                                                 F2B02920
DOREC  PZE                          NR DONEST RECS ON TAPE 2.           F2B02930
       PZE                                                              F2B02940
ATSW   PZE                          ADDED TAG SW (1 IF PROC ADDED TAGS.)F2B02950
NEWTAG PZE                          INIT 4000, FROM FIRSTTAG.           F2B02960
XC     PZE                          IX CURRENT DO.                      F2B02970
LC     PZE                          LEV CURRENT DO.                     F2B02980
ALPHA  PZE                          ALPHA CURRENT DO.                   F2B02990
BETA   PZE                          BETA CURRENT DO.                    F2B03000
TS     PZE                          TAG, (4TAG OR NEW TAG NAME.)        F2B03010
TAG1   PZE                          4TH WD OF TAGTAG.                   F2B03020
GROUP  PZE                          GROUP NO. IN DECR.                  F2B03030
       REM                          HERE TO CARWRD ARE SET 0 IN IDENT.  F2B03040
X1     PZE                         IX DO MATCHING 1ST SYMBOL.          $F2B03050
L1     PZE                         LEV DO MATCHING 1ST SYMBOL.         $F2B03060
X2     PZE                         IX DO MATCHING 2ND SYMB             $F2B03070
L2     PZE                         LEV DO MATCHING 2ND                 $F2B03080
X3     PZE                         IX DO MATCHING 3RD                  $F2B03090
L3     PZE                         LEV DO MATCHING 3RD                 $F2B03100
XL     PZE                         IX LOWEST LEVEL DOSUB               $F2B03110
LL     PZE                         LEV LOWEST LEVEL DOSUB              $F2B03120
NRSUBS PZE                         NR. SUBSCRIPTS IN SUBSCR COMBINATION$F2B03130
NRRC   PZE                         NR. RELCONS IN SUBSCR COMBINATION   $F2B03140
NRDS   PZE                         NR DOSUBS IN S.C.                   $F2B03150
DORC   PZE                         BIT IN 15,16,17 IF CORRES X1,X2,X3  $F2B03160
       REM                          IS DORC.                            F2B03170
RCSUBS PZE                         BIT IN 15,16,17 IF CORRES X1,X2,X3  $F2B03180
       REM                          IS RELCON.                          F2B03190
DOSUBS PZE                         BIT IN 15,16,17 IF CORRES X1,X2,X3  $F2B03200
       REM                          IS DOSUB.                           F2B03210
DELTA  PZE                                                             $F2B03220
RCDUP  PZE                         BIT IN 15,16,17 FOR CORRES DUPE RCS.$F2B03230
DUPES  PZE                         BIT IN 15,16,17 FOR CORRES          $F2B03240
       REM                          DOSUBS.                             F2B03250
CARWRD PZE                         BIT IN 11 IF TYPE 1 CARRY,          $F2B03260
       REM                          12 IF LEFT TYPE 2, 13 IF CENTER     F2B03270
       REM                          TYPE 1, 14 IF CENTER TYPE 2,        F2B03280
       REM               S SET NEG IF COUNTER AND TEST FOUND            F2B03290
TL1    PZE                                                              F2B03300
TL2    PZE                                                              F2B03310
REBITS PZE                                                              F2B03320
LOWPOS PZE                          5,3,1 IF LL SUBSCR. IS X1,X2,X3.    F2B03330
L(0)           0,0,0                                                    F2B03340
L(1)           0,0,1                                                    F2B03350
L(2)           0,0,2                                                    F2B03360
L(3)           0,0,3                                                    F2B03370
L(4)           0,0,4                                                    F2B03380
L(5)           0,0,5                                                    F2B03390
L(6)           0,0,6                                                    F2B03400
L(36)          0,0,36                                                   F2B03410
L(1)A          1                                                        F2B03420
L(2)A          2                                                        F2B03430
L(4)A          4                                                        F2B03440
L(MZ)  MZE                                                              F2B03450
DTGZAD PZE     DOTGZ                                                    F2B03460
CR1    OCT     100000000            BIT 11                              F2B03470
CR2    OCT     40000000             BIT 12                              F2B03480
CARMSK OCT     300000               BITS 19,20(CARRY BITS FOR WD6 DOTAG)F2B03490
FRSTAG OCT     4000                                                     F2B03500
2BITS  OCT     -200000000000        S AND 1 BIT                         F2B03510
BIT18  OCT     400000                                                   F2B03520
BIT19  OCT     200000                                                   F2B03530
BIT20  OCT     100000                                                   F2B03540
ADTXX          200*M/N*2            IX VALUE FOR DEC                    F2B03550
RESXX          1200*M/N             CONTAINS NEXT TABLE ENTRY.          F2B03560
TAGXX          1000*M/N*4,,1000*M/N*4                                   F2B03570
NAMXX  OCT     0                    DEC AND ADD INITLZD AT BEGIN EVERY  F2B03580
       REM                           NEST TO VALUE FOR NEXT TABLE ENTRY.F2B03590
       REM                           THEN DEC BMPD THRU NEST FOR NEXT   F2B03600
       REM                           TABLE ENTRY.                       F2B03610
*      ***                                                              F2B03620
BEGIN  TSX     (TAPE),4             REWIND                              F2B03630
       PZE     REWIND,,(SKBP)       DOTAGA                              F2B03640
       PZE     DTGL,,FTAPE3         TAPE.                               F2B03650
       AXT     5,1                  INITIALIZE                          F2B03660
BEG10  CLA     LADDIN+5,1           PROGRAM                             F2B03670
       ANA     ADDMSK               ADDRESSES                           F2B03680
       STO     $LADDS+5,1                                               F2B03690
       TIX     BEG10,1,1                                                F2B03700
       CLA     L(0)                                                     F2B03710
       STO     DOREC                                                    F2B03720
       LXD     L(0),6               TEST FOR EMPTY                      F2B03730
       MSE     100                  FORVAL                              F2B03740
       LXD     L(1),4               OFF, NOT EMPTY                      F2B03750
       SXD     END80,4              ON, EMPTY                           F2B03760
       MSE     99                   TEST FOR                            F2B03770
       LXD     L(1),2               EMPTY DOTAG.                        F2B03780
       SXD     END85,2              SAVE TABLE INFO IN END PROG.        F2B03790
       TXL     ENDA,2,0             IF DOTAG EMPTY, GO TO END.          F2B03800
       LXD     FORTAG-1,1           INITIALIZE                          F2B03810
       SXD     TINF30,1             FORTAG                              F2B03820
       SXD     TAG20,1              TEST                                F2B03830
       SXD     TAG90,1              INSTRUCTIONS.                       F2B03840
PAT01  CLA     FRSTAG               INITIALIZE NEW TAG NAME BASE.       F2B03850
       STO     NEWTAG                                                   F2B03860
       TRA     NEST                                                     F2B03870
*      ***                                                              F2B03880
ENDA   TSX     (TAPE),4             WRITE LABEL RECORD                  F2B03890
       PZE     NSTCM2,,(WBNP)       FOR DOTAG B.                        F2B03900
       PZE     DTGBL,,FTAPE2        FILE (LABEL ONLY).                  F2B03910
*      ***                                                              F2B03920
END    TSX     (TAPE),4             WRITE EOF                           F2B03930
       PZE     ,,(WEFP)             AFTER                               F2B03940
       PZE     FIL2L,,FTAPE4        TAGTAG.                             F2B03950
       CLA     $LADDS+4             MAKE INDICATION IN                  F2B03960
       STA     END05                TABLE                               F2B03970
       ADD     L(1)A                DRMTAG.                             F2B03980
       STA     END06                OF                                  F2B03990
       CLA     35ONES               END                                 F2B04000
END05  STO     **                   OF                                  F2B04010
END06  STO     **                   ENTRIES.                            F2B04020
       LXD     L(5),1                                                   F2B04030
END10  CLA     LADDIN+5,1           STORE                               F2B04040
       SUB     L(1)A                TABLE                               F2B04050
       STA     END15                WORD COUNTS IN                      F2B04060
       CLA     LADDIN+5,1           WD PRECEDING EACH TABLE OF          F2B04070
       ANA     ADDMSK               DRMTAG,                             F2B04080
       SUB     $LADDS+5,1           NAMEKEY,                            F2B04090
       SSP                          TSXCOM,                             F2B04100
END15  STO     **                   TRASTO,                             F2B04110
       TIX     END10,1,1            CHATAG.                             F2B04120
       PSE     96                   RESTORE SENSE LIGHTS                F2B04130
       LXD     END80,1              SL 100 ON, FORVAL EMPTY             F2B04140
       TXH     END20,1,0            SL 99 ON, DOTAG EMPTY.              F2B04150
       PSE     100                                                      F2B04160
END20  LXD     END85,1                                                  F2B04170
       TXH     END30,1,0                                                F2B04180
       PSE     99                                                       F2B04190
*      ***                                                              F2B04200
END30  TSX     (TAPE),4             WRITE EOF                           F2B04210
       PZE     ,,(WEFP)             AFTER                               F2B04220
       PZE     FIL6L,,FTAPE2        DOTAGB.                             F2B04230
       LXD     DOREC,4              SAVE DOTAG RECORD COUNT             F2B04240
       SXD     DORCCT,4             FOR LATER BLOCKS,                   F2B04250
       SXA     SKPT,4               AND SET SKIP COMMAND.               F2B04260
*      ***                                                              F2B04270
       TSX     (TAPE),4             POSITION TAPE                       F2B04280
       PZE     SKPT,,(SKBP)         TO READ DOTAG                       F2B04290
       PZE     DTGBL,,FTAPE2        TABLE.                              F2B04300
*      ***                                                              F2B04310
       TSX     (TAPE),4             REWIND TAGTAG TAPE                  F2B04320
       PZE     REWIND,,(SKBP)       FOR LATER                           F2B04330
       PZE     TRLVL,,FTAPE4        POSITIONING.                        F2B04340
       TRA     MKDO                 GO TO FORM DO TABLE.                F2B04350
TRLVL  BCI     1,TRALEV                                                 F2B04360
END80  PZE                          ES. (DEC IS 1 IF 4VAL NOT EMPTY)    F2B04370
END85  PZE                          ES. (DEC IS 1 IF DOTAG NOT EMPTY)   F2B04380
*      ***                                                              F2B04390
NEST   TSX     (TAPE),4             READ ONE                            F2B04400
       PZE     NSTCOM,,(RBEC)       NEST OF                             F2B04410
       PZE     DTGL,,FTAPE3         DOTAGA.                             F2B04420
*      ***                                                              F2B04430
       NZT     (SCHU)+FTAPE3        TEST FOR EOF.                       F2B04440
       TRA     TETAPE                                                   F2B04450
*      ***                                                              F2B04460
       CLA     (SCHU)+FTAPE3                                            F2B04470
       STO     NSTSCH                                                   F2B04480
       ANA     ADDMSK               INTO ADD OF AC                      F2B04490
       SUB     DTGZAD                                                   F2B04500
       TMI     NEST20               IF STORAGE EXCEEDED,                F2B04510
       TZE     NEST20                                                   F2B04520
       TSX     ERROR6,4             SOURCE PROGRAM ERROR.               F2B04530
NEST20 PAX     0,2                                                      F2B04540
NEST30 CLA     L(0)                 INITIALIZING INSTRUCTIONS.          F2B04550
       STO     ATSW                                                     F2B04560
       SXD     XC,2                 PUT C(XRB) IN XC                    F2B04570
       SXD     DOTAG-1,2            INITIALIZE                          F2B04580
       SXD     TRW20,2              THAT                                F2B04590
       SXD     TRW50,2              TEST                                F2B04600
       SXD     SPC040,2             END OF                              F2B04610
       SXD     SPC090,2             DONEST.                             F2B04620
       LXA     ADTXX,4              INIT                                F2B04630
       SXD     ADTXX,4              DECS                                F2B04640
       LXA     RESXX,4              FROM                                F2B04650
       SXD     RESXX,4              ADDRESSES.                          F2B04660
       CLA     LADDIN+3             GET UPPER TERMINUS NAMKEY.          F2B04670
       ARS     18                   TABLE IN ADDRESS,                   F2B04680
       SUB     $LADDS+3             MINUS CURRENT FOR XR VALUE,         F2B04690
       STA     NAMXX                AND INITLZ NAMXX                    F2B04700
       ALS     18                   (ADD WILL GET LOWER TERMINUS,       F2B04710
       STD     NAMXX                DEC NEXT-PENDING FOR THIS NEST)     F2B04720
       TRA     DOFOR                IF NO ERROR, GO TO DOFOR.           F2B04730
NSTCOM IORT    DOTAG,,201*M/N*9                                         F2B04740
NSTSCH PZE                                                             $F2B04750
DTGL   BCI     1,DOTAGA                                                 F2B04760
FIL2L  BCI     1,EOF2                                                   F2B04770
FIL6L  BCI     1,EOF6                                                   F2B04780
SKPT   MZE     **,,1                                                    F2B04790
NESTEN LXD     L(4),2               PUT END OF NEST INDICATION          F2B04800
       CLA     35ONES               IN TAGTAG, CONSISTING OF            F2B04810
NEST80 STO     $E1+4,2              FOUR WDS OF 35 ONES.                F2B04820
       TIX     NEST80,2,1                                               F2B04830
       TSX     TAGENT,4             ENTER IN TAGTAG AND                 F2B04840
       CLA     L(1)                 SET ADDED TAG SWITCH                F2B04850
       STO     ATSW                 AND GO TO DRMENT TO                 F2B04860
       TSX     DRMENT,4             PROCESS ADDED TAGS                  F2B04870
       LXD     ADTXX,1              TRANSFER                            F2B04880
       SXD     NEST88,1             TO DRUM TABLE NAME                  F2B04890
       LXA     ADTXX,1              ALL ENTRIESP                        F2B04900
NEST85 TXL     NEST88,,0            IN CORE TABLE ADTAG                 F2B04910
NEST86 CLA     ADTAGZ+1,1           EXCEPT                              F2B04920
       TMI     NEST87               RESET                               F2B04930
       STO     $E2                  ENTRIES                             F2B04940
       CLA     ADTAGZ,1                                                 F2B04950
       STO     $E1                                                      F2B04960
       PDX     0,2                                                      F2B04970
       CLA     DOTGZ,2                                                  F2B04980
       STD     $E1                                                      F2B04990
       SXD     NEST85,1                                                 F2B05000
       CLA     NAMKEY                                                   F2B05010
       TSX     $LIST,4                                                  F2B05020
       LXD     NEST85,1                                                 F2B05030
NEST87 TXI     NEST88,1,-2                                              F2B05040
NEST88 TXH     NEST86,1,0                                               F2B05050
NST100 LXD     DOTAG-1,1                                                F2B05060
       TRA     NST120                                                   F2B05070
NST110 CLA     DOTGZ+8,1            DOES BIT 20 WD 9 OF THIS DOTAG      F2B05080
       ANA     BBIT                 EQ 1.                               F2B05090
       TZE     NST120               AND                                 F2B05100
       CLA     DOTGZ-1,1            DOES BIT 18 WD9 OF PRIOR DOTAG      F2B05110
       ANA     ABIT                 EQ 1.                               F2B05120
       TNZ     NST120                                                   F2B05130
       CLA     ADDMSK               YES. ERASE DEC WD 9                 F2B05140
       ANS     DOTGZ+8,1            OF PRIOR DOTAG.                     F2B05150
NST120 TXI     NST130,1,9                                               F2B05160
NST130 TXL     NST110,1,200*M/N*9-9                                     F2B05170
       CLA     DOREC                WRITE                               F2B05180
       ADD     L(1)                 DOTAG                               F2B05190
       STO     DOREC                ON                                  F2B05200
       LXA     NSTSCH,4      SET THE DECREMENT OF THE                  $F2B05210
       TXI     *+1,4,-DOTAG  CHANNEL COMMAND WITH THE                  $F2B05220
       SXD     NSTCM2,4      WORD COUNT.                               $F2B05230
*      ***                                                              F2B05250
NEST90 TSX     (TAPE),4             WRITE A                             F2B05260
       PZE     NSTCM2,,(WBNC)       NEST OF                             F2B05270
       PZE     DTGBL,,FTAPE2        DOTAGB.                             F2B05280
       TRA     NEST                 RETURN FOR NEXT NEST.               F2B05290
NSTCM2 IOCT    DOTAG,0,0           (DEC INITIALIZED.                   $F2B05300
DTGBL  BCI     1,DOTAGB                                                 F2B05310
DOFOR  LXD     XC,1                 OBTAIN                              F2B05320
       TXI     DOF10,1,9            NEXT BACK DO,                       F2B05330
DOF10  TXH     NESTEN,1,200*M/N*9   IF ANY.                             F2B05340
       TSX     DOINFO,4             USE DOINFO                          F2B05350
       TRA     TAG00                AND GO TO TAG00 ROUTINE.            F2B05360
DOFEND LXD     XC,1                 IS A COUNTER                        F2B05370
       CLA     DOTGZ+8,1                                                F2B05380
       ANA     BIT19                                                    F2B05390
       TZE     MAKESC                                                   F2B05400
       CAL     DOTGZ+5,1            NECESSARY BECAUSE OF                F2B05410
       ANA     2BITS                TRANSFERS OR COMPUTATION WITH       F2B05420
       TNZ     DOF15                SYMBOL.                             F2B05430
       CLA     BIT20                TEST FOR                            F2B05440
       ANA     DOTGZ+6,1            DELTA TWO                           F2B05450
       TZE     DOF20                INSERT                              F2B05460
DOF15  CLA     DOTGZ+6,1            HAS A COUNTER BEEN                  F2B05470
       ANA     BITTWO               FOUND.                              F2B05480
       TNZ     DOF40                IF NOT,                             F2B05490
       TRA     MAKESC               MAKE ONE. (RETURN IS TO DOF40)      F2B05500
DOF20  CLA     DOTGZ+8,1            HAS A TEST                          F2B05510
       PDX     0,2                  BEEN                                F2B05520
       TXH     DOF25,2,0            FOUND.                              F2B05530
       TRA     MAKESC               NO, MAKE A COUNTER.                 F2B05540
DOF25  CLA     DOTGZ+5,1            YES, HAS SYM OCCURRED WITH          F2B05550
       ANA     SUBBIT               RELCON NOT AS TYPE ONE CARRY.       F2B05560
       TNZ     DOF40                IF YES, GO TO DOF40                 F2B05570
DOF30  CLA     DOTGZ+8,1            IF SYM HAS NOT OCCURRED WITH        F2B05580
       ARS     12                   RELCON OR IN SUCH OCCURRENCES       F2B05590
       PDX     0,2                  WAS ALWAYS A TYPE ONE               F2B05600
       TXL     DOF40,2,11           CARRY, IS CURRECT TEST              F2B05610
       CLA     BBIT                                                     F2B05620
       ORS     DOTGZ+8,1                                                F2B05630
DOF40  CLA     DOF50                MADE. TAKE SIGN AND                 F2B05640
       ANS     DOTGZ+8,1            TEST TABLE INTEGER OUT              F2B05650
       TRA     DOFOR                OF TEST WORD AND EXIT.              F2B05660
DOF50  OCT     7777777777                                               F2B05670
MAKESC CLA     L(4)                 INITIALIZE                          F2B05680
       STO     DOSUBS               DOSUBS AND OTHER LOCATIONS          F2B05690
       CLA     L(0)                 USED IN 1NS00.                      F2B05700
       STO     RCSUBS                                                   F2B05710
       STO     DORC                                                     F2B05720
       STO     $C1                                                      F2B05730
       STO     CARWRD                                                   F2B05740
       CLA     NEWTAG               GET A NAME                          F2B05750
       STO     TS                   FOR THIS                            F2B05760
       ADD     L(1)A                SUBSCRIPT AND                       F2B05770
       STO     NEWTAG               UP DATE NEWTAG.                     F2B05780
       TSX     1NS00,4              USE 1NS00 FOR TEST INFO,LIST.       F2B05790
       CLA     L(6)                 SET UP TAG TAG                      F2B05800
       ORA     L(4)A                ENTRY                               F2B05810
       ORA     CARWRD                                                   F2B05820
       SLW     $E4                                                      F2B05830
       CLA     TS                                                       F2B05840
       STO     $E3                                                      F2B05850
       CLA     L(0)                                                     F2B05860
       STO     $E2                                                      F2B05870
       CLA     XC                                                       F2B05880
       ARS     18                                                       F2B05890
       ORA     ALPHA                                                    F2B05900
       STO     $E1                                                      F2B05910
       TSX     TAGENT,4             ENTER INTO TAGTAG.                  F2B05920
       LXD     XC,1                                                     F2B05930
       CLA     ABIT                                                     F2B05940
       ORS     DOTGZ+8,1                                                F2B05950
       TRA     DOF40                RETURN                              F2B05960
DOINFO CLA     DOTGZ,1              FOR THE DO FORMULA WHOSE            F2B05970
       PAX     0,2                  INDEX IS IN XRA,                    F2B05980
       ANA     DECMSK               ESTABLISH                           F2B05990
       STO     ALPHA                ALPHA,BETA,XC,XL                    F2B06000
       PXD     0,2                                                      F2B06010
       STO     BETA                                                     F2B06020
       PXD     0,1                                                      F2B06030
       STO     XC                                                       F2B06040
       CLA     DOTGZ+5,1                                                F2B06050
       ANA     DECMSK                                                   F2B06060
       STO     LC                                                       F2B06070
       TRA     1,4                                                      F2B06080
TAG00  LXD     MAXFTG,1             THIS ROUTINE.                       F2B06090
       TRA     TAG20                SELECTS EVERY TAG                   F2B06100
TAG05  CLA     FORTZ,1              IN THE RANGE OF THE                 F2B06110
       ANA     DECMSK               CURRENT DO WHICH                    F2B06120
       CAS     ALPHA                CONTAINS THE SUBSCRIPT              F2B06130
       TRA     TAG30                SYMBOL OF THE CURRENT               F2B06140
       TSX     ERRORM,4             THE IFN OF A SUBSCRIPTED            F2B06150
       REM                          VARIABLE (XR1 WD IN FORTAG)         F2B06160
       REM                          SHOULD NOT BE SAME AS IFN           F2B06170
       REM                          OF A DO (DECR OF FIRST WD OF        F2B06180
       REM                          DOTAG ENTRY WITH XR VALUE IN        F2B06190
       REM                          XC). 4TAG IS REC11 FILE 5           F2B06200
       REM                          TAPE 2, DOTAG IS FILE 1 TP 3.       F2B06210
TAG10  TXI     TAG20,1,-1           PREVIOUSLY BEEN                     F2B06220
TAG20  TXH     TAG05,1,0            PROCESSED, AND (DEC IS 4TAG IX)     F2B06230
       TRA     DOFEND               COMPLETELY PROCESSES                F2B06240
TAG25  LXD     TAG40,1              THE TAG. THE RETURN                 F2B06250
       TRA     TAG10                IS TO DOFEND                        F2B06260
TAG30  CAS     BETA                 COMPARE WITH BETA.                  F2B06270
TAG40  TXL     DOFEND,,0            END RANGE. (DEC HAS 4TAG IX)        F2B06280
       NOP                          IF ENTRY IS NEGATIVE,               F2B06290
       CLA     FORTZ,1              THEN IT HAS ALREADY                 F2B06300
       TMI     TAG10                BEEN PROCESSED.                     F2B06310
       ANA     ADDMSK               STORE                               F2B06320
       STO     $TAG                 IN TAG,                             F2B06330
       SXD     TAG40,1              AND SAVE INDEX.                     F2B06340
       TSX     SUBCOM,4             OBTAIN SUB. COM.                    F2B06350
       NOP                                                              F2B06360
       TSX     IDENT,4              USE IDENT.                          F2B06370
       TRA     TAG25                SC. NOT WANTED.                     F2B06380
       TSX     NAME,4               SC. TO BE PROCESSED. USE NAME.      F2B06390
       TSX     BRANCH,4                                                 F2B06400
       TSX     SCEND,4                                                  F2B06410
       TSX     TAGENT,4                                                 F2B06420
TAG50  LXD     L(5),2                                                   F2B06430
TAG52  CLA     X1+5,2               ENTER BIT 18 WD 9                   F2B06440
       TZE     TAG58                OF MATCHING DOTAG                   F2B06450
       PDX     0,1                  IF 1ST SUBSCR OR                    F2B06460
       TXH     TAG56,2,4            IF THERE IS NO                      F2B06470
       CLA     CR1                  TYPE 1 CARRY INTO                   F2B06480
       TXH     TAG54,2,2            THE 2ND AND 3RD                     F2B06490
       ARS     2                    SUBSCRS RESPECTIVELY.               F2B06500
TAG54  ANA     CARWRD                                                   F2B06510
       TNZ     TAG58                                                    F2B06520
TAG56  CLA     ABIT                 ENTER BIT 18 WD 9.                  F2B06530
       ORS     DOTGZ+8,1                                                F2B06540
TAG58  TIX     TAG52,2,2                                                F2B06550
       LXD     L(5),4               TAG 60 SEQUENCE CONCERNS            F2B06560
TAG60  CLA     X1+5,4               TESTS AND ADDED TAGS.               F2B06570
       TZE     TAG68                FOR EACH INDEXED SUBSCRIPT,         F2B06580
       PDX     0,1                  DETERMINE F IRST WHETHER            F2B06590
       CLA     RCSUBS               OR NOT IT                           F2B06600
       ORA     DORC                 OCCURS WITH                         F2B06610
       TZE     TAG66                A RELCON.                           F2B06620
       TXL     TAG64,4,1            IF SO, PUT IN                       F2B06630
       CLA     CR1                  SUBBIT MEANING A TEST               F2B06640
       TXH     TAG62,4,3            IS NEEDED UNLESS                    F2B06650
       ARS     2                    THE 1ST AND 2ND                     F2B06660
TAG62  ANA     CARWRD               SUBSCR PROMOTE A                    F2B06670
       TNZ     TAG68                TYPE ONE CARRY  (LEFT               F2B06680
TAG64  CLA     SUBBIT               OR CENTER RESPECTIVELY)             F2B06690
       ORS     DOTGZ+5,1            IS                                  F2B06700
TAG65  TXL     TAG68,,0             NEEDED.                             F2B06710
TAG66  CLA     BIT19                                                    F2B06720
       ORS     DOTGZ+8,1                                                F2B06730
       CLA     DOTGZ+5,1            IF THE SS DOES NOT OCCUR            F2B06740
       ANA     2BITS                WITH A RELCON, DETERMINE WHETHER OR F2B06750
       TNZ     TAG68                NOT A COUNTER HAS BEEN REQUESTED.   F2B06760
       SXD     TAG65,4              IF SO, TAKE NEXT INDEXED SUBSCR.    F2B06770
       TSX     TEST,2               IF NOT, USE ROUTINE TEST.           F2B06780
       LXD     TAG65,4              THEN TAKE NEXT INDEXED SUBSCRIPT.   F2B06790
TAG68  TIX     TAG60,4,2                                                F2B06800
TAG70  LXD     TAG40,1              SET ALL OCCURRANCES                 F2B06810
TAG72  CLA     FORTZ,1              OF THIS TAG, IN FORTAG,             F2B06820
       ANA     DECMSK               IN THE RANGE OF THIS                F2B06830
       CAS     BETA                 DO, NEGATIVE.                       F2B06840
TAG75  TXL     TAG25,,0                                                 F2B06850
       NOP                                                              F2B06860
       CLA     FORTZ,1                                                  F2B06870
       ANA     ADDMSK                                                   F2B06880
       SUB     $TAG                                                     F2B06890
       TNZ     TAG80                                                    F2B06900
       CAL     L(MZ)                                                    F2B06910
       ORS     FORTZ,1                                                  F2B06920
TAG80  TXI     TAG90,1,-1                                               F2B06930
TAG90  TXH     TAG72,1,0            (DEC HAS 4TAG INDEX)                F2B06940
       TRA     TAG25                RETURN FOR NEXT TAG.                F2B06950
       REM SCEND COLLECTS TAGTAG ENTRY AND MAKES TABLE ENTRY            F2B06960
SCEND  CLA     GROUP                ALL OF SCEND IS CONCERNED           F2B06970
       STO     TAG1                 WITH GENERATING THE                 F2B06980
       CLA     DOSUBS               TAGTAG ENTRY FROM ITS               F2B06990
       ORA     DUPES                                                    F2B07000
       ARS     18                   VARIOUS COMPONENTS.                 F2B07010
       ORS     TAG1                                                     F2B07020
       CLA     RCSUBS                                                   F2B07030
       ORA     DORC                                                     F2B07040
       ARS     15                                                       F2B07050
       ORS     TAG1                                                     F2B07060
       CLA     DUPES                                                    F2B07070
       ARS     9                                                        F2B07080
       ORS     TAG1                                                     F2B07090
       CAL     CARWRD                                                   F2B07100
       ORS     TAG1                                                     F2B07110
       LXD     L(5),1                                                   F2B07120
SCE010 CLA     L(1)                                                     F2B07130
       CAS     $C1+5,1              GENERATES THE THREE BIT             F2B07140
       TRA     SCE020               TAG SHOWING WHICH                   F2B07150
       TRA     SCE020               COEFFICIENTS ARE GREATER            F2B07160
       PXD     0,1                  THAN ONE.                           F2B07170
       TXL     SCE015,1,1                                               F2B07180
       SUB     L(1)                                                     F2B07190
SCE015 ARS     6                                                        F2B07200
       ORS     TAG1                                                     F2B07210
SCE020 TIX     SCE010,1,2                                               F2B07220
       CLA     TAG1                 TAG1 IS NOW COMPLETE.               F2B07230
       STO     $E4                  CONSTRUCT THE TAGTAG                F2B07240
       CLA     $TAG                 ENTRY                               F2B07250
       ALS     18                                                       F2B07260
       ADD     TS                                                       F2B07270
       STO     $E3                                                      F2B07280
       CLA     X3                                                       F2B07290
       ARS     18                                                       F2B07300
       ADD     X2                                                       F2B07310
       STO     $E2                                                      F2B07320
       CLA     X1                                                       F2B07330
       ARS     18                                                       F2B07340
       ADD     ALPHA                                                    F2B07350
       STO     $E1                                                      F2B07360
       TRA     1,4                                                      F2B07370
TEST   CLA     DOTGZ+8,1            IF A GOOD                           F2B07380
       TMI     1,2                  TEST PREVIOUSLY FOUND, EXIT.        F2B07390
       SXA     TEST80,2             SAVE RETURN.                        F2B07400
       CLA     NRSUBS               IS TAG THREE                        F2B07410
       SUB     L(3)                 DIMENSIONAL.                        F2B07420
       TNZ     TEST05               NO, TEST IS VALID                   F2B07430
       CLA     DUPES                ARE THERE                           F2B07440
       ANA     SUBMSK               DUPE SUBSCRIPTS.                    F2B07450
       TNZ     TEST05               YES, TEST IS VALID.                 F2B07460
       PXD     0,1                  IS CURRENT SUBSCRIPT                F2B07470
       SUB     X3                   THE RIGHTMOST.                     $F2B07480
       TZE     TEST05               YES, TEST IS VALID.                $F2B07490
       CLA     DOSUBS               ARE THE OTHER                       F2B07500
       ANA     SUBMSK               SUBSCRIPTS                          F2B07510
       ERA     SUBMSK               DOSUBS.                             F2B07520
       TNZ     TEST05               NO, TEST IS VALID.                  F2B07530
       CLA     DOTGZ+5,1            IS RIGHTMOST                       $F2B07540
       ANA     DECMSK               SUBSCRIPT CONTROLLED                F2B07550
       STO     TCL                                                      F2B07560
       SUB     L3                   BY A LOWER LEVEL DO.               $F2B07570
       TMI     TEST05               NO, TEST IS VALID.                 $F2B07580
       TRA     TSTPCH               YES  GO TO PATCHED PORTION         $F2B07590
RETRN  SUB     L2ORL1               IS CENTER ,OR LEFT, SS CONTROLLED  $F2B07600
       TMI     TEST05               BY A LOWER LEVEL DO. NO,TEST IS  OK$F2B07610
       CLA     L3                   ARE TWO OUTER                      $F2B07620
       SUB     L2ORL1               DOS APART                          $F2B07630
       SSP                          BY ONLY                             F2B07640
       SUB     L(1)                 ONE LEVEL.                          F2B07650
       TNZ     TEST80               NO, TEST IS NOT VALID.              F2B07660
       CLA     L3                   YES, FIND SUBSCRIPT CONTROLLED      F2B07670
       SUB     L2ORL1               BY OUTER   DO.                     $F2B07680
       TMI     TEST03                                                  $F2B07690
       LXD     X2ORX1,2             CENTER (OR LEFT) SS IS CONTROLLED  $F2B07700
       CAL     DOTGZ+7,2            BY OUTER DO. PICK UP TRA BITS      $F2B07710
       LXD     L2ORL1,2             AND LEVEL NO.                      $F2B07720
       TRA     TEST04                                                   F2B07730
TEST03 LXD     X3,2                 RIGHT SUBSCRIPT IS CONTROLLED       F2B07740
       CAL     DOTGZ+7,2            BY OUTER DO. PICK UP TRA BITS       F2B07750
       LXD     L3,2                 AND LEVEL NO.                       F2B07760
TEST04 SXA     *+1,2                IS THERE A TRA FROM THE RANGE OF    F2B07770
       ALS     **                   THE OUTER DO BACK TO THE RANGE      F2B07780
       PBT                          OF THE OUTER DO.                    F2B07790
       TRA     TEST05               NO, TEST IS VALID.                  F2B07800
       TRA     TEST80               TEST NO GOOD, LEAVE.                F2B07810
TEST05 TIX     TEST10,4,1           XRC CONTAINS 5,3,1                  F2B07820
TEST10 PXD     0,4                  DEPENDING ON POSITION NR            F2B07830
       ALS     3                    1,2,3. CONSTRUCT A                  F2B07840
       ORA     GROUP                TABLE SEARCH MASK IN                F2B07850
       TXL     TEST20,4,1           WHICH THE FORTH OCTAL               F2B07860
       STO     TEST85               DIGIT IS THE CARRY BIT              F2B07870
       CLA     CARWRD               INFO. FOR THE POSITION              F2B07880
       ALS     5,4                  BEING CONSIDERED, THE               F2B07890
       ANA     TEST90               FIFTH OCTAL DIGIT IS THE            F2B07900
       ORA     TEST85               POSITION BIT, AND THE               F2B07910
TEST20 LXD     TEST35,4             SIXTH OCTAL DIGIT                   F2B07920
TEST30 CAS     TESTAB+15,4          IS THE GROUP NUMBER.                F2B07930
       TXI     TEST40,4,-1          SEARCH TESTAB FOR                   F2B07940
TEST35 TXL     TEST50,0,15          ENTRY AND CONSIDER                  F2B07950
       TXI     TEST40,4,-1          C(XRC) AFTER SEARCH, IF             F2B07960
TEST40 TXH     TEST30,4,0           ENTRY NOT FOUND,C(XRC)=0.           F2B07970
TEST50 SXD     TEST60,4             COMPARE THIS INTEGER                F2B07980
       CLA     DOTGZ+8,1            WITH PREVIOUS INTEGER,              F2B07990
       PDX     0,4                  IF ANY. IF NEW NR. IS LESS          F2B08000
       TXL     TEST75,4,0           THAN OLD, USE NEW TAG               F2B08010
       ARS     12                   FOR TEST. OTHERWISE                 F2B08020
       PDX     0,4                  USE OLD TAG.                        F2B08030
TEST60 TXL     TEST80,4,0           (DEC HAS TEST TAB NR FOR THIS S.C.) F2B08040
TEST70 CLA     TEST95               IF THE NEW TAG IS                   F2B08050
       ANS     DOTGZ+8,1            USED, AND C(XRC)                    F2B08060
TEST75 LXD     TEST60,4             AFTER SEARCH WAS ZERO,              F2B08070
       PXD     0,4                  SET DOTAGZ+8 WORD                   F2B08080
       ARS     6                    NEGATIVE.                           F2B08090
       ORA     TS                                                       F2B08100
       ALS     18                                                       F2B08110
       ORS     DOTGZ+8,1                                                F2B08120
       TXH     TEST80,4,0                                               F2B08130
       CAL     L(MZ)                                                    F2B08140
       ORS     DOTGZ+8,1                                                F2B08150
TEST80 AXT     **,2                                                     F2B08160
       TRA     1,2                                                      F2B08170
TEST85 PZE                          STORAGE FOR COMPOSED TEST WORD.     F2B08180
TEST90 OCT     300000000            BITS 10, 11                         F2B08190
TEST95 OCT     777777                                                   F2B08200
TESTAB OCT     241000000            FIRST SIGNIF DIGIT CONTAINS         F2B08210
       OCT     221000000            A TWO IF TYPE ONE CARRY ,           F2B08220
       OCT     244000000            ONE IF TYPE TWO FROM LEFT OR        F2B08230
       OCT     222000000            CENTER. (4TH OCT DIG). NEXT         F2B08240
       OCT     141000000            HAS 4 IF POSIT OF SUBSC IS          F2B08250
       OCT     121000000            LEFT, 2 IF CENTER, 0 IF RIGHT       F2B08260
       OCT     144000000            (5TH OCT DIGIT).   FINAL DIG HAS    F2B08270
       OCT     122000000            GROUP NR. (6TH OCT DIG).            F2B08280
       OCT     45000000                                                 F2B08290
       OCT     41000000                                                 F2B08300
       OCT     21000000                                                 F2B08310
       OCT     44000000                                                 F2B08320
       OCT     22000000                                                 F2B08330
       OCT     43000000                                                 F2B08340
       OCT     23000000                                                 F2B08350
TCL    PZE                                                              F2B08360
SUBMSK OCT     3000000                                                  F2B08370
CARRY  SXD     CAR05,4              SAVE LINKAGE                        F2B08380
       CLA     X1+4,2               PUT LEFT INDEX                      F2B08390
       PDX     0,1                  IN XRA                              F2B08400
       CLA     X1+6,2               PUT RIGHT INDEX                     F2B08410
       PDX     0,4                  IN XRC                              F2B08420
       CLA     DOTGZ+5,1            TEST LEFT SUB. DO                   F2B08430
       ANA     CARMSK               CARRY BITS.                         F2B08440
       TZE     CAR30                EXIT IF NO CARRY.                   F2B08450
       CLA     DOTGZ+6,1            COMPARE                             F2B08460
       ANA     DECMSK               NO CARRY TRA LEVEL                  F2B08470
       CAS     LL                   AND LOW LEVEL.                      F2B08480
       TRA     CAR30                EXIT                                F2B08490
CAR05  TXL     CAR30,,0                                                 F2B08500
       CLA     DOTGZ+5,1            COMPUTE FOR LEFT                    F2B08510
       ANA     ADDMSK               SUBSCRIPT THE QUANTITY              F2B08520
       STO     CAR40                C*X (COEF. TIMES ADDED              F2B08530
       LDQ     CAR40                VALUE).                             F2B08540
       MPY     $C1+4,2              COMPUTE FOR RIGHT                   F2B08550
       STQ     CAR40                SUBSCRIPT THE QUANTITY              F2B08560
       LDQ     $D1                  C*N3*D(L)  (COEFF. TIMES            F2B08570
       TXH     CAR10,2,2            INCREMENT TIMES DIM. OF             F2B08580
       LDQ     $D2                  LEFT SUBSCRIPT).                    F2B08590
CAR10  MPY     DOTGZ+4,4            IF THESE QUANTITIES                 F2B08600
       MPY     $C1+6,2              ARE UNEQUAL,                        F2B08610
       ALS     17                   EXIT                                F2B08620
       SUB     CAR40                                                    F2B08630
       TNZ     CAR30                OBTAIN LEFT                         F2B08640
       CLA     DOTGZ+5,1            SUB. DOTAG                          F2B08650
       ANA     CARMSK               CARRY BITS AGAIN.                   F2B08660
       ARS     15                   TEST FOR                            F2B08670
       LBT                          CARRY TYPE ONE                      F2B08680
       TRA     CAR15                OR CARRY TYPE                       F2B08690
       CLA     CR1                  TWO.                                F2B08700
       TRA     CAR20                OBTAIN PROPER                       F2B08710
CAR15  CLA     CR2                  TAGTAG CARRY BIT,                   F2B08720
CAR20  TXH     CAR25,2,2            SHIFT IF NECESSARY FOR              F2B08730
       ARS     2                    CENTER SUB. AND                     F2B08740
CAR25  ORS     CARWRD               PLACE IN CARWRD.                    F2B08750
CAR30  LXD     CAR05,4              EXIT                                F2B08760
       TRA     1,4                                                      F2B08770
CAR40  PZE                          E.S.                                F2B08780
BRANCH SXD     BRA45,4              IF THERE ARE RELCONS                F2B08790
       CLA     NRRC                 (NOT DORC) IN THE SC,               F2B08800
       TZE     BRA10                USE                                 F2B08810
       TRA     CORES                RELCON, (CODING BLOCK FOR MIXED RCS.F2B08820
BRA10  LXD     NRDS,1               THIS ROUTINE                        F2B08830
       TXH     BRA30,1,1            CONDENSES                           F2B08840
BRA20  TSX     1NS00,4              DUPLICATE                           F2B08850
       TRA     BRA90                SUBSCRIPTS                          F2B08860
BRA30  TXH     BRA50,1,2            AND                                 F2B08870
       CLA     DUPES                TRANSFERS                           F2B08880
       TNZ     BRA20                TO                                  F2B08890
BRA40  TSX     2NS00,4              ROUTINES                            F2B08900
BRA45  TXL     BRA90,,0             1NS00, 2NS00, 3NS00                 F2B08910
BRA50  LXD     DUPES,4              AFTER                               F2B08920
       TXH     BRA20,4,6            PROCESSING,                         F2B08930
       TXL     BRA80,4,0            RETURN                              F2B08940
       TXH     BRA60,4,5            IS TO                               F2B08950
       TXL     BRA60,4,3            DRMENT OR                           F2B08960
       CLA     L(3)                 TAG00                               F2B08970
       TRA     BRA70                                                    F2B08980
BRA60  CLA     L(5)                                                     F2B08990
BRA70  STO     DOSUBS                                                   F2B09000
       TRA     BRA40                                                    F2B09010
BRA80  TSX     3NS00,4                                                  F2B09020
BRA90  LXD     BRA45,4                                                  F2B09030
       TRA     1,4                                                      F2B09040
RSR    SXD     RSR20,4              SAVE LINKAGE                        F2B09050
       SXD     RSR30,1              SAVE INDEX                          F2B09060
       CLA     DOTGZ+6,1            HAS COUNTER ADJUSTMENT              F2B09070
       ANA     BIT18                INSTRUCTION BEEN ENTERED.           F2B09080
       TNZ     RSR10                IF SO, GO TO RSR10                  F2B09090
       CLA     BIT18                IF NOT, ENTER IN                    F2B09100
       ORS     DOTGZ+6,1            TRASTO AN ENTRY TO CAUSE            F2B09110
       CLA     DOTGZ,1              THE COUNTER TO BE                   F2B09120
       SSM                                                              F2B09130
       STO     $E1                  DECREASED BY N1, WHICH              F2B09140
       CLA     DOTGZ+5,1            WILL MAKE IT USEFUL AS              F2B09150
       ANA     DECMSK               AS A RESET SUB. COMB.               F2B09160
       ARS     18                                                       F2B09170
       STO     $E2                                                      F2B09180
       CLA     DOTGZ+8,1                                                F2B09190
       ANA     DECMSK                                                   F2B09200
       ORA     DOTGZ+2,1                                                F2B09210
       STO     $E3                                                      F2B09220
       CLA     TRASTO                                                   F2B09230
       TSX     $LIST,4                                                  F2B09240
RSR10  LXD     RSR30,1              ENTER IN TRASTO                     F2B09250
       CLA     DOTGZ+8,1            AN ENTRY TO CAUSE                   F2B09260
       ANA     DECMSK               THE TAG UNDER                       F2B09270
       ORA     TS                   CONSIDERATION                       F2B09280
       SSM                                                              F2B09290
       STO     $E3                  TO BE RESET                         F2B09300
       CLA     TL2                  BY THE ADJUSTED                     F2B09310
       ARS     18                   COUNTER AT THE                      F2B09320
       ORA     TL1                  PROPER TIMES.                       F2B09330
       STO     $E2                                                      F2B09340
       CLA     DOTGZ,1                                                  F2B09350
       STO     $E1                                                      F2B09360
       CLA     TRASTO                                                   F2B09370
       TSX     $LIST,4                                                  F2B09380
       LXD     RSR20,4                                                  F2B09390
       TRA     1,4                                                      F2B09400
RSR20  PZE                                                              F2B09410
RSR30  PZE                                                              F2B09420
DRMENT SXD     DRM05,4              THIS ROUTINE                        F2B09430
       LXD     ADTXX,2              PROCESSES THE                       F2B09440
       SXD     DRM20,2              ADDED TAG TABLE                     F2B09450
       LXA     ADTXX,2                                                  F2B09460
DRM05  TXL     DRM20,,0                                                 F2B09470
DRM10  CLA     ADTAGZ,2             OBTAIN FIRST ENTRY WORD.            F2B09480
       PDX     0,1                  PUT INDEX IN XRA.                   F2B09490
       ANA     ADDMSK               STORE TAG                           F2B09500
       STO     $TAG                 IN TAG                              F2B09510
       STO     TS                   AND TS                              F2B09520
       PXD     0,1                  PUT INDEX                           F2B09530
       STO     XC                   IN XC                               F2B09540
       SXD     DRM30,2              SAVE INDEX B.                       F2B09550
       CLA     ADTAGZ+1,2           OBTAIN WORD TWO.                    F2B09560
       TMI     DRM40                TRA IF RESET ENTRY.                 F2B09570
       STO     TS                   SAVE NAME IN TS.                    F2B09580
       TSX     DOINFO,4             USE DOINFO                          F2B09590
       TSX     SUBCOM,4             AND                                 F2B09600
       NOP                          OTHER                               F2B09610
       TSX     IDENT,4              ROUTINES                            F2B09620
       TSX     ERRORM,4             SECOND WD OF XR1 DOTAG ENTRY        F2B09630
       REM                          SHOULD BE EQUAL TO S1,S2,OR         F2B09640
       REM                          S3. DOTAG IS FROM FILE 1 TAPE 3,    F2B09650
       REM                          AND S1,2,AND 3 COME FROM THE        F2B09660
       REM                          TAU TABLES IN CORE.                 F2B09670
       TSX     BRANCH,4             PROCESS                             F2B09680
       TSX     SCEND,4              ENTRY.                              F2B09690
       CLA     DRMTAG                                                   F2B09700
       TSX     $LIST,4              ENTER RESULT IN DRMTAG.             F2B09710
DRM15  LXD     DRM30,2                                                  F2B09720
       TXI     DRM20,2,-2                                               F2B09730
DRM20  TXH     DRM10,2,0                                                F2B09740
       LXD     DRM05,4                                                  F2B09750
       TRA     1,4                                                      F2B09760
DRM30  PZE                                                              F2B09770
DRM40  PAX     0,4                  FOR RESET ENTRY,                    F2B09780
       ANA     DECMSK               INITIALIZE CELLS                    F2B09790
       STO     TL1                  USED IN RSR ROUTINE.                F2B09800
       PXD     0,4                                                      F2B09810
       STO     TL2                                                      F2B09820
       TSX     RSR,4                                                    F2B09830
       TRA     DRM15                TRA FOR NEXT ENTRY.                 F2B09840
       REM SUBROUTINE TAGADD                                            F2B09850
TAGADD TXH     TAGAD1,2,0           C(IRB) EQ 1 IF NORMAL ADTAG         F2B09860
       PXD     0,1                                                      F2B09870
TAGAD1 LXD     ADTXX,1                                                  F2B09880
       TXL     TAGAD6,1,0                                               F2B09890
       TXH     TAGAD8,2,0           XRB=1,NORMAL ADDED TAG              F2B09900
       ADD     $TAG                                                     F2B09910
       STO     ADTAGZ,1                                                 F2B09920
       CLA     NEWTAG                                                   F2B09930
       LDQ     NEWTAG                                                   F2B09940
       STO     ADTAGZ+1,1                                               F2B09950
       ADD     L(1)A                                                    F2B09960
       STO     NEWTAG                                                   F2B09970
       TXI     TAGAD2,1,-2                                              F2B09980
TAGAD2 SXD     ADTXX,1                                                  F2B09990
TAGAD3 TRA     1,4                                                      F2B10000
TAGAD6 TSX     ERROR8,4             ADTAG TABLE IS FULL.                F2B10010
TAGAD8 STO     ADTAGZ,1                                                 F2B10020
       STQ     ADTAGZ+1,1                                               F2B10030
       TXI     TAGAD2,1,-2                                              F2B10040
       REM INSTR PLUS ONE. XRA CONTAINS INDEX IN FORTAG OF FIRST TAG    F2B10050
       REM FOUND                                                        F2B10060
       REM SUBROUTINE TRAWRD                                            F2B10070
TRWRD  SXD     TRW65,4                                                  F2B10080
       CLA     L(0)                                                     F2B10090
       STO     TRABIT                                                   F2B10100
       CLA     DOTGZ+5,1                                                F2B10110
       STD     TRW30                                                    F2B10120
TRW10  CLA     DOTGZ+7,1            GET T2 WORD                         F2B10130
       ORS     TRABIT               OR INTO TRABIT                      F2B10140
       TXI     TRW20,1,-9           TAKE NEXT DO                        F2B10150
TRW20  TXL     TRW70,1,0            IF NONE, EXIT.                      F2B10160
       CLA     DOTGZ+5,1            GET L WORD                          F2B10170
       PDX     0,4                  PUT L IN XRC.                       F2B10180
TRW30  TXL     TRW70,4,0            EXIT IF DO IS NOT IN R1.            F2B10190
       TXL     TRW10,2,1            IF COMPLETE TEST, GO BACK           F2B10200
TRW35  CLA     DOTGZ+1,1            IF INCOMPLETE, IS THIS A            F2B10210
       SUB     $RSYM2               DO TO BE SKIPPED                    F2B10220
       TNZ     TRW10                IF NOT, GO BACK                     F2B10230
       CLA     DOTGZ+5,1            THIS DO IS TO BE SKIPPED            F2B10240
       STD     TRW60                PUT LEVEL OF THIS DO IN INSTR       F2B10250
TRW40  TXI     TRW50,1,-9           TAKE NEXT DO, IF ANY                F2B10260
TRW50  TXL     TRW70,1,0            IF NOT, EXIT.                       F2B10270
       CLA     DOTGZ+5,1            OBTAIN L WORD.                      F2B10280
       PDX     0,4                  PUT L IN XRC                        F2B10290
TRW60  TXH     TRW40,4,0            IF DO IS IN RANGE R2, GO BACK.      F2B10300
TRW65  TXL     TRW30,,0             OTHERWISE, GO TO TRW30.             F2B10310
TRW70  LXD     TRW65,4                                                  F2B10320
       CLA     L(36)                OBTAIN 36 IN DECREMENT              F2B10330
       SUB     TL2                  36-TL2                              F2B10340
       ARS     18                   IN ADDRESS                          F2B10350
       STA     TRW90                INITIALIZE SHIFT                    F2B10360
       CLA     TL2                  OBTAIN TL2                          F2B10370
       SUB     TL1                  TL2-TL1                             F2B10380
       ARS     18                   IN ADDRESS                          F2B10390
       STA     TRW80                INITIALIZE SHIFT                    F2B10400
       CLA     L(0)                 ACC CONTAINS ZERO                   F2B10410
       LDQ     35ONES               MQ CONTAINS ALL ONES                F2B10420
TRW80  LLS     **                   PUT TL2-TL1 ONES IN AC.             F2B10430
TRW90  ALS     **                   POSITION ONES IN AC.                F2B10440
       ANA     TRABIT               AND IN TRANSFER BITS                F2B10450
       TRA     1,4                  GO BACK TO CALLING INSTR PLUS ONE.  F2B10460
       REM SUBROUTINES TAGENT AND TETAPE                                F2B10470
TAGENT LXD     TAGXX,1              THIS ROUTINE ENTERS                 F2B10480
       TXH     TE10,1,0             ONE ENTRY IN TAGZ,                  F2B10490
       TSX     ERRO11,4             TAGTAG IS FULL.                     F2B10500
TE10   LXD     L(4),2               TRA TO TETAPE.                      F2B10510
TE20   CLA     $E1+4,2                                                  F2B10520
       STO     TAGZ,1                                                   F2B10530
       TXI     TE30,1,-1                                                F2B10540
TE30   TIX     TE20,2,1                                                 F2B10550
       SXD     TAGXX,1                                                  F2B10560
       TRA     1,4                                                      F2B10570
*ROUTI NE TETAPE ENTERS ALL THE VALID ENTRIES IN TAGTAG ON TP. THE LAST F2B10580
*ENTRY  ON TAPE AFTER EACH NEST IS AN ENTRY OF 4 WDS OF 35 ONES.        F2B10590
*      ***                                                              F2B10600
TETAPE TSX     (TAPE),4             REWIND DOTAG A                      F2B10610
       PZE     REWIND,,(SKBP)       TAPE.                               F2B10620
       PZE     DTGL,,FTAPE3                                             F2B10630
       CLA     TAGXX                GET XR VALUE OF                     F2B10640
       ARS     18                   TAGTAG IN DEC AND                   F2B10650
       SUB     TAGXX                COMPUTE NR WDS                      F2B10660
       ALS     18                                                       F2B10670
       STD     TETCOM                                                   F2B10680
       SXA     TET20,4                                                  F2B10690
*      ***                                                              F2B10700
TET10  TSX     (TAPE),4             WRITE                               F2B10710
       PZE     TETCOM,,(WBNP)       TAGTAG                              F2B10720
       PZE     TAGL,,FTAPE4         TABLE.                              F2B10730
TET20  AXT     0,4                                                      F2B10740
       TRA     END                                                      F2B10750
TETCOM IOCT    TAGTAG,0,0          DEC INITIALIZED WC TAGTAG           $F2B10760
TAGL   BCI     1,TAGTAG                                                 F2B10770
IDENT  SXD     ID075,4              SAVE INDEX                          F2B10780
       AXT     18,1                 INITIALIZE IDENT STORAGE            F2B10790
       CLA     L(0)                 TO ZERO                             F2B10800
       STO     IDES                                                     F2B10810
ID010  STO     X1+18,1                                                  F2B10820
       TIX     ID010,1,1                                                F2B10830
       CLA     35ONES               INITIALIZE                          F2B10840
       STO     LL                   LOW LEVEL                           F2B10850
       LXD     L(0),2               COUNT THE SUBSCRIPT                 F2B10860
       LXD     L(5),4               SYMBOLS.                            F2B10870
ID020  CLA     $S1+5,4              STORE COUNT IN                      F2B10880
       TZE     ID030                NRSUBS, AND ALSO IN                 F2B10890
       TXI     ID030,2,1            NRRC, WHICH IS THE                  F2B10900
ID030  TIX     ID020,4,2            COUNT OF REL. CON.                  F2B10910
       PXD     0,2                  SUBSCRIPTS. DO SUBS ARE             F2B10920
       STO     NRRC                 SUBTRACTED OUT LATER.               F2B10930
       STO     NRSUBS                                                   F2B10940
       LXD     XC,1                 COMPARE EACH SYMBOL                 F2B10950
       LXD     LC,2                 IN THE SUB. COMB. WITH              F2B10960
       PSE     TL                   THE SYMBOL OF EACH                  F2B10970
ID050  CLA     DOTGZ+1,1            DO IN THE SUB NEST.                 F2B10980
       LXD     L(5),4               WHEN EQUALITY IS                    F2B10990
ID060  CAS     $S1+5,4              FOUND, GO TO ID120                  F2B11000
       TRA     ID070                IF THE CURRENT DO                   F2B11010
       TRA     ID120                SYMBOL IS NOT FOUND,                F2B11020
ID070  TIX     ID060,4,2            MAKE EXIT FROM ID410                F2B11030
       MSE     TL                                                       F2B11040
       TRA     ID080                                                    F2B11050
ID075  TXL     ID410,,0                                                 F2B11060
ID080  TXL     ID150,2,1            THESE INSTRUCTIONS                  F2B11070
ID090  TXI     ID100,1,9            FIND THE NEXT BACK                  F2B11080
ID100  CLA     DOTGZ+5,1            SUB NEST DO FORMULA,                F2B11090
       STD     ID110                AND RETURN CONTROL                  F2B11100
ID110  TXL     ID090,2,0            TO ID050.                           F2B11110
       PDX     0,2                                                      F2B11120
       TRA     ID050                                                    F2B11130
ID120  MSE     TL                   TURN OFF TEST LIGHT                 F2B11140
       NOP                          AND                                 F2B11150
       PXD     0,1                  ESTABLISH                           F2B11160
       STO     X1+5,4               INDEX                               F2B11170
       PXD     0,2                  AND                                 F2B11180
       STO     L1+5,4               LEVEL FOR THIS SUBSCRIPT.           F2B11190
       CLA     NRRC                 SUBTRACT ONE FROM                   F2B11200
       SUB     L(1)                 NRRC. THIS WORD                     F2B11210
       STO     NRRC                 CONTAINS INITIALLY                  F2B11220
       TZE     ID150                THE NUMBER OF                       F2B11230
       CLA     DOTGZ+1,1            SUBSCRIPTS IN THE                   F2B11240
       TRA     ID070                COMBINATION.                        F2B11250
ID150  CLA     X1                   THIS ROUTINE                        F2B11260
       LDQ     X2                   LOOKS FOR THE                       F2B11270
       TLQ     PT041                OUTERMOST                           F2B11280
       CLA     X2                   DOTAG                               F2B11290
PT041  LDQ     X3                   OF A                                F2B11300
       TLQ     PT042                SUBSCRIPT                           F2B11310
       CLA     X3                   COMBINATION.                        F2B11320
PT042  STO     PT043                                                    F2B11330
       LXD     L(6),4                                                   F2B11340
       LXD     L(3),3                                                   F2B11350
       TRA     ID160                RETURN                              F2B11360
PT043  PZE                                                              F2B11370
ID160  CLA     $S1+3,1              WHICH CAN BE ASSIGNED.              F2B11380
       TZE     ID170                HAVE BEEN ASSIGNED.                 F2B11390
       SUB     $S1+5,2              THIS                                F2B11400
       TNZ     ID170                ROUTINE                             F2B11410
       PXD     0,4                  MAKES UP THE                        F2B11420
       ORS     DUPES                DUPLICATE                           F2B11430
ID170  TIX     ID180,4,1            SUBSCRIPT                           F2B11440
ID180  TIX     ID160,2,2            WORD.                               F2B11450
       TIX     ID190,4,1                                                F2B11460
ID190  TIX     ID160,1,2                                                F2B11470
       LXD     NRRC,2               IF THERE IS MORE                    F2B11480
       TXL     ID300,2,0            THAN ONE RELCON,                    F2B11490
       TXL     ID195,2,1            AND IF THERE ARE                    F2B11500
       CLA     DUPES                DUPLICATES, THEN THE                F2B11510
       STO     RCDUP                RELCONS ARE DUPLICATES.             F2B11520
       CLA     L(0)                 OTHERWISE, THE DOSUBS               F2B11530
       STO     DUPES                ARE DUPLICATES.                     F2B11540
ID195  LXD     L(5),4               IF THERE ARE RELCONS,               F2B11550
ID200  CLA     L1+5,4               THERE ARE NOT MORE                  F2B11560
       TNZ     ID210                THAN TWO.                           F2B11570
       CLA     $S1+5,4              PUT THEIR SYMBOLS                   F2B11580
       TZE     ID210                IN PSYM1 AND RSYM2,                 F2B11590
       PXD     0,4                  AND PUT BITS IN THE                 F2B11600
       TXL     ID205,4,1            PROPER POSITIONS OF                 F2B11610
       SUB     L(1)                 RCSUBS.                             F2B11620
ID205  ORS     RCSUBS                                                   F2B11630
       CLA     $S1+5,4                                                  F2B11640
       TNX     ID220,2,1                                                F2B11650
       STO     $RSYM2                                                   F2B11660
ID210  TIX     ID200,4,2                                                F2B11670
       TRA     ID300                                                    F2B11680
ID220  STO     $RSYM1                                                   F2B11690
ID300  LXD     L(5),4               FOR ALL DO SUBS,                    F2B11700
ID310  CLA     X1+5,4               SELECT THE                          F2B11710
       TZE     ID340                MAXIMUM OF ALL                      F2B11720
       PDX     0,1                  VARAIBLE N LEVEL                    F2B11730
       LXD     L(3),2               OF DEFINITION                       F2B11740
ID320  CLA     DOTGZ+6,1            QUANTITIES.                         F2B11750
       ANA     ADDMSK                                                   F2B11760
       ALS     18                                                       F2B11770
       CAS     IDES                                                     F2B11780
       STO     IDES                                                     F2B11790
       NOP                                                              F2B11800
       TIX     ID330,1,1                                                F2B11810
ID330  TIX     ID320,2,1                                                F2B11820
ID340  TIX     ID310,4,2                                                F2B11830
       LXD     L(5),4               COMPARE THIS MAXIMUM                F2B11840
       LXD     L(0),2                                                   F2B11850
ID350  CLA     L1+5,4               WITH EACH SUBSCRIPT                 F2B11860
       TZE     ID380                LEVEL, THOSE SUBSCRIPT              F2B11870
       CAS     IDES                 LEVELS LESS THAN OR                 F2B11880
       TRA     ID370                EQUAL TO THE MAXIMUM                F2B11890
       NOP                          LEVEL OF DEFINITION                 F2B11900
       PXD     0,4                  QUANTITY WILL BE TREATED            F2B11910
       TXL     ID360,4,1            AS REL. CONS.                       F2B11920
       SUB     L(1)                 INDICATE THIS CONDITION             F2B11930
ID360  ORS     DORC                 IN THE DORC WORD.                   F2B11940
       CLA     X1+5,4                                                   F2B11950
       PDX     0,1                                                      F2B11960
       CLA     BITONE               MAKE INDICATION FOR STORED COUNTER  F2B11970
       ORS     DOTGZ+5,1            FOR THIS DORC.                      F2B11980
       PXD     0,0                  CLEAR X(N) AND L(N)                 F2B11990
       STO     L1+5,4               SINCE THEY ARE NO LONGER DOSUBS.    F2B12000
       STO     X1+5,4                                                   F2B12010
       TRA     ID380                                                    F2B12020
ID370  CAS     LL                   FOR TRUE DO SUBS.                   F2B12030
       TRA     ID372                ESTABLISH LOW LEVEL                 F2B12040
       TRA     ID372                AND LOW INDEX. LOW                  F2B12050
       STO     LL                   LEVEL WORD WAS                      F2B12060
       CLA     X1+5,4               INITIALIZED TO                      F2B12070
       STO     XL                   35ONES.                             F2B12080
       SXD     LOWPOS,4                                                 F2B12090
ID372  PXD     0,4                  PUT BITS IN                         F2B12100
       TXL     ID375,4,1            PROPER POSITIONS                    F2B12110
       SUB     L(1)                 OF DOSUBS                           F2B12120
ID375  ORS     DOSUBS               WORD                                F2B12130
       TXI     ID380,2,1                                                F2B12140
ID380  TIX     ID350,4,2                                                F2B12150
       PXD     0,2                                                      F2B12160
       STO     NRDS                 CHECK TO SEE THAT                   F2B12170
       TNZ     ID385                AT LEAST ONE SUBSCR IS A DOSUB      F2B12180
       TSX     ERRORM,4             AC (ALSO IN NRDS) SHOULD NOT        F2B12190
       REM                          BE ZERO. XR2 PLACED IN AC TO        F2B12200
       REM                          TEST.                               F2B12210
ID385  LXD     NRRC,2               THESE INSTRUCTIONS                  F2B12220
       TXL     ID400,2,0            COMPUTE DELTA.                      F2B12230
       LXD     L(1),4               IF ONE DISTINCT DOSUB,              F2B12240
       CLA     RCDUP                ONE DISTINCT RELCON,                F2B12250
       TNZ     ID395                DELTA IS ONE.                       F2B12260
       CLA     DUPES                IF TWO DISTINCT DOSUBS,             F2B12270
       TNZ     ID395                ONE RELCON, DELTA IS TWO.           F2B12280
       TXL     ID390,2,1            IF ONE DOSUB, TWO                   F2B12290
       TXI     ID395,4,2            DISTINCT RELCONS,                   F2B12300
ID390  LXD     NRDS,2               DELTA IS THREE.                     F2B12310
       TXL     ID395,2,1            FOR ALL OTHER CASES,                F2B12320
       TXI     ID395,4,1            DELTA IS ZERO.                      F2B12330
ID395  PXD     0,4                                                      F2B12340
       STO     DELTA                                                    F2B12350
ID400  LXD     ID075,4              EXIT,                               F2B12360
       TRA     2,4                  SUBCOM USED.                        F2B12370
ID410  LXD     ID075,4              EXIT,                               F2B12380
       TRA     1,4                  SUBCOMB NOT USED.                   F2B12390
IDES   PZE                                                              F2B12400
NAME   SXD     NAM10,4              SAVE LINKAGE                        F2B12410
       CLA     $TAG                 PUT TAU IN TS                       F2B12420
PAT05  STO     TS                   P463        S                       F2B12430
       LXD     PT043,1                                                  F2B12440
RET01  TSX     TINFOR,4             SEARCH RANGE OF XL                  F2B12450
       TRA     NAM20                (FOUND) FOR NEGATICE TAG.           F2B12460
NAM10  TXL     NAM50,,0             NOT FOUND                           F2B12470
NAM20  CLA     NEWTAG               OBTAIN                              F2B12480
       STO     TS                   NEW                                 F2B12490
       ADD     L(1)A                NAME                                F2B12500
       STO     NEWTAG                                                   F2B12510
       LXD     XC,1                 ARRANGE                             F2B12520
       CLA     DOTGZ,1              ENTRY BLOCK                         F2B12530
       STO     $E1                  FOR CHATAG                          F2B12540
       CLA     $TAG                 ENTRY                               F2B12550
       ALS     18                                                       F2B12560
       ADD     TS                                                       F2B12570
       STO     $E2                                                      F2B12580
       CLA     CHATAG                                                   F2B12590
       LXD     NRRC,4               USE LIST OR SPC000,                 F2B12600
       TXH     NAM30,4,0            DEPENDING UPON                      F2B12610
       TSX     $LIST,4              WHETHER OR NOT                      F2B12620
       TRA     NAM40                WORD NRRC IS ZERO. I.E., ARE THERE RF2B12630
NAM30  LXD     L(2),2               NO TINFOR SEARCH REQUIRED.          F2B12640
       TSX     SPC000,4                                                 F2B12650
NAM40  CLA     ALPHA                ENTER ALPHA AND                     F2B12660
       ORA     $TAG                 NAME                                F2B12670
       STO     $E1                  IN                                  F2B12680
       CLA     TS                   NAME                                F2B12690
       STO     $E2                  TABLE.                              F2B12700
       CLA     NAMKEY               ENTER INTO                          F2B12710
       TSX     $LIST,4              NAME (OR NAMEKEY) TABLE.            F2B12720
       CLA     LADDIN+3             UPDATE                              F2B12730
       ARS     18                   NAMXX INDEX REG                     F2B12740
       SUB     $LADDS+3             VALUES.                             F2B12750
       ALS     18                   .                                   F2B12760
       STD     NAMXX                .                                   F2B12770
NAM50  LXD     NAM10,4              EXIT                                F2B12780
       TRA     1,4                                                      F2B12790
       REM 1NS00 PROCESSES SC CONTAINING ONE DISTINCT INDEXED SUBSCRIPT.F2B12800
1NS00  SXD     1NS20,4              SAVE LINKAGE                        F2B12810
       LXD     XC,1                                                     F2B12820
       CLA     BITTWO               IF A COUNTER HAS                    F2B12830
       ANA     DOTGZ+6,1            BEEN FOUND,                         F2B12840
       TNZ     1NS10                GO TO 1NS10                         F2B12850
       LXD     DOSUBS,4             SKIP TO 1NS10                       F2B12860
       TXL     1NS10,4,3            IF NOT FIRST POSITION.              F2B12870
       TXH     1NS10,4,4                                                F2B12880
       CLA     RCSUBS               IF ANY RELCONS,                     F2B12890
       ORA     DORC                 GO TO 1NS10                         F2B12900
       TNZ     1NS10                                                    F2B12910
       LXD     $C1,4                IF C1 IS NOT ONE,                   F2B12920
       TXH     1NS10,4,1            GO TO 1NS10                         F2B12930
       CLA     ADDMSK               THIS SUB. COMB. WILL SERVE          F2B12940
       ANS     DOTGZ+8,1            AS COUNTER AND TEST. ENTER IN       F2B12950
       CLA     TS                   DOTAGZ+8.                           F2B12960
       ALS     18                   INDICATE                            F2B12970
       ORA     L(MZ)                BEST TEST                           F2B12980
       ORS     DOTGZ+8,1            FOUND.                              F2B12990
       CLA     BITTWO               INDICATE COUNTER FOUND.             F2B13000
       ORS     DOTGZ+6,1                                                F2B13010
       CAL     L(MZ)                SET CARWRD NEGATIVE.                F2B13020
       ORS     CARWRD               TEST BITONE OF L WORD.              F2B13030
       CLA     BITONE               IF ONE, SKIP TRASTO                 F2B13040
       ANA     DOTGZ+5,1            TEST.                               F2B13050
       TNZ     1NS10                                                    F2B13060
1NS05  CLA     DOTGZ+5,1            TEST TO SEE IF TRANSFER             F2B13070
       TPL     1NS10                STORE NECESSARY.                    F2B13080
       CLA     DOTGZ,1              MAKE TRASTO ENTRY                   F2B13090
       STO     $E1                  TO STORE COUNTER                    F2B13100
       CLA     DOTGZ+1,1            IN LOCATION OF SYMBOL.              F2B13110
       STO     $E2                                                      F2B13120
       CLA     LC                                                       F2B13130
       ORA     TS                                                       F2B13140
       STO     $E3                                                      F2B13150
       CLA     TRASTO                                                   F2B13160
       TSX     $LIST,4                                                  F2B13170
1NS10  CLA     L(6)                 ENTER                               F2B13180
       STO     GROUP                GROUP NR.                           F2B13190
       LXD     1NS20,4              AND EXIT.                           F2B13200
       TRA     1,4                                                      F2B13210
1NS20  PZE                                                              F2B13220
       REM 2NS00 ROUTINE PROCESSES SC WITH TWO DISTINCT INDEXED         F2B13230
       REM SUBSCRIPTS.                                                  F2B13240
2NS00  SXD     2NS25,4              SAVE LINKAAGE                       F2B13250
2NS10  LXD     DOSUBS,1             2NS10 TO 2NS80 DETERMINE THE        F2B13260
       LXD     L(2),2               GROUP NR AND CARRY BITS             F2B13270
       CLA     L1                   FOR THE SL.                         F2B13280
       TXH     2NS20,1,3                                                F2B13290
       CLA     L2                                                       F2B13300
2NS20  TXL     2NS30,1,5                                                F2B13310
       SUB     L2                                                       F2B13320
2NS25  TXL     2NS40,,0                                                 F2B13330
2NS30  SUB     L3                                                       F2B13340
2NS40  TMI     2NS70                                                    F2B13350
       SUB     L(1)                                                     F2B13360
       TNZ     2NS60                                                    F2B13370
       TXL     2NS50,1,3                                                F2B13380
       TXL     2NS60,1,5                                                F2B13390
       TXI     2NS50,2,2                                                F2B13400
2NS50  LXD     DUPES,4              THIS DUPE TEST IS AN ADJUSTMENT     F2B13410
       TXH     2NS60,4,0            FOR DUPLICATES IN A REDUCED         F2B13420
       TSX     CARRY,4              3NS CASE.                           F2B13430
2NS60  CLA     L(1)                                                     F2B13440
2NS65  TXL     2NS80,,0                                                 F2B13450
2NS70  CLA     L(6)                                                     F2B13460
2NS80  STO     GROUP                                                    F2B13470
       PDX     0,4                                                      F2B13480
       LXD     DOSUBS,2             THIS ROUTINE,TO 2NS90,              F2B13490
       CLA     L1                   PREPARES A TRAWRD CALLING           F2B13500
       TXH     2NS82,2,3            SEQUENCE TO DETERMINE               F2B13510
       CLA     L2                   WHETHER OR NOT RESETTING            F2B13520
2NS82  TXL     2NS84,2,5            IS NECESSARY                        F2B13530
       LDQ     L2                                                       F2B13540
       TRA     2NS86                                                    F2B13550
2NS84  LDQ     L3                                                       F2B13560
2NS86  TXL     2NS88,4,1            TEST GROUP                          F2B13570
       STO     TL1                                                      F2B13580
       STQ     TL2                                                      F2B13590
       LXD     X3,1                                                     F2B13600
       CLA     L(1)                                                     F2B13610
       TXL     2NS90,2,5                                                F2B13620
       LXD     X2,1                                                     F2B13630
       CLA     L(2)                                                     F2B13640
       TRA     2NS90                                                    F2B13650
2NS88  STO     TL2                                                      F2B13660
       STQ     TL1                                                      F2B13670
       LXD     X1,1                                                     F2B13680
       CLA     L(4)                                                     F2B13690
       TXH     2NS90,2,3                                                F2B13700
       LXD     X2,1                                                     F2B13710
       CLA     L(2)                                                     F2B13720
2NS90  STO     REBITS               2NS90 SEQ. SINGLE REBITS            F2B13730
       ANA     DUPES                ARE PART OF THE TAG OF THE          F2B13740
       TZE     2NS91                RESETTING SC,IT MUST BE             F2B13750
       CLA     REBITS               ADJUSTED FOR DUPE RESETS.           F2B13760
       ORA     DUPES                                                    F2B13770
       STO     REBITS                                                   F2B13780
2NS91  SXD     2NS65,1                                                  F2B13790
       LXD     L(1),2                                                   F2B13800
       TSX     TRWRD,4              TEST FOR TRANSFER BITS.             F2B13810
       TZE     2NSEND               RESETTING NOT NECESSARY IF          F2B13820
       LXD     REBITS,2             TRAWRD RESULT ZERO.  IF             F2B13830
       LXD     2NS65,1              RESETTING NECESSARY, EXECUTE        F2B13840
       TSX     RESET,4              RESET ROUTINE AND                   F2B13850
2NSEND LXD     2NS25,4              EXIT                                F2B13860
       TRA     1,4                                                      F2B13870
       REM 3NS00 ROUTINE PROCESSES SC WITH THREE DISTINCT INDEXED       F2B13880
       REM SUBSCRIPTS.                                                  F2B13890
3NS00  SXD     3GRP15,4             SAVE LINKAGE                        F2B13900
       REM THIS ROUTINE DETERMINES GROUP NUMBER FOR 3NS NO DUPE SC      F2B13910
       LXD     L(0),2               PUT ZERO IN XRB                     F2B13920
       CLA     L3                   OBTAIN L3                           F2B13930
       CAS     L2                   COMPARE WITH L2                     F2B13940
       TXI     3GRP10,2,4           L3 GREATER THAN L2                  F2B13950
       TSX     ERRORM,4             LEVEL NOS.(L2,L3) SHOULD NOT        F2B13960
       REM                          BE EQUAL. LEVEL TAKEN FROM THE      F2B13970
       REM                          SECOND WD OF DOTAG ENTRY.           F2B13980
3GRP10 CAS     L1                   L3 LESS THAN L2,COMPARE L3,L1       F2B13990
3GRP15 TXL     3GRP20,,0            L3 GREATER THAN L1.                 F2B14000
       TSX     ERRORM,4             LEVEL NO. OF INNER NEST (L3)        F2B14010
       REM                          SHOULD BE GREATER THAN THAT OF      F2B14020
       REM                          OUTER NEST (L1).                    F2B14030
       TXI     3GRP20,2,1           L3 LESS THAN L1                     F2B14040
3GRP20 CLA     L2                   OBTAIN L2                           F2B14050
       SUB     L1                   SUBTRACT L1                         F2B14060
       TMI     3GRP30               TRA IF L2 LESS THAN L1              F2B14070
       TXI     3GRP30,2,2           L2 GREATER THAN L1                  F2B14080
3GRP30 PXD     0,2                  PUT GROUP NUMBER IN ACC DEC.        F2B14090
       STO     GROUP                OR INTO TAG 1                       F2B14100
       CLA     L1                   OBTAIN L1                           F2B14110
       SUB     L(1)                 L1 LESS 1                           F2B14120
       SUB     L2                   L1 LESS 1 LESS L2                   F2B14130
       TNZ     3GRP40               NOT ZERO,NO CARRY,TRA               F2B14140
       LXD     L(4),2               SET XRB                             F2B14150
       TSX     CARRY,4              AND TSX TO CARRY                    F2B14160
3GRP40 CLA     L2                   RE-ENTRY,OBTAIN L2                  F2B14170
       SUB     L(1)                 L2 LESS 1                           F2B14180
       SUB     L3                   L2 LESS 1 LESS L3                   F2B14190
       TNZ     3GRP50               NOT ZERO,NO CARRY,TRA               F2B14200
       LXD     L(2),2               SET XRB                             F2B14210
       TSX     CARRY,4              AND TSX TO CARRY                    F2B14220
3GRP50 LXD     L(0),6               THE FOLLOWING ROUTINE,              F2B14230
       LXD     GROUP,1              THROUGH 3GRP72, COMPUTES            F2B14240
3GRP55 TRA     3GRP55+7,1           QUANTITIES FOR XRB, XRC.            F2B14250
       TXI     3GRP65,2,2           GROUP IS SIX                        F2B14260
       TXI     3GRP65,4,4           FIVE                                F2B14270
       TXI     3GRP65,2,4           FOUR                                F2B14280
       TXI     3GRP60,6,2           THREE                               F2B14290
       TXI     3GRP65,4,2           TWO                                 F2B14300
       TXI     3GRP60,4,4           ONE                                 F2B14310
3GRP60 TXI     3GRP65,2,2                                               F2B14320
3GRP65 CLA     X1+4,4                                                   F2B14330
       STO     INX                                                      F2B14340
       CLA     X1+5,4                                                   F2B14350
       STO     INL                                                      F2B14360
       CLA     X1+4,2                                                   F2B14370
       STO     MIDX                                                     F2B14380
       CLA     X1+5,2                                                   F2B14390
       STO     MIDL                                                     F2B14400
       TXH     3GRP70,4,0           THE QUANTITIES IN XRB.              F2B14410
       TXI     3GRP70,4,1           XRC, ARE ZERO, TWO, OR              F2B14420
3GRP70 SXD     INP,4                FOUR, ADJUSTED TO ONE,              F2B14430
       TXH     3GRP72,2,0           TWO, FOUR, TO INDICATE THE          F2B14440
       TXI     3GRP72,2,1           POSITION OF THE SUBCCRIPT           F2B14450
3GRP72 SXD     MIDP,2               BEING RESET, STORE IN INP, MIDP.    F2B14460
       LXD     L(4),4               THIS LOOP IS EXECUTED TWICE.        F2B14470
3GRP75 CLA     INX+4,4              OBTAIN INNER INDEX OF PAIR          F2B14480
       PDX     0,1                  IN XRA                              F2B14490
       CLA     INL+4,4              OBTAIN INNER LEVEL OF PAIR          F2B14500
       STO     TL2                  TL2                                 F2B14510
       CLA     LL                   OBTAIN LOWER LEVEL IN               F2B14520
       STO     TL1                  TL1                                 F2B14530
       LXD     L(1),2               PUT ONE IN XRB,                     F2B14540
       SXD     3GRP80,4             SAVE XRC,                           F2B14550
       TSX     TRWRD,4              AND USE TRWRD.                      F2B14560
       LXD     3GRP80,4             RESTORE XRC,                        F2B14570
       TZE     3GRP77               GO TO INDEXING IF ZERO.             F2B14580
       CLA     INP+4,4              TRAWRD RESULT NOT ZERO.             F2B14590
       PDX     0,2                  PREPARE TO                          F2B14600
       CLA     INX+4,4              USE RESET                           F2B14610
       PDX     0,1                                                      F2B14620
       SXD     3GRP80,4             SAVE XRC,                           F2B14630
       TSX     RESET,4              GO TO RESET,                        F2B14640
       LXD     3GRP80,4             RESTROE XRC,                        F2B14650
3GRP77 TIX     3GRP75,4,2           INDEX AND GO BACK,                  F2B14660
       TRA     3NSEND               OR EXIT                             F2B14670
INP    PZE                          POSITION OF INNER SUB.              F2B14680
3GRP80 PZE                                                              F2B14690
MIDP   PZE                          POSITION OF MIDDLE SUB.             F2B14700
INX    PZE                          INDEX INNER LEVEL SUB.              F2B14710
INL    PZE                          LEVEL INNER LEVEL SUB.              F2B14720
MIDX   PZE                          INDEX MIDDLE LEVEL SUB.             F2B14730
MIDL   PZE                          LEVEL INNER LEVEL SUB.              F2B14740
3NSEND LXD     3GRP15,4                                                 F2B14750
       TRA     1,4                                                      F2B14760
RESET  SXD     RES45,4              SAVE LINKAGE                        F2B14770
       PXD     0,2                  SAVE                                F2B14780
       STO     RES300               PREFIX (REBITS)                     F2B14790
       PXD     0,1                  SAVE INDEX                          F2B14800
       STO     RES310               OF RESET                            F2B14810
       CLA     $C3                  OBTAIN C3 IN                        F2B14820
       ARS     18                   ADDRESS PART.                       F2B14830
RES05  TRA     RES05+7,2            INDEXED T RANSFER, C(XRB)=C(REBITS) F2B14840
       TRA     RES50                C(XRB)=110                          F2B14850
       TRA     RES30                C(XRB)=101                          F2B14860
       TRA     RES40                C(XRB)=100                          F2B14870
       TRA     RES20                C(XRB)=011                          F2B14880
       TRA     RES50                C(XRB)= 010                         F2B14890
RES10  STO     $E2                  C(XRB)=001                          F2B14900
       CLA     $D2                  THESE INSTRUCTIONS, THRU            F2B14910
       ARS     18                   RES60, COMPUTE THE                  F2B14920
       ADD     $D1                  CHARACTERISTIC WORDS OF THE         F2B14930
       TRA     RES60                SUBSCRIPT COMBINATION.              F2B14940
RES20  ADD     $C2                                                      F2B14950
       TRA     RES10                                                    F2B14960
RES30  ADD     $C1                                                      F2B14970
       TRA     RES10                                                    F2B14980
RES40  CLA     $C1                                                      F2B14990
       STO     $E2                                                      F2B15000
       CLA     L(0)                                                     F2B15010
RES45  TXL     RES60,,0                                                 F2B15020
RES50  CLA     $C2                                                      F2B15030
       ARS     18                                                       F2B15040
       TXL     RES55,2,2                                                F2B15050
       ADD     $C1                                                      F2B15060
RES55  STO     $E2                                                      F2B15070
       CLA     $D1                                                      F2B15080
RES60  STO     $E3                                                      F2B15090
       TXH     RES65,2,4            IF PREFIX IS 1,0,0,                 F2B15100
       TXH     RES400,2,3           T RA TO RES400                      F2B15110
RES65  LXD     RESXX,1              SEARCH                              F2B15120
       SXD     RES75,1              RETAB                               F2B15130
       LXA     RESXX,1              FOR                                 F2B15140
       TRA     RES75                SAME                                F2B15150
RES70  CLA     RETABZ,1             INDEX.                              F2B15160
       ANA     DECMSK                                                   F2B15170
       CAS     RES310                                                   F2B15180
       TXI     RES75,1,-3                                               F2B15190
       TRA     RES80                INDEX FOUND, GO TO RES80            F2B15200
RES73  TXI     RES75,1,-3                                               F2B15210
RES75  TXH     RES70,1,0                                                F2B15220
       TRA     RES85                NOT FOUND, GO TO RES85              F2B15230
RES80  CLA     RETABZ,1             COMPARE PREFIX OF                   F2B15240
       ANA     RES320               RETAB ENTRY                         F2B15250
       ALS     6                    WITH CURRENT                        F2B15260
       SUB     RES300               PREFIX. IF NOT EQUAL,               F2B15270
       TNZ     RES73                CONTINUE RETAB SEARCH.              F2B15280
       CLA     RETABZ+1,1           IF EQUAL, COMPARE                   F2B15290
       SUB     $E2                  CHARACTERISTIC WORDS.               F2B15300
       TNZ     RES73                IF                                  F2B15310
       CLA     RETABZ+2,1           NOT                                 F2B15320
       SUB     $E3                                                      F2B15330
       TNZ     RES73                EQUAL, CONTINUE SEARCH.             F2B15340
       CLA     RETABZ,1             IF EQUAL,                           F2B15350
       ANA     ADDMSK               USE RESET TAG ALREADY               F2B15360
       STO     RES330               ENTERED. SAVE NAME.                 F2B15370
       TRA     RES200               TRA TO RES200                       F2B15380
RES85  CLA     RES300               NO USABLE ENTRY FOUND.              F2B15390
       ARS     6                    MAKE                                F2B15400
       ORA     $TAG                 NEW                                 F2B15410
       STO     RES330                                                   F2B15420
       ORA     RES310               ENTRY                               F2B15430
       LXD     RESXX,1              IN                                  F2B15440
       TXH     RES87,1,0            RETAB.                              F2B15450
       TSX     ERROR8,4             RETAB TABLE IS FULL.                F2B15460
RES87  STO     RETABZ,1                                                 F2B15470
       CLA     $E2                                                      F2B15480
       STO     RETABZ+1,1                                               F2B15490
       CLA     $E3                                                      F2B15500
       STO     RETABZ+2,1                                               F2B15510
       TXI     RES88,1,-3           ADJUST IN DEX.                      F2B15520
RES88  SXD     RESXX,1                                                  F2B15530
       CLA     RES310               MAKE E2 WORD                        F2B15540
       TXH     RES96,2,5            FOR DRUMTAG OR                      F2B15550
       TXH     RES94,2,4            TAGTAG ENTRY                        F2B15560
       TXH     RES92,2,3                                                F2B15570
       TXH     RES90,2,2                                                F2B15580
       TXH     RES96,2,1                                                F2B15590
       ARS     18                                                       F2B15600
       TRA     RES96                                                    F2B15610
RES90  ARS     18                                                       F2B15620
       ADD     RES310                                                   F2B15630
       TRA     RES96                                                    F2B15640
RES92  CLA     L(0)                                                     F2B15650
RES94  ARS     18                                                       F2B15660
RES96  STO     $E2                                                      F2B15670
       CLA     RES310               MAKE                                F2B15680
       ARS     18                   E1 WORD                             F2B15690
       TXH     RES98,2,3                                                F2B15700
       CLA     L(0)                                                     F2B15710
RES98  STO     $E1                                                      F2B15720
       LXD     RES310,1                                                 F2B15730
       CLA     DOTGZ,1                                                  F2B15740
       ANA     DECMSK                                                   F2B15750
       ORS     $E1                                                      F2B15760
       CLA     RES330               MAKE                                F2B15770
       STO     $E3                  E3 WORD                             F2B15780
       CLA     L(6)                 MAKE                                F2B15790
       STO     $E4                  E4                                  F2B15800
       CLA     RES300               WORD                                F2B15810
       ARS     18                                                       F2B15820
       ORS     $E4                                                      F2B15830
       TXL     RES110,2,2                                               F2B15840
       TXL     RES100,2,3                                               F2B15850
       TXL     RES110,2,4                                               F2B15860
RES100 ALS     9                                                        F2B15870
       ORS     $E4                                                      F2B15880
RES110 CLA     L(0)                 THESE INSTRUCTIONS,                 F2B15890
       STO     RES340               TO RES170, DETERMINE                F2B15900
       LXD     L(5),4               WHICH COEFFICIENTS                  F2B15910
RES120 CLA     $C1+5,4              ARE GREATER THAN                    F2B15920
       SUB     L(1)                 ONE AND PLACE                       F2B15930
       TZE     RES140               THIS INFO IN                        F2B15940
       TIX     RES130,4,1           E4(TAG1).                           F2B15950
RES130 PXD     0,4                                                      F2B15960
       ORS     RES340                                                   F2B15970
       TXI     RES140,4,1                                               F2B15980
RES140 TIX     RES120,4,2                                               F2B15990
       CLA     RES340                                                   F2B16000
       ANA     RES300                                                   F2B16010
       ARS     6                                                        F2B16020
       ORS     $E4                                                      F2B16030
       CLA     DRMTAG               DRUM TAG ENTRY                      F2B16040
       TSX     $LIST,4              OR                                  F2B16050
       TRA     RES200               TAGTAG                              F2B16060
RES180 TSX     TAGENT,4             ENTRY.                              F2B16070
RES200 LXD     RES310,1             MAKE                                F2B16080
       CLA     DOTGZ,1              PROPER                              F2B16090
       STO     $E1                  TRASTO                              F2B16100
       CLA     TL2                  ENTRY                               F2B16110
       ARS     18                                                       F2B16120
       ADD     TL1                                                      F2B16130
       STO     $E2                                                      F2B16140
       CLA     RES330                                                   F2B16150
       ALS     18                                                       F2B16160
       ADD     TS                                                       F2B16170
       SSM                                                              F2B16180
       STO     $E3                                                      F2B16190
       CLA     TRASTO                                                   F2B16200
       TSX     $LIST,4                                                  F2B16210
RES210 LXD     RES45,4              EXIT.                               F2B16220
       TRA     1,4                                                      F2B16230
RES300 PZE                          PREFIX STORAGE                      F2B16240
RES310 PZE                          INDEX STORAGE                       F2B16250
RES320 OCT     70000                PREFIX MASK                         F2B16260
RES330 PZE                          RESET NAME STORAGE.                 F2B16270
RES340 PZE                          E.S.                                F2B16280
RES400 CLA     $E2                  TEST FOR COEFFICIENT                F2B16290
       SUB     L(1)                 EQUAL TO ONE.                       F2B16300
       TNZ     RES65                IF NOT, PROCESS NORMALLY            F2B16310
       CLA     DOTGZ,1              THROUGH RESET.                      F2B16320
       ARS     17                   TEST FOR CONSTANT N1.               F2B16330
       LBT                          IF VARIABLE, NORMAL PROCESSING.     F2B16340
       TRA     RES410               0                                   F2B16350
       TRA     RES65                1                                   F2B16360
RES410 CLA     DOTGZ+6,1            HAS COUNTER BEEN FOUND.             F2B16370
       ANA     BITTWO                                                   F2B16380
       TNZ     RES420               IF SO, GO TO RES420                 F2B16390
       CLA     TL2                  IF NOT, MAKE ENTRY                  F2B16400
       ARS     18                   IN ADDED TAG TABLE                  F2B16410
       ORA     TL1                  FOR PROCESSING INTO                 F2B16420
       SSM                          DRUM TAG AFTER NEST                 F2B16430
       LRS     35                   ANALYSIS.                           F2B16440
       PXD     0,1                                                      F2B16450
       ORA     TS                                                       F2B16460
       LXD     L(1),2                                                   F2B16470
       TSX     TAGADD,4                                                 F2B16480
       TRA     RES210               TRA TO EXIT                         F2B16490
RES420 TSX     RSR,4                COUNTER FOUND, USE RSR.             F2B16500
       TRA     RES210               TRA TO EXIT                         F2B16510
*      ***                                                              F2B16520
NRMRT  TSX     (LOAD),4             GO TO BLOCK 3.                      F2B16530
       PZE                                                              F2B16540
       REM THIS ROUTINE PROCESSES SINGLE RELATIVE CONSTANTS             F2B16550
       REM AND, FOR SC WITH TWO RC SUBS, DOES ALL PROCESSING            F2B16560
       REM EXCEPT WHERE THERE IS A POSSIBLE MULTIPLE DEFINITION,        F2B16570
       REM AT WHICH POINT IT CALLS ON 2R0000.                           F2B16580
CORES  LXD     DOTAG-1,1            RELCON CODING BLOCK. (STATE B)      F2B16590
       SXD     DSDR20,1                                                 F2B16600
       SXD     DSD118,1                                                 F2B16610
       SXD     DSD145,1                                                 F2B16620
       SXD     2R0020,1                                                 F2B16630
DSDR00 MSE     100                                                      F2B16640
       NOP                                                              F2B16650
       LXD     XC,1                 PUT INDEX OF DC IN XRA              F2B16660
       LXD     DELTA,4              PUT DELTA IN XRC                    F2B16670
       CLA     LC                   INITIALIZE END OF                   F2B16680
       STD     DSDR30               DC TEST INSTR                       F2B16690
DSDR10 TXI     DSDR20,1,-9          TAKE NEXT DOWN DO,IF POSSIBLE       F2B16700
DSDR20 TXL     DSD100,1,0           EXIT IF DOTAG EXHAUSTED.            F2B16710
       CLA     DOTGZ+5,1            GET LEVEL OF THIS DO IN             F2B16720
       PDX     0,2                  XRB,COMPARE WITH LEVEL OF           F2B16730
DSDR30 TXL     DSD100,2,0           D6 AND EXIT IF NOT IN DC.           F2B16740
       CLA     DOTGZ+1,1            GET SYMBOL OF THIS DO               F2B16750
       SUB     $RSYM1               COMPARE WITH FIRST R SYM.           F2B16760
       TZE     DSDR50               IF THIS DO IS DR1,TRA.              F2B16770
       TXL     DSDR10,4,2           IF NOT DR1,GO BACK,UNLESS DELTA3    F2B16780
       CLA     DOTGZ+1,1            GET SYMBOL AGAIN                    F2B16790
       SUB     $RSYM2               AND COMPARE WITH RSYM2.             F2B16800
       TNZ     DSDR10               IF NOT RSYM1 OR RSYM2,GO BACK       F2B16810
       CLA     $RSYM2               IF DO SYM IS RSYM2,                 F2B16820
       LDQ     $RSYM1               SWITCH RSYM1 AND RSYM2              F2B16830
       STO     $RSYM1               TO MAKE BUCKET LABLES               F2B16840
       STQ     $RSYM2               AGREE WITH ORDER OF DO FORMULAS.    F2B16850
DSDR50 SXD     XR1,1                SAVE                                F2B16860
       PXD     0,2                  INDEX OF R1                         F2B16870
       STO     LR1                  AND LEVEL OF R1                     F2B16880
       STO     TL2                  INITIALIZE TRAWRD TL2               F2B16890
       CLA     LL                   INITIALIZE TRAWRD TL1               F2B16900
       STO     TL1                  PREPARE                             F2B16910
       LXD     L(1),2               TRAWRD C(XRB)                       F2B16920
       TXL     DSDR55,4,2                                               F2B16930
       LXD     L(2),2                                                   F2B16940
DSDR55 TSX     TRWRD,4              GO TO TRWRD AND                     F2B16950
       STO     D2D1                 SAVE IF NOT ZERO                    F2B16960
       LXD     DELTA,4              RETURN HERE                         F2B16970
       TXH     DSDR85,4,2           TRANSFER IF DELTA IS THREE          F2B16980
       TZE     DSDR20               RETURN IF RESULT ZERO               F2B16990
       SXD     DSDR95,1                                                 F2B17000
       TXL     DSDR65,4,1           TR IF DELTA=1                       F2B17010
       CLA     L(36)                FOR DELTA=2,SEPARATE                F2B17020
       SUB     LC                   TRAWRD RESULTS.                     F2B17030
       ARS     18                                                       F2B17040
       STA     DSDR60                                                   F2B17050
       LDQ     L(0)                                                     F2B17060
       CLA     D2D1                                                     F2B17070
DSDR60 LRS     **                                                       F2B17080
       TZE     DSDR62               IF TRANSFERS EXIST DC TO DL,        F2B17090
       PSE     100                  SET SENSE SWITCH                    F2B17100
DSDR62 STQ     D2D1                                                     F2B17110
       CLA     D2D1                                                     F2B17120
       TZE     DSDR80               IF NO TRANSFERS DR TO DC,EXIT       F2B17130
DSDR65 CLA     ATSW                 TEST ADDED TAG SWITCH               F2B17140
       TNZ     DSDR80               IF ADDED DELTA TWO, SKIP INSERT     F2B17150
       LXD     XR1,1                IS TAG IN DR1                       F2B17160
       TSX     TINFOR,4             GO TO TINFOR AND RETURN             F2B17170
       TRA     DSDR70               FOUND                               F2B17180
       LXD     L(0),2               NOT FOUND                           F2B17190
       LXD     XR1,1                                                    F2B17200
       TSX     TAGADD,4             INSERT TAG IN R1,RETURN             F2B17210
       STQ     TR1                  HERE AND STORE NAME IN TR1          F2B17220
       TRA     DSDR75                                                   F2B17230
DSDR70 LXD     XR1,1                FIND NAME OF TAG IN R1              F2B17240
       CLA     DOTGZ,1                                                  F2B17250
       ANA     DECMSK                                                   F2B17260
       ADD     $TAG                                                     F2B17270
       TSX     GETNAM,4                                                 F2B17280
       STO     TR1                                                      F2B17290
DSDR75 LXD     XR1,1                LIST STORES                         F2B17300
       LXD     L(0),2                                                   F2B17310
       TSX     STORES,4                                                 F2B17320
DSDR80 LXD     DSDR95,1                                                 F2B17330
       LXD     DELTA,4                                                  F2B17340
       TRA     DSDR20                                                   F2B17350
DSDR85 TZE     2R0000               GO TO R2 SEARCH IF NO TRA R1 TO D6  F2B17360
       LXD     XR1,1                IF TRA R1 TO DC,                    F2B17370
       LXD     L(1),2               USE SPC000 TO LOOK FOR              F2B17380
       TSX     SPC000,4             TAG IN R1                           F2B17390
       TRA     DSDR87               NOT FOUND,GO TO DSDR87              F2B17400
       LXD     XR1,1                FOUND,USE SUBROUTINE                F2B17410
       CLA     DOTGZ,1              GETNAM TO DETERMINE LABEL           F2B17420
       ANA     DECMSK               OF TAG IN R1                        F2B17430
       ADD     $TAG                                                     F2B17440
       TSX     GETNAM,4                                                 F2B17450
       STO     TR1                  PUT NAME IN TR1                     F2B17460
       TRA     DSDR89                                                   F2B17470
DSDR87 LXD     XR1,1                USE TAGADD TO INSERT                F2B17480
       LXD     L(0),2               TAG IN R1                           F2B17490
       TSX     TAGADD,4                                                 F2B17500
       STQ     TR1                  PUT NAME IN TR1                     F2B17510
       LXD     XL,1                                                     F2B17520
       CLA     BIT20                                                    F2B17530
       ORS     DOTGZ+6,1                                                F2B17540
DSDR89 LXD     XR1,1                LIST STORES                         F2B17550
       LXD     L(1),2                                                   F2B17560
       TSX     STORES,4                                                 F2B17570
DSDR90 TRA     2R0000               GO TO R2 ROUTINE AND                F2B17580
DSDR92 LXD     DELTA,4              RETURN HERE                         F2B17590
DSDR95 TXL     DSDR20,,0            NEXT R1. DEC IS XNEXTR1.            F2B17600
DSD100 TXL     DSD200,4,1           TRA IF DELTA IS 1                   F2B17610
       TXH     DSD200,4,2           TRA IF DELTA IS 3                   F2B17620
       MSE     100                  DELTA IS 2,TEST D3D1 SWITCH         F2B17630
       TRA     DSD110               LIGHT OFF                           F2B17640
       TRA     DSD170               LIGHT ON                            F2B17650
DSD110 LXD     XL,1                 OBTAIN INDEX OF DL IN XRA           F2B17660
       CLA     DOTGZ+5,1            GET LEVEL OF DL                     F2B17670
       STD     DSD120               AND STORE IN TEST INSTR.            F2B17680
DSD115 TXI     DSD118,1,-9          TAKE NEXT DOWN DO IF POSSIBLE       F2B17690
DSD118 TXL     DSD200,1,0           OTHERWISE, EXIT.                    F2B17700
       CLA     DOTGZ+5,1            GET LEVEL OF THIS DO                F2B17710
       PDX     0,2                  AND TEST WHETHER THIS DO IS         F2B17720
DSD120 TXL     DSD200,2,0           IN DL. IF NOT, EXIT.                F2B17730
       PXD     0,1                  IF IN DL,                           F2B17740
       SUB     XC                   IF THIS DO D6.                      F2B17750
       TZE     DSD130               IF SO,TRA.                          F2B17760
       CLA     DOTGZ+1,1            IF NOT, IS THIS DO A DR.            F2B17770
       SUB     $RSYM1                                                   F2B17780
       TZE     DSD160               IF SO,TRA,                          F2B17790
       TRA     DSD115               IF NOT,GO BACK TO GET NEXT DO       F2B17800
DSD130 SXD     DSD150,2             IF DO IS DC,                        F2B17810
DSD140 TXI     DSD145,1,-9                                              F2B17820
DSD145 TXL     DSD200,1,0                                               F2B17830
       CLA     DOTGZ+5,1            IS NEW IN DL.                       F2B17840
       PDX     0,2                  IF SO,GO BACK TO STEP DOWN          F2B17850
DSD150 TXL     DSD120,2,0           AGAIN IN DC. IF NOT IN              F2B17860
       TRA     DSD140               DC, GO TO TEST IF IN DL             F2B17870
DSD160 PXD     0,2                  INITIALIZE                          F2B17880
       STO     TL2                  TL2 TO LEVEL OF DR                  F2B17890
       CLA     LL                   PUT LEVEL OF DL                     F2B17900
       STO     TL1                  IN TL1                              F2B17910
       LXD     L(1),2               PUT 1 IN XRB                        F2B17920
       TSX     TRWRD,4              AND GO TO TRWRD.                    F2B17930
       TZE     DSD118               IF RESUTL ZERO,GO BACK              F2B17940
DSD170 LXD     XL,2                                                     F2B17950
       CLA     BITONE                                                   F2B17960
       ORS     DOTGZ+5,2                                                F2B17970
       LXD     LOWPOS,2                                                 F2B17980
       CLA     L(0)                                                     F2B17990
       STO     X1+5,2                                                   F2B18000
       STO     X1+6,2                                                   F2B18010
       TIX     DSD175,2,1                                               F2B18020
DSD175 PXD     0,2                                                      F2B18030
       ORS     DORC                                                     F2B18040
       COM                                                              F2B18050
       ANS     DOSUBS                                                   F2B18060
       CLA     XC                                                       F2B18070
       STO     XL                                                       F2B18080
       CLA     LC                                                       F2B18090
       STO     LL                                                       F2B18100
       CLA     L(1)                                                     F2B18110
       STO     NRDS                                                     F2B18120
       STO     DELTA                                                    F2B18130
DSD200 TRA     DS4VAL                                                   F2B18140
       REM RELCON DELTA THREE SECOND LEVEL DEFINITION.                  F2B18150
2R0000 LXD     XR1,1                PUT INDEX OF R1 IN XRA              F2B18160
       CLA     LR1                  OBTAIN LEVEL OF R1                  F2B18170
       STD     2R0030               INITIALIZE TEST INSTR.              F2B18180
2R0010 TXI     2R0020,1,-9          TAKE NEXT DOWN DO IF POSSIBLE       F2B18190
2R0020 TXL     DSDR92,1,0           EXIT IF DOTAG EXHAUSTED.            F2B18200
       CLA     DOTGZ+5,1            GET LEVEL OF DO                     F2B18210
       PDX     0,2                  PUT IN XRB AND COMPARE WITH         F2B18220
2R0030 TXL     DSDR92,2,0           LR1,EXIT IF NEW DO NOT IN XR1.      F2B18230
       CLA     DOTGZ+1,1            GET SYMBOL OF NEW DO,               F2B18240
       SUB     $RSYM2               COMPARE WITH RSYM2                  F2B18250
       TNZ     2R0010               IF NOT RSYM2,GO BACK.               F2B18260
       SXD     XR2,1                SAVE INDEX                          F2B18270
       PXD     0,2                  AND LEVEL                           F2B18280
       STO     LR2                  OF R2.                              F2B18290
       STO     TL2                  PREPARE FOR TSX TO TRAWRD.          F2B18300
       CLA     LC                   TO TEST FOR TRANSFERS               F2B18310
       STO     TL1                  FROM R2 TO DS.                      F2B18320
       LXD     L(1),2                                                   F2B18330
       TSX     TRWRD,4              IF NO TRANSFERS, GO BACK            F2B18340
       TZE     2R0020               FOR NEXT DO.                        F2B18350
       SXD     2R0065,1                                                 F2B18360
       STO     D3D2                 TEMPORARY STORAGE                   F2B18370
       CLA     L(36)                PUT 36 IN ACC                       F2B18380
       SUB     LR1                  SUB LEVEL OF R1,                    F2B18390
       ARS     18                   SHIFT RESULT AND                    F2B18400
       STA     2R0050                                                   F2B18410
       LDQ     L(0)                 PUT ZERO IN MQ,                     F2B18420
       CLA     D3D2                 OBTAIN TRAWRD RESULT,               F2B18430
2R0050 LRS     **                   PERFORM SEPARATION                  F2B18440
       STO     D3D1                 AND SAVE                            F2B18450
       STQ     D3D2                 RESULTS.                            F2B18460
       CLA     D3D1                 IF D3D1 IS ZERO,THEN D3D2           F2B18470
       TNZ     2R0060               IS NOT ZERO                         F2B18480
       CLA     D2D1                 IF D2D1 IS ZERO,                    F2B18490
       TZE     2R0200               TR TO GET NEX DO                    F2B18500
2R0060 LXD     XR2,1                SEARCH FOR TAG                      F2B18510
       TSX     TINFOR,4             IN R2                               F2B18520
       TRA     2R0080               FOUND,TR TO OBTAIN NAME             F2B18530
       LXD     XR2,1                NOT FOUND, LOOK FOR DELTA TWO       F2B18540
       TSX     ADDSER,4             INSERT IN ADDED TAG TABLE.          F2B18550
2R0065 TXL     2R0090,,0            FOUND, NAME IN AC.                  F2B18560
       LXD     XR2,1                NOT FOUND                           F2B18570
       LXD     L(0),2               ADD TAG                             F2B18580
       TSX     TAGADD,4             IN TABLE OF ADDED TAGS              F2B18590
       STQ     TR2                  PUT NAME IN TR2                     F2B18600
       TRA     2R0100                                                   F2B18610
2R0080 LXD     XR2,1                SEARCH                              F2B18620
       CLA     DOTGZ,1              FOR                                 F2B18630
       ANA     DECMSK               NAME                                F2B18640
       ADD     $TAG                                                     F2B18650
       TSX     GETNAM,4                                                 F2B18660
2R0090 STO     TR2                  PUT NAME IN TR2                     F2B18670
2R0100 CLA     D3D1                 LIST STORES,IF ANY TR,              F2B18680
       TZE     2R0150               FOR TRANSFERS                       F2B18690
       LXD     XR2,1                D3D1                                F2B18700
       LXD     L(2),2                                                   F2B18710
       TSX     STORES,4                                                 F2B18720
2R0150 CLA     D3D2                 TEST TR                             F2B18730
       TZE     2R0200               D3D2                                F2B18740
       CLA     D2D1                 TEST TR                             F2B18750
       TZE     2R0200               D2D1                                F2B18760
       LXD     XR2,1                LIST STORES                         F2B18770
       TSX     STORXX,4                                                 F2B18780
2R0200 LXD     2R0065,1             RETURN FOR                          F2B18790
       TRA     2R0020               NEXT R2                             F2B18800
       REM TABLE SEARCH OF FORVAL                                       F2B18810
DS4VAL LXD     END80,1              OBTAIN FORVAL EMPTY INDICATOR.      F2B18820
       TXL     DS4V20,1,0           EXIT IF FORVAL EMPTY                F2B18830
       CLA     $TAG                 PRESET WD E2 FOR LIST               F2B18840
       ALS     18                   ROUTINE,TAU TAG AND NAME            F2B18850
       ADD     TS                                                       F2B18860
       STO     $E2                                                      F2B18870
       MSE     100                  LIGHT 100 OFF                       F2B18880
       NOP                                                              F2B18890
       CLA     ALPHA                THESE INSTRUCTIONS SET UP           F2B18900
       STO     $A                   FOR DRUM SEARCH                     F2B18910
       CLA     BETA                                                     F2B18920
       ADD     L(1)A                                                    F2B18930
       STO     $B                                                       F2B18940
       LXD     L(0),1               GET LOC OF 1ST 4VAL ENTRY, STORE IN F2B18950
       TSX     FSXX,4               UPDATED ADD. PUT 0 IN XRA, GO TO    F2B18960
       LXD     DELTA,4              SEARCH ROUTINE. UPON RETURN,        F2B18970
       TXH     DS4V20,4,2           ECIT UNLESS DELTA IS 2,             F2B18980
       TXL     DS4V20,4,1           IN WHICH CASE,CONTINUE              F2B18990
       PSE     100                  TURN INDICATOR LIGHT ON             F2B19000
       CLA     $B                   THE FOLLOWING INSTR.                F2B19010
       STO     $NEXTA               SET UP TWO ADDITIONAL               F2B19020
       CLA     $A                   RANGES FOR SEARCHING,               F2B19030
       STO     $B                   THOSE FORMULAS OUTSIDE              F2B19040
       LXD     XL,2                 OF DC BUT WITHIN DL.                F2B19050
       CLA     DOTGZ,2              IN THESE SPECIAL RANGES             F2B19060
       PAX     0,2                  AS SOON AS ONE ENTRY IS             F2B19070
       ANA     DECMSK               FOUND IN EITHER RANGE,              F2B19080
       STO     $A                   TO BE DONE.                         F2B19090
       PXD     0,2                                                      F2B19100
       ADD     L(1)A                                                    F2B19110
       STO     $LASTB                                                   F2B19120
       CLA     $A                                                       F2B19130
       ADD     L(1)                                                     F2B19140
       SUB     $B                                                       F2B19150
       TZE     DS4V10               IF THIS RANGE IS EMPTY, SKIP SEARCH.F2B19160
       LXD     L(0),1                                                   F2B19170
       TSX     FSXX,4               GO TO SEARCH ROUTINE                F2B19180
DS4V10 CLA     $NEXTA               A AND B FOR SECOND                  F2B19190
       STO     $A                                                       F2B19200
       CLA     $LASTB                                                   F2B19210
       STO     $B                                                       F2B19220
       SUB     $A                                                       F2B19230
       TZE     DS4V20                                                   F2B19240
       PSE     100                                                      F2B19250
       LXD     L(0),1                                                   F2B19260
       TSX     FSXX,4                                                   F2B19270
DS4V20 TRA     RELEND               EXIT                                F2B19280
       REM ROUTINE FSXX FINDS THOSE FORVAL ENTRIES FALLING WITHIN THE   F2B19290
       REM RANGE A TO B (B+1) AS DEFINED EARLIER.                       F2B19300
FSXX   SXD     FS28,4               SAVE LINKAGE.                       F2B19310
FS00   CLA     FORVAL-1             INITIALIZE DECREMENTS               F2B19320
       STD     FS50                 THAT TEST                           F2B19330
       STD     FS100                END OF FORVAL TABLE.                F2B19340
       LXD     MAXFVL,1             LOAD XRA FOR FIRST FVL ENTRY.       F2B19350
       CLA     $A                                                       F2B19360
FS20   LDQ     4VALZ,1              DOES THIS FORVAL ALPHA              F2B19370
       TLQ     FS40                 EXCEED A.                           F2B19380
       CLA     $B                   YES. DOES FIRST ENTRY EXCEEDING A   F2B19390
       TLQ     FS85                 ALSO EXCEED B. IF NO, TRANSFER.     F2B19400
FS28   TXL     BS99,,0              IF YES, EXIT.                       F2B19410
FS40   TXI     FS50,1,-2            BUMP FOR NEXT FORVAL ENTRY.         F2B19420
FS50   TXH     FS20,1,0             IF END OF FORVAL TABLE REACHED      F2B19430
       TRA     BS99                 WITHOUT ANY ENTRY EXCEEDING A, EXIT.F2B19440
FS70   LDQ     4VALZ,1              DOES THIS FORVAL ENTRY              F2B19450
       TLQ     FS90                 EXCEED B, IF YES,                   F2B19460
FS80   SXD     FSEND,1              SAVE IR FOR LAST 4VAL IN RANGE.     F2B19470
       SXD     BS40,1               SET DEC FOR TEST IN BS BELOW        F2B19480
       TRA     BS00                 GO TO PROCESS THESE ENTRIES.        F2B19490
FS85   SXD     FSBEG,1              SAVE IR FOR 1ST 4VAL IN RANGE.      F2B19500
FS90   TXI     FS100,1,-2           BUMP FOR NEXT FORVAL ENTRY          F2B19510
FS100  TXH     FS70,1,0             IF END OF FORVAL TABLE,             F2B19520
       TRA     FS80                 GO TO SAVE IR SETTING.              F2B19530
FSBEG  PZE                          IX FOR 1ST 4VAL IN RANGE            F2B19540
FSEND  PZE                          IX FOR LAST+1 4VAL IN               F2B19550
       REM                          RANGE A TO B.                       F2B19560
       REM THIS ROUTINE SEARCHES AMONG THOSE FORVAL ENTRIES OF          F2B19570
       REM ROUTINE FS00 FOR RSYM1, AND RSYM2 IF DELTA IS 3.             F2B19580
BS00   CLA     $RSYM1               DOES RSYM1                          F2B19590
       LXD     DELTA,4              OR, IF DELTA IS 3, RSYM1 OR 2,      F2B19600
BS10   LXD     FSBEG,2                                                  F2B19610
BS20   CAS     4VALZ+1,2            MATCH ANY OF THESE FORVAL ENTRIES   F2B19620
       TRA     BS30                                                     F2B19630
       TRA     BS60                 YES. GO TO SEE IF NORMAL SEARCH.    F2B19640
BS30   TXI     BS40,2,-2            NO. STEP THRU RANGE OF FORVALS,     F2B19650
BS40   TXH     BS20,2,0             AND, IF NO MATCH FOUND,             F2B19660
BS50   TXL     BS99,4,2             EXIT.                               F2B19670
       LXD     L(0),4               (SET DELTA LESS THAN 3 FOR          F2B19680
       REM                          NEXT PASS).                         F2B19690
       CLA     $RSYM2                                                   F2B19700
       TRA     BS10                                                     F2B19710
BS60   MSE     100                  TEST TO SEE IF                      F2B19720
       TRA     BS80                 NORMAL SEARCH, OR IF                F2B19730
BS78   TXL     BS90,,0              SPECIAL CASE OF DELTA TWO.          F2B19740
BS80   STO     4VALES               RSYM FOUND,ARRANGE TO               F2B19750
       LXD     XL,1                 SAVE INDEXED SUBSCRIPTS.            F2B19760
       CLA     BITONE                                                   F2B19770
       ORS     DOTGZ+5,1                                                F2B19780
       LXD     XC,1                                                     F2B19790
       ORS     DOTGZ+5,1            RSYM FOUND, E2 PREVIOUSLY           F2B19800
       CLA     4VALZ,2              PREPARED,NOW PREPARE                F2B19810
       STO     $E1                  E1, SAVE AC, XRB, XRC,              F2B19820
       CLA     TSXCOM               AND LIST.                           F2B19830
       SXD     BS85,2               AFTER LISTING,                      F2B19840
       SXD     BS78,4               RESTORE ACC,XRB,XRC                 F2B19850
       TSX     $LIST,4              AND RETURN TO CONTINUE              F2B19860
       LXD     BS85,2               SEARCH.                             F2B19870
       LXD     BS78,4                                                   F2B19880
       CLA     4VALES                                                   F2B19890
BS85   TXL     BS30,,0                                                  F2B19900
BS90   LXD     XL,2                 SPECIAL CASE,DELTA TWO,             F2B19910
       CLA     BITONE               PUT IN BIT TO SAVE SL               F2B19920
       ORS     DOTGZ+5,2                                                F2B19930
       LXD     LOWPOS,2             OBTAIN INDEX QUANTITY 1, 3, 5.      F2B19940
       CLA     L(0)                 FOR XL,                             F2B19950
       STO     X1+5,2               SET PROPER X AND L TO ZERO,         F2B19960
       STO     X1+6,2                                                   F2B19970
       TIX     BS91,2,1             ADJUST 1,3,5 TO 1,2,4,              F2B19980
BS91   PXD     0,2                  PUT IN ACC                          F2B19990
BS92   ORS     DORC                 AND PUT BIT IN DORC                 F2B20000
       COM                          REMOVE BIT                          F2B20010
       ANS     DOSUBS               FROM DOSUBS                         F2B20020
       CLA     XC                                                       F2B20030
       STO     XL                                                       F2B20040
       CLA     LC                                                       F2B20050
       STO     LL                                                       F2B20060
       CLA     L(1)                                                     F2B20070
       STO     NRDS                                                     F2B20080
       STO     DELTA                                                    F2B20090
       TRA     DS4V20               EXIT                                F2B20100
BS99   LXD     FS28,4               EXIT FROM FSXX ENTRY                F2B20110
       TRA     1,4                                                      F2B20120
4VALES PZE                          E.S.                                F2B20130
XR1                                                                     F2B20140
LR1                                                                     F2B20150
XR2                                                                     F2B20160
LR2                                                                     F2B20170
D2D1                                                                    F2B20180
D3D1                                                                    F2B20190
D3D2                                                                    F2B20200
TR1                                                                     F2B20210
TR2                                                                     F2B20220
       REM SUBROUTINE GETNAM                                            F2B20230
GETNAM LXD     NAMXX,1              THIS ROUTINE SEARCHES               F2B20240
       SXD     GETN20,1             TABLE NAMZ FOR THE NAME             F2B20250
       LXA     NAMXX,1              OF TAU TAG IN A PARTICULAR          F2B20260
       TRA     GETN20                                                   F2B20270
GETN05 CAS     NAMZ,1               DO FORMULA.                         F2B20280
       TRA     GETN10                                                   F2B20290
       TRA     GETN30                                                   F2B20300
GETN10 TXI     GETN20,1,-2                                              F2B20310
GETN20 TXH     GETN05,1,0                                               F2B20320
       ANA     ADDMSK                                                   F2B20330
       TRA     1,4                                                      F2B20340
GETN30 CLA     NAMZ+1,1                                                 F2B20350
       TRA     1,4                                                      F2B20360
       REM SUBROUTINE ADDSER                                            F2B20370
ADDSER PXD     0,1                                                      F2B20380
       ADD     $TAG                                                     F2B20390
       LXD     ADTXX,1              PREPARE XRA AND DEC O               F2B20400
       SXD     ADS030,1             ADS030 FOR TABLE SEARCH.            F2B20410
       LXA     ADTXX,1                                                  F2B20420
       TRA     ADS030               TRA FOR EMPTY TABLE TEST            F2B20430
ADS010 CAS     ADTAGZ,1                                                 F2B20440
       TRA     ADS020                                                   F2B20450
       TRA     ADS040               FIRST WORD FOUND                    F2B20460
ADS020 TXI     ADS030,1,-2                                              F2B20470
ADS030 TXH     ADS010,1,0                                               F2B20480
       TRA     2,4                  NOT FOUND                           F2B20490
ADS040 CLA     ADTAGZ+1,1                                               F2B20500
ADS050 TRA     1,4                                                      F2B20510
       REM SUBROUTINES STORES AND STORXX                                F2B20520
STORES SXD     ST040,4              THIS ROUTINE PREPARES               F2B20530
       CLA     LR1                  AN ENTRY FOR TABLE TRASTO           F2B20540
       ARS     18                   AND USES LIST TO ENTER              F2B20550
       ADD     LC                   THE ENTRY ON THE PROPER             F2B20560
       STO     $E2                  DRUM TABLE. IF SPC000               F2B20570
       CLA     TR1                  IS USED BY THE ROUTINE,             F2B20580
       TXL     ST020,2,1            MANY ENTRIES MAY BE MADE            F2B20590
       CLA     TR2                  IN TRA STO.                         F2B20600
ST020  ALS     18                   IF DELTA EQUALS ONE OR TWO,         F2B20610
       ADD     TS                   THIS ROUTINE IS ENTERED             F2B20620
       STO     $E3                  THROUGH STORES WITH C(XRB)          F2B20630
       TXL     ST035,2,0            ZERO. IF DELTA IS THREE             F2B20640
       TXL     ST050,2,1            AND WE ARE WORKING ON               F2B20650
       TRA     ST035                TRANSFERS DR2 TO DS,THEN            F2B20660
STORXX SXD     ST040,4              STORES ENTRY IS USED WITH           F2B20670
       CLA     LR2                  C(XRB)=2                            F2B20680
       ARS     18                   IF DELTA=3,TRA DR1 TO DS,           F2B20690
       ADD     LR1                  STORES ENTRY IS USED WITH           F2B20700
       STO     $E2                  C(XRB)=1                            F2B20710
       CLA     TR2                  IF DELTA=3,TRA DR2 TO DR1,          F2B20720
       ALS     18                   ENTRY  STORXX IS USED.              F2B20730
       ADD     TR1                  C(XRB) NOT USED.                    F2B20740
       STO     $E3                  LIST ROUTINE IS USED IN             F2B20750
       REM                          EVERY CASE, MAKING ONE              F2B20760
       REM                          TRASTO ENTRY, EXCEPT FOR            F2B20770
       REM                           CASE DELTA=3,TRA DR1 TO DS,        F2B20780
       REM                           C(XRB)=1,WHEN SPC000 IS USED.      F2B20790
ST035  CLA     DOTGZ,1              LIST ROUTINE USED.                  F2B20800
       STO     $E1                                                      F2B20810
       CLA     TRASTO                                                   F2B20820
       TSX     $LIST,4                                                  F2B20830
ST040  TXL     ST100,,0                                                 F2B20840
ST050  LXD     L(2),2               SPC000 USED.                        F2B20850
       CLA     TRASTO                                                   F2B20860
       TSX     SPC000,4                                                 F2B20870
ST100  LXD     ST040,4              EXIT                                F2B20880
       TRA     1,4                                                      F2B20890
       REM MKDO READS DOTAG A INTO DOUBLE BUFFERS AND USES THE          F2B20900
       REM FIRST TWO WORDS OF EACH ENTRY TO FORM THE DO TABLE           F2B20910
       REM FOR BLOCK THREE.                                             F2B20920
MKDO   LXD     MAXDO,1                                                  F2B20930
       SLT     3                                                        F2B20940
       TRA     MKDO1                EMPTY DOTAG.                        F2B20950
       SLN     3                    RESET SL                            F2B20960
       TRA     MKDO9                AND SKIP MKDO.                      F2B20970
MKDO1  AXT     -1,2                 FILL                                F2B20980
*      ***                                                              F2B20990
       TSX     (TAPE),4             FIRST                               F2B21000
       PZE     DBIO2,2,(RBNP)       BUFFER.                             F2B21010
       PZE     DTGL,,FTAPE3                                             F2B21020
MKDO2  AXC     -1,2                 REVERSE SWITCH.                     F2B21030
       CLA     DB1,2                CHANGE                              F2B21040
       STA     MKDO6                BUFFER ADDRESS.                     F2B21050
*      ***                                                              F2B21060
       TSX     (TAPE),4             FILL                                F2B21070
       PZE     DBIO2,2,(RBEP)       NEXT                                F2B21080
       PZE     DTGL,,FTAPE3         BUFFER.                             F2B21090
       SXA     MKDO2,2                                                  F2B21100
       NZT     (SCHU)+FTAPE3        TEST FOR EOF.                       F2B21110
       TRA     MKDO9                EOF.                                F2B21120
*      ***                                                              F2B21130
       CLA     (SCHU)+FTAPE3        COMPUTE                             F2B21140
       ANA     ADDMSK               XR VALUE                            F2B21150
MKDO4  SUB     DB1,2                FOR END OF                          F2B21160
       PAX     0,4                  NEST AND                            F2B21170
       SXD     MKDO8,4              SAVE IN TEST.                       F2B21180
       AXT     DBUFSZ,2                                                 F2B21190
MKDO5  AXT     2,4                  PICK UP                             F2B21200
MKDO6  CLA     **,2                 FIRST TWO WORDS                     F2B21210
       STO     DOZ,1                OF EACH DOTAG                       F2B21220
       TXI     *+1,2,-1             AND SAVE                            F2B21230
       TXI     *+1,1,-1             IN DO.                              F2B21240
       TIX     MKDO6,4,1                                                F2B21250
       TXI     *+1,2,-7             BUMP TO NEXT DOTAG ENTRY.           F2B21260
MKDO8  TXH     MKDO5,2,**           IS THIS END OF NEST.                F2B21270
       TRA     MKDO2                YES, GO TO READ NEXT NEST.          F2B21280
MKDO9  SXD     DOZ,1                SAVE XR VALUE FOR LAST DO ENTRY.    F2B21290
*      ***                                                              F2B21300
       TSX     (TAPE),4             REWIND TAPE 3 TO                    F2B21310
       PZE     REWIND,,(SKBP)       WRITE DOFILE C.                     F2B21320
       PZE     DTGL,,FTAPE3         (BLOCK 4).                          F2B21330
       TRA     NRMRT                GO TO BLOCK THREE)                  F2B21340
DBIO1  PZE     DBUF1+DBUFSZ                                             F2B21350
DB1    IORT    DBUF2,,DBUFSZ                                            F2B21360
DBIO2  PZE     DBUF2+DBUFSZ                                             F2B21370
DB2    IORT    DBUF1,,DBUFSZ                                            F2B21380
MAXDO  PZE     ,,600*M/N*2          MAX SIZE OF DO TABLE.               F2B21390
TSTPCH CLA     L(3)+5,4             PICK UP REFERENCE FOR NON CURRENT  $F2B21391
       PDX     0,2                  SUBSCRIPT - LEFT OR CENTER         $F2B21392
       CLA     L1+5,2               GET LEVEL NO. OF NON CURRENT SS    $F2B21393
       STD     L2ORL1               AND STORE IN WORKING STORAGE       $F2B21394
       CLA     X1+5,2               GET DOTAG REF. NO. OF NON CURRENT  $F2B21395
       STD     X2ORX1               SS AND STORE IN WORKING STORAGE    $F2B21396
       CLA     TCL                  RESTORE LEVEL OF CURRENT SS DO     $F2B21397
X2ORX1 BRA     RETRN,,*-*           TO ACCUMULATOR AND RETURN          $F2B21398
L2ORL1 PZE                                                             $F2B21399
 ENDB  SYN     *+11                                                    $F2B21400
TL     EQU     97                                                       F2B21410
ABIT   SYN     BIT18                                                    F2B21420
BBIT   SYN     BIT20                                                    F2B21430
SUBBIT SYN     BIT18                                                    F2B21440
RELEND SYN     BRA10                FINISH OF RELCON CODING BLOK.       F2B21450
       TCD     -1                                                      $F2B21455
       LBL     9F20,M                                                   F2B21460
       TTL     BLOCK C.                                                 F2B21470
*     SECTION TWO OF 709/7090 32K FORTRAN, BLOCK C.                     F2C00000
       HEAD    3                                                        F2C00010
       ORG     SYSCUR                                                  $F2C00020
       BCI     1,9F2000                                                $F2C00030
       ORG     (LODR)                                                  $F2C00040
       TXI     BLCK3A,,200                                              F2C00060
       ABS                                                              F2C00070
       REM BLOCK 3 DOES SUBSCRIPT ANALYSIS FOR                          F2C00080
       REM THOSE SUBSCRIPT COMBINATIONS NO SUBSCRIPT                    F2C00090
       REM ELEMENT OF WHICH IS UNDER CONTROL OF                         F2C00100
       REM A DO (PURE RELATIVE CONSTANTS). TWO                          F2C00110
       REM TYPES OF TSXCOM TABLE ENTRIES ARE MADE IN ROUTINE FOUND      F2C00120
       REM WHICH WILL INDICATE TO SUCCEEDING BLOCKS THE NECESSITY TO    F2C00130
       REM COMPILE EITHER DIRECT LXDS OF INDEX REG VALUES OR TSXS TO    F2C00140
       REM SUBROUTINES TO COMPUTE THOSE INDEX REG VALUES. FOUR TYPES OF F2C00150
       REM TRASTO TABLE ENTRIES ARE MADE WHICH WILL INDICATE THAT       F2C00160
       REM CERTAIN INDEXING INSTRUCTIONS SHOULD BE COMPILED ACCOMPANYINGF2C00170
       REM THE TRANSFERS OUT OF THE RANGE OF DOS WHICH DEFINE VALUES    F2C00180
       REM OF THE SUBSCRIPTS IN QUESTION. FINALLY, TSXCOM ENTRIES AND   F2C00190
       REM TABLE IRV ENTRIES ARE SORTED AND CONDENSED. ROUTINES         F2C00200
       REM ENCOUNTERED IN BLOCK 2 WILL BE RECOGNIZED IN THIS BLOCK 3 -  F2C00210
       REM SUBCOM, TRAWORD, SPC, TINFOR, LIST.                          F2C00220
M      SYN     1$M                  M/N IS THE RATIO OF TABLE SIZES     F2C00230
N      SYN     1$N                  TO NORMAL 32K SIZES.                F2C00240
TCOMZ  SYN     NAMKYZ-1             ADDITIONAL TABLE                    F2C00250
TCOM   SYN     TSCMTB               DEFINITIONS                         F2C00260
TCOMWC SYN     TCOMZ                FOR                                 F2C00270
IRVZ   SYN     TCOM-1               BLOCK                               F2C00280
IRV    SYN     IRVZ-600*M/N         THREE.                              F2C00290
IRVWC  SYN     IRV-1                                                    F2C00300
TAU3   SYN     1$TAU3                                                   F2C00310
TAU2   SYN     1$TAU2                                                   F2C00320
TAU1   SYN     1$TAU1                                                   F2C00330
4VALZ  SYN     2$4VALZ                                                  F2C00340
FORTZ  SYN     2$FORTZ                                                  F2C00350
DO     SYN     FORTZ                                                    F2C00360
DOZ    SYN     DO+600*M/N*2                                             F2C00370
DOTAG  SYN     DO+1                                                     F2C00380
DOTGZ  SYN     DOTAG+600*M/N*9                                          F2C00390
NAMZ   SYN     FRTGWC                                                   F2C00400
NAME   SYN     NAMZ-600*M/N*2                                           F2C00410
NAMWC  SYN     NAME-1                                                   F2C00420
       REM CONSULT END OF BLOCK FOR MORE SYN AND EQU ENTRIES.           F2C00430
       ORG     LADDIN+5                                                 F2C00440
TS     PZE                          NEW NAME.                           F2C00450
TAGIND PZE                          1 IF ONLY 1 SC(COEFF 1), OTHERWISE 0F2C00460
DELTA  PZE                          COUNT OF NO OF SYMBOLS IN SC COMB.  F2C00470
TL2    PZE                          LEV OF DOTAG MATCHING SC SYMBOL.    F2C00480
XR1    PZE                          IX DOTAG MATCHING RSYM1.            F2C00490
LR1    PZE                          LEV DOTAG MATCHING RSYM1.           F2C00500
NEXTR1 PZE                          IX LAST DOTAG OF NEST SEARCHED.     F2C00510
       REM                          IN TRAWRD 1ST LEVEL.                F2C00520
XR2    PZE                          IX DOTAG MATCHING RSYM2.            F2C00530
LR2    PZE                          LEV DOTAG MATCHING RWYM2.           F2C00540
NEXTR2 PZE                          IX LAST DO OF NEST SEARCHED.        F2C00550
       REM                          IN TRAWRD ON 2ND LEVEL.             F2C00560
XR3    PZE                          IX DOTAG MATCHING RSYM3.            F2C00570
NEXTR3 PZE                          IX LAST DO OF NEXT SEARCHED.        F2C00580
       REM                          IN TRWRD ON 3RD LEVEL.              F2C00590
SKIP   PZE                          SKIP, ZERO OR ONE.                  F2C00600
IRVXX  PZE                          CURRENT IRV TABLE IX VALUE.         F2C00610
L(0)           0,0,0                                                    F2C00620
L(1)           0,0,1                                                    F2C00630
L(2)           0,0,2                                                    F2C00640
L(3)           0,0,3                                                    F2C00650
L(6)           0,0,6                                                    F2C00660
L(36)          0,0,36                                                   F2C00670
L(2)A  OCT     2                                                        F2C00680
L(MZ)  MZE                                                              F2C00690
BIT18  OCT     400000                                                   F2C00700
PREMSK OCT     -200000000000                                            F2C00710
NAMAX          ,,600*M/N*2          MAX SIZE OF NAME.                   F2C00720
IRVMAX         0,0,600*M/N          MAXIMUM SIZE OF IRV.                F2C00730
TCOMAX         ,,1000*M/N*2         MAX SIZE OF TSXCOM.                 F2C00740
NMKYAD         NMKYTB               ORIGIN OF NAMKEY TABLE CARRYOVER    F2C00750
       REM                           FROM BL 2.                         F2C00760
NAMAD          NAME                 ORIGIN O F NAME TABLE               F2C00770
TCOMAD         TCOM                 ORIGIN OF TCOM TABLE                F2C00780
TRSTAD         TRSTTB               ORIGIN OF TRASTO TABLE              F2C00790
BLCK3A CLA     TSCMWC               INITIALIZE                          F2C00800
       ADD     LADDIN+2             LADDS CONSTANTS                     F2C00810
       ANA     ADDMSK               IN ROUTINE LIST FOR                 F2C00820
       STO     $LADDS+2             TSXCOM,                             F2C00830
       CLA     TRSTWC                                                   F2C00840
       AXT     TCOMZ,1                                                  F2C00850
       SXD     LADDIN+2,1                                               F2C00860
       ADD     LADDIN+1                                                 F2C00870
       ANA     ADDMSK                                                   F2C00880
       STO     $LADDS+1             AND TRASTO.                         F2C00890
       CLA     IRVMAX               INITIALIZE IRVXX.                   F2C00900
       STO     IRVXX                                                    F2C00910
       CLA     L(0)                 INITIALIZE WD CT OF                 F2C00920
       STO     IRVWC                IRV TABLE                           F2C00930
       LXD     FORTAG-1,1           IF FORTAG EMPTY,                    F2C00940
       TXH     BLCK3B,1,3000*M/N*2-1                                    F2C00950
       CLA     NMKYWC               GET WD CT OF NAMKEY LEFT FROM BL2.  F2C00960
       PAX     0,1                                                      F2C00970
       TXL     NAM95,1,0            IF NO TABLE NAME, GO SEARCH 4VAL.   F2C00980
       ADD     NAMAD                ADD ORG NAME TABLE TO GET END, AND  F2C00990
       STA     NAM20                STORE IN STORE ADDRESS              F2C01000
       CLA     NMKYWC               GET WD CT OF NAMKEY LEFT FROM BL 2. F2C01010
       ADD     NMKYAD               ADD ORG NAMKEY TABLE CARRYOVER FROM F2C01020
       STA     NAM10                BL2 TO GET END AND STORE IN CLA ADD F2C01030
       PXD     0,1                                                      F2C01040
       SSM                                                              F2C01050
       ADD     NAMAX                COMP NEXT UNUSED INDEX AND          F2C01060
       STO     NAME-1               PLACE IN WD CT LOCAT.               F2C01070
NAM10  CLA     0,1                  MOVE NAMKEY TABLE CARRYOVER FROM    F2C01080
NAM20  STO     0,1                  BL 2 TO NEW LOCATION FOR THIS       F2C01090
       TIX     NAM10,1,1            BLOCK.                              F2C01100
       TRA     BEGIN                TABLE NAME ALL IN.                  F2C01110
NAM95  CLA     NAMAX                TABLE NAME EMPTY.                   F2C01120
       STO     NAME-1                                                   F2C01130
BEGIN  MSE     LIGHT                TEST FOR EMPTY FORVAL               F2C01140
       TRA     INIT                                                     F2C01150
       TRA     BLCK3B                                                   F2C01160
INIT   LXD     FORVAL-1,1           INITIALIZE                          F2C01170
       SXD     TAB60,1              .                                   F2C01180
       LXD     FORTAG-1,1           .                                   F2C01190
       SXD     VAL80,1              .                                   F2C01200
       SXD     VAL95,1              .                                   F2C01210
       LXD     DOZ,1                .                                   F2C01220
       SXD     IND20,1              .                                   F2C01230
VALTAG LXD     MAXFTG,1             THIS PROGRAM                        F2C01240
VAL10  CLA     FORTZ,1              MAKES A                             F2C01250
       TMI     VAL90                PASS OVER                           F2C01260
       ANA     BITONE               FORTAG, AND                         F2C01270
       TNZ     VAL90                FOR EACH POSITIVE(UNTREATED IN BL2) F2C01280
       CLA     FORTZ,1              TAG WITH BITONE EQUAL               F2C01290
       ANA     ADDMSK               TO ZERO, (NOT YET TREATED HERE)     F2C01300
       STO     $TAG                 OBTAINS THE CORRESPONDING SSC.      F2C01310
       SXD     SAVEA,1              COMBINATION FROM THE                F2C01320
       TSX     SUBCOM,4             TAU TABLE DRUM.                     F2C01330
       LXD     L(3),4                                                   F2C01340
       PXD     0,0                                                      F2C01350
VAL20  STO     $RSYM1+3,4           INITIALIZE WITH ZEROES.             F2C01360
       TIX     VAL20,4,1                                                F2C01370
       LXD     L(6),1               THIS ROUTINE STORES                 F2C01380
       LXD     L(3),2               THE SYMBOLS AS FOLLOWS              F2C01390
VAL30  CLA     $S1+6,1              LEFTMOST IN RSYM1,                  F2C01400
       TZE     VAL40                NEXT SYMBOL IN RSYM2,               F2C01410
       STO     $RSYM1+3,2           RIGHTMOST IN RSYM3.                 F2C01420
       TXI     VAL40,2,-1           IF THERE ARE NOT THREE              F2C01430
VAL40  TIX     VAL30,1,2            SYMBOLS IN THE SC, THEN             F2C01440
       PXD     0,2                  THE RSYM LOCATIONS ARE              F2C01450
       SSM                          SET TO ZERO.                        F2C01460
       ADD     L(3)                 DELTA IS THE SYMBOL COUNT.          F2C01470
       TZE     VAL60                SUBSCRIPT IS CONSTANT, NO SYMBOLS.  F2C01480
       STO     DELTA                                                    F2C01490
       LXD     L(0),4               LOCATION TAGIND IS SET              F2C01500
       SUB     L(1)                 TO ZERO, UNLESS THE SC              F2C01510
       TNZ     VAL50                HAS THE FOLLOWING                   F2C01520
       CLA     $S1                  CHARACTERISTICS                     F2C01530
       TZE     VAL50                ONE SYMBOL                          F2C01540
       LXD     $C1,1                IN LEFTMOST POSITION                F2C01550
       TXH     VAL50,1,1            WITH COEFFICIENT EQUAL              F2C01560
       LXD     L(1),4               TO ONE                              F2C01570
VAL50  SXD     TAGIND,4                                                 F2C01580
SAVEA  TXL     TABSER,,0            GO TO TABSER(DEC IS 4TAG IX)        F2C01590
VAL60  LXD     SAVEA,1              RETURN FROM PROCESSING              F2C01600
       CLA     FORTZ,1              ROUTINE. FOR THIS TAG,              F2C01610
       TMI     VAL70                AND ALL TAGS EQUAL TO               F2C01620
       ANA     BITONE               THIS TAG, SET FORTAG                F2C01630
       TNZ     VAL70                ENTRY BIT ONE EQUAL                 F2C01640
       CLA     FORTZ,1              TO ONE.                             F2C01650
       ANA     ADDMSK                                                   F2C01660
       SUB     $TAG                                                     F2C01670
       TNZ     VAL70                                                    F2C01680
       CLA     BITONE                                                   F2C01690
       ORS     FORTZ,1                                                  F2C01700
VAL70  TXI     VAL80,1,-1                                               F2C01710
VAL80  TXH     VAL60+1,1,0          IF 4TAG DONE,(DEC IS 4TAG IX)       F2C01720
       LXD     SAVEA,1              GO BACK                             F2C01730
VAL90  TXI     VAL95,1,-1           FOR NEXT TAG                        F2C01740
VAL95  TXH     VAL10,1,0            IF ANY       (DEC IS 4TAG IX)       F2C01750
       TRA     BLCK3B                                                   F2C01760
TABSER LXD     MAXFVL,1                                                 F2C01770
       SXD     TAB40,2              (6 - 2X NO SUB SYMBOLS     - VAL40) F2C01780
TAB10  LXD     L(3),2               FORVAL                              F2C01790
       CLA     4VALZ+1,1            FOR AN                              F2C01800
TAB20  CAS     $RSYM1+3,2           OCCURRANCE                          F2C01810
       TRA     TAB30                OF ANY SYMBOL                       F2C01820
       TRA     FOUND                IN THIS SC.                         F2C01830
TAB30  TXI     TAB40,2,-1                                               F2C01840
TAB40  TXH     TAB20,2,0            (DEC LOADED FROM TABSER +1)         F2C01850
TAB50  TXI     TAB60,1,-2                                               F2C01860
TAB60  TXH     TAB10,1,0            (DEC HAS FORVAL IX)                 F2C01870
       TRA     VAL60                                                    F2C01880
FOUND  SXD     FND10,1              IF SYMBOL FOUND,                    F2C01890
       LXD     TAGIND,4             MAKE NORMAL OR SPECIAL              F2C01900
       CLA     4VALZ,1              ENTRY IN TSXCOM, DEPENDING          F2C01910
       TXH     FND20,4,0            ON TAGIND. (UNLESS SEE SUBRT INDO)  F2C01920
       STO     FORNR                                                    F2C01930
       TSX     INDO,4                                                   F2C01940
       TRA     FND40                INDO RETURN IF FRVL ALPH IN RANGE MTF2C01950
       LXD     FND10,1              RETURN FROM INDO WHEN NOT SO.       F2C01960
       CLA     4VALZ,1                                                  F2C01970
       STO     $E1                  SPECIAL ENTRY IF TAGIND             F2C01980
       CLA     $TAG                 NOT ZERO.                           F2C01990
       ALS     18                                                       F2C02000
       ORA     $TAG                                                     F2C02010
FND10  TXL     FND30,,0             (DEC HAS FORTAG IX)                 F2C02020
FND20  ORA     $TAG                 SET UP E BLCK WHEN TAGIND IS 1.     F2C02030
       STO     $E1                                                      F2C02040
       CLA     $RSYM1               TAG SYMBOL                          F2C02050
FND30  STO     $E2                                                      F2C02060
       CLA     TSXCOM               TSXCOM KEY                          F2C02070
       TSX     $LIST,4                                                  F2C02080
FND40  LXD     FND10,1                                                  F2C02090
       TRA     TAB50                CONTINUE SEARCH                     F2C02100
       REM SUBRT INDO.... THIS ROUTINE DETERMINES  WHETHER THE FORVAL   F2C02110
       REM WHICH HAS BEEN FOUND TO MATCH A SUBSCRIPT FALLS WITHIN RANGE F2C02120
       REM OF A DO WHICH IN TURN MATCHES THE FORAVAL. IF SO A RETURN IS F2C02130
       REM MADE AND TSXCOM ENTRY FOR THIS FORVAL ALPHA IS OMMITTED.     F2C02140
INDO   LXD     IND60,1                                                  F2C02150
       TRA     IND20                                                    F2C02160
IND10  CLA     DOZ,1                OBTAIN FIRST WORD DOTAG.            F2C02170
       PAX     0,2                  DOTAGS BETA.                        F2C02180
       ANA     DECMSK               DOTAGS ALPHA                        F2C02190
       CAS     FORNR                AGAINST FORVAL ALPHA.               F2C02200
       TRA     2,4                  OUTSIDE RANGE . RETURN.             F2C02210
       TSX     ERRORM,4             DECR OF FIRST WD OF XR1             F2C02220
       REM                          DO    ENTRY (IFN) SHOULD NOT        F2C02230
       REM                          EQUAL TO FORNR. DO IS FIRST         F2C02240
       REM                          TWO WDS OF EACH DOTAG ENTRY         F2C02250
       REM                          (FILE 1 TAPE3), AND FORNR IS        F2C02260
       REM                          4VAL ENTRY WITH XR VALUE IN         F2C02270
       REM                          DECR OF FND10.                      F2C02280
       PXD     0,2                                                      F2C02290
       CAS     FORNR                DOTAGS BETA AGAINST FORVAL ALPHA.   F2C02300
       TRA     IND30                FORVAL WITHIN RANGE                 F2C02310
       TRA     IND30                OF DOTAG.                           F2C02320
       TXI     IND20,1,-2                                               F2C02330
IND20  TXH     IND10,1,0                                                F2C02340
       TRA     2,4                  DOTAG EXHAUSTED, RETURN.            F2C02350
IND30  LXD     L(3),2                                                   F2C02360
       CLA     DOZ+1,1              FN  EDIT CORR CD NR.                F2C02370
IND40  CAS     $RSYM1+3,2           DOES DOTAG SYMBOL EQUAL             F2C02380
       TRA     IND50                FORVAL SYMBOL (WHICH HAS BEEN FOUND F2C02390
       TRA     1,4                  TO EQUAL SUBSCRIPT). IF SO, RETURN. F2C02400
IND50  TIX     IND40,2,1                                                F2C02410
       TXI     IND20,1,-2                                               F2C02420
FORNR  PZE                          STORAGE FOR 1ST WD 4VAL (ALPHA)     F2C02430
IND60          ,,600*M/N*2                                              F2C02440
       REM     *******************SUBROUTINES COMMON TO 3A + 3B.        F2C02450
*      ***                                                              F2C02460
NORMRT TSX     (LOAD),4             GO TO BLOCK 4.                      F2C02470
       PZE                                                              F2C02480
BLCK3B LXD     FORTAG-1,1                                               F2C02490
       TXH     NORMRT,1,3000*M/N*2-1                                    F2C02500
       MSE     99                                                       F2C02510
       TRA     RDO105                                                   F2C02520
       PSE     99                                                       F2C02530
       TRA     RDTSX                                                    F2C02540
RDO105 LXD     DORCCT,1             PICK UP DOTAG RECORD COUNT.         F2C02550
       SXA     SKLST1,1                                                 F2C02560
*      ***                                                              F2C02570
RDORD  TSX     (TAPE),4             READ IN                             F2C02580
       PZE     RDOCM2,,(RBNC)       ONE DOTAG                           F2C02590
       PZE     DTGBL,,FTAPE2        RECORD.                             F2C02600
*      ***                                                              F2C02610
       CLA     (SCHU)+FTAPE2        UPDATE                              F2C02620
       STA     RDOCM2               ADDRESS.                            F2C02630
       TIX     RDORD,1,1            RETURN TO READ NEXT RECORD.         F2C02640
       CLA     RDOCM2               COMPUTE                             F2C02650
       ANA     ADDMSK               XR VALUE FOR                        F2C02660
       SUB     LDTGZ                END OF TABLE.                       F2C02670
       TMI     RDO30                TEST FOR OVERFLOW.                  F2C02680
       TSX     ERRORM,4             DOTAG TABLE OVERFLOWS A BUFFER      F2C02690
       REM                          THE SAME SIZE AS THE ONE FROM WHICH F2C02700
       REM                          IT WAS WRITTEN IN RECORD 16.        F2C02710
       REM                          DOTAG IS ON TAPE 2 AS FILE 6.       F2C02720
RDO30  ALS     18                   SAVE                                F2C02730
       STD     DOTAG-1              NEXT UNUSED INDEX.                  F2C02740
*      ***                                                              F2C02750
RDO40  TSX     (TAPE),4             SPACE TAPE                          F2C02760
       PZE     SKLST1,,(SKBP)       TO READ DOTAG                       F2C02770
       PZE     DTGBL,,FTAPE2        TABLE (BLOCK 5).                    F2C02780
       TRA     DOPASS                                                   F2C02790
DTGBL  BCI     1,DOTAGB                                                 F2C02800
RDOCM2 IORT    DOTAG,,200*M/N*9                                         F2C02810
SKLST1 MZE     **,,0                                                    F2C02820
LDTGZ          DOTGZ                                                    F2C02830
RDES1  PZE                          RECORD COUNT                        F2C02840
RDES2  PZE                          RECORD COUNT                        F2C02850
DOPASS LXD     DOTAG-1,1            DOTAG INDEX.                        F2C02860
       SXD     SYM40,1              INITIALIZE.                         F2C02870
       SXD     SYM130,1             .                                   F2C02880
       SXD     SYM220,1             .                                   F2C02890
       SXD     TRAW20,1             .                                   F2C02900
       SXD     TRAW50,1             .                                   F2C02910
       SXD     SP040,1                                                  F2C02920
       SXD     SP090,1                                                  F2C02930
       LXD     NAME-1,1             .                                   F2C02940
       SXD     GETN20,1             .                                   F2C02950
       REM THIS ROUTINEMAKES A PASS OVER FORTAG AND FOR EACH NON-       F2C02960
       REM NEGATIVE TAG, OBTAINS THE CORRESPONDING SUBSCRIPT COMBINATIONF2C02970
       REM FROM THE TAU TABLE. THE SYMBOLS ARE PUT INTO THE LOCATIONS   F2C02980
       REM RSYM1, RSYM2, RSYM3, AND LOCATION TAGIND IS INITIALIZED.     F2C02990
       REM CONTROL THEN GOES TO ROUTINE SYMONE. UPON RETURN, THIS ENTRY F2C03000
       REM IN FORTAG AND ALL OTHER NON- NEGATIVE ENTRIES  CONTAINING    F2C03010
       REM THIS TAG ARE SET NEGATIVE.                                   F2C03020
TAGPAS LXD     FORTAG-1,1                                               F2C03030
       SXD     TINF3,1                                                  F2C03040
       SXD     TAGP80,1                                                 F2C03050
       SXD     TAGP98,1                                                 F2C03060
       LXD     MAXFTG,1             MAXIMUM SIZE TABLE FORTAG.          F2C03070
TAGP10 CLA     FORTZ,1                                                  F2C03080
       TMI     TAGP94               IF NEG, GET NEXT FORTAG             F2C03090
       ANA     ADDMSK               TAG                                 F2C03100
       STO     $TAG                                                     F2C03110
       SXD     TAGX,1               SAVE CURRENT FORTAG IX              F2C03120
       TSX     SUBCOM,4             OBTAIN AND DISPERSE THE TAU TABLES. F2C03130
       LXD     L(3),4                                                   F2C03140
       PXD     0,0                                                      F2C03150
TAGP20 STO     $RSYM1+3,4           INITIALIZE WITH ZEROS.              F2C03160
       TIX     TAGP20,4,1                                               F2C03170
       LXD     L(6),1                                                   F2C03180
       LXD     L(3),2                                                   F2C03190
       LXD     L(0),4                                                   F2C03200
TAGP30 CLA     $S1+6,1              GET SYMBOL                          F2C03210
       TZE     TAGP40               IF ZERO, GET NEXT SYMBOL            F2C03220
       TXH     TAGP34,2,2           AT RSYM2 AND RSYM3 PASS,            F2C03230
       CAS     $RSYM1               CHECK FOR DUPLICATE SYMBOLS.        F2C03240
       TRA     TAGP32                                                   F2C03250
       TXI     TAGP40,4,1           SYMBOL DUPLICATES RSYM1.            F2C03260
TAGP32 CAS     $RSYM2                                                   F2C03270
       TRA     TAGP34                                                   F2C03280
       TXI     TAGP40,4,1           SYMBOL DUPLICATES RSYM2.            F2C03290
TAGP34 STO     $RSYM1+3,2                                               F2C03300
       TXI     TAGP40,2,-1          BUMP DELTA COUNTER.                 F2C03310
TAGP40 TIX     TAGP30,1,2                                               F2C03320
       PXD     0,2                  COMPUTE                             F2C03330
       SSM                          DELTA AS NO                         F2C03340
       ADD     L(3)                 OF DISTINCT SYMBOLS.                F2C03350
       TZE     TAGP50               CONSTANT SUBSCRIPT.                 F2C03360
       STO     DELTA                                                    F2C03370
       LXD     L(0),2                                                   F2C03380
       TXH     TAGP45,4,0           IF DUPES, SET TAGIND TO ZERO        F2C03390
       SUB     L(1)                                                     F2C03400
       TNZ     TAGP45               IF DELTA NOT 1, SET TAGIND TO 0.    F2C03410
       CLA     $S1                                                      F2C03420
       TZE     TAGP45               IF SSC CONSTANT, SET TAGIND TO 0.   F2C03430
       LXD     $C1,1                IF COEFF NOT 1 SET TAGIND TO 0.     F2C03440
       TXH     TAGP45,1,1                                               F2C03450
       LXD     L(1),2               OTHERWISE SET TAGIND TO ONE.        F2C03460
TAGP45 SXD     TAGIND,2                                                 F2C03470
       TRA     SYMONE               GO TO ANALYZE DONEST.               F2C03480
TAGP50 LXD     TAGX,1               IF ANY                              F2C03490
TAGP60 CLA     FORTZ,1              OF THE AS YET UNTREATED             F2C03500
       TMI     TAGP70               FORTAGS                             F2C03510
       ANA     ADDMSK               ARE                                 F2C03520
       SUB     $TAG                 THE SAME AS THAT TAG                F2C03530
       TNZ     TAGP70               JUST TREATED,                       F2C03540
       CAL     L(MZ)                SET THEM                            F2C03550
       ORS     FORTZ,1              MINUS.                              F2C03560
TAGP70 TXI     TAGP80,1,-1                                              F2C03570
TAGP80 TXH     TAGP60,1,0           (DEC HAS 4TAG IX)                   F2C03580
TAGP90 LXD     TAGX,1                                                   F2C03590
TAGP94 TXI     TAGP98,1,-1          IF ALL OF FORTAG                    F2C03600
TAGP98 TXH     TAGP10,1,0           HAS BEEN DONE, (DEC HAS 4TAG IX)    F2C03610
TAGX   TXL     RDTSX,,0             EXIT.                               F2C03620
       REM ROUTINE SYMONE FINDS DOFORMULAS DEFINING SOME SYMBOL IN THIS F2C03630
       REM SC. IT USES TRAWRD TO DETERMINE WHETHER OR NOT ROUTINE       F2C03640
       REM PROCESS SHOULD BE USED.                                      F2C03650
       REM IF MORE THAN ONE SYMBOL, IT THEN USES ROUTINE SYM2.          F2C03660
SYMONE LXD     MAXDTG,1                                                 F2C03670
SYM10  LXD     L(3),2                                                   F2C03680
       CLA     DOTGZ+1,1            GET NEXT DOTAG SYMBOL.              F2C03690
SYM20  CAS     $RSYM1+3,2           IS IT SAME AS SS SYMBOL.            F2C03700
       TRA     SYM30                                                    F2C03710
       TRA     SYM50                YES                                 F2C03720
SYM30  TIX     SYM20,2,1                                                F2C03730
       TXI     SYM40,1,-9                                               F2C03740
SYM40  TXH     SYM10,1,0            END OF DOTAG, RETURN.               F2C03750
       TRA     TAGP50                                                   F2C03760
SYM50  CLA     $RSYM1               INTERCHANGE THE                     F2C03770
       LDQ     $RSYM1+3,2           MATCHING SUBSCRIPT                  F2C03780
       STO     $RSYM1+3,2           SYMBOL WITH                         F2C03790
       STQ     $RSYM1               RSYM1.                              F2C03800
       CLA     DOTGZ+5,1                                                F2C03810
       ANA     DECMSK               STORE LEVEL                         F2C03820
       STO     LR1                  OF                                  F2C03830
       STO     TL2                  DOTAG                               F2C03840
       SXD     XR1,1                THIS DOTAG IS R1.                   F2C03850
       LXD     DELTA,4              IF DELTA IS                         F2C03860
       LXD     L(1),2               ONE, THEN                           F2C03870
       TXL     SYM60,4,1            NO TRAWORD SKIP.                    F2C03880
       LXD     L(2),2               OTHERWISE, TRAWORD SKIP.            F2C03890
SYM60  TSX     TRAWRD,4                                                 F2C03900
       SXD     NEXTR1,1             SAVE INDEX LAST DOTAG HANDLED.      F2C03910
       TZE     SYM70                ARE THERE TRANSFERS OUT(TRABITS).   F2C03920
       LXD     XR1,1                YES. LOAD I.R. FOR MATCHING DOTAG.  F2C03930
       LXD     L(1),2               A ONE TELLS PROCESS THAT            F2C03940
       TSX     PROCES,4             CALLER WAS SYMONE. (B).             F2C03950
SYM70  LXD     DELTA,4              NO TRANSFERS OUT (TRABITS)          F2C03960
       TXL     SYM80,4,1            IF DELTA IS GREATER THAN ONE, THEN  F2C03970
       LXD     XR1,1                LOAD INDEX REG FOR MATCHING DOTAG,  F2C03980
       LXD     LR1,2                AND LEVEL AND                       F2C03990
       TRA     SYM2                 GO TO SECOND LEVEL SEARCH.          F2C04000
SYM80  LXD     NEXTR1,1             DELTA IS ONE,                       F2C04010
       TRA     SYM40                CONTINUE FIRST LEVEL SEARCH.        F2C04020
       REM ROUTINE SYMTWO MAKES A SECOND LEVEL SEARCH AMONG THOSE DOS   F2C04030
       REM NESTED WITHIN THE DO MATCHING RSYM1. USES PROCESS ROUTINE    F2C04040
       REM IF NECESSARY, AND ROUTINE SYM3 IF NECESSARY.                 F2C04050
SYM2   SXD     SYM100,2             INITIALIZE LEVEL TEST               F2C04060
       TRA     SYM120                                                   F2C04070
SYM90  CLA     DOTGZ+5,1            GET LEVEL OF                        F2C04080
       PDX     0,2                  NEW DOTAG AND                       F2C04090
SYM100 TXL     SYM40,2,0            TEST AGAINST LEVEL OF R1 AND        F2C04100
       CLA     DOTGZ+1,1            IF IN RANGE OF R1,                  F2C04110
       CAS     $RSYM2               COMP DOTAG SYMBOL AND RSYM2.        F2C04120
       TRA     SYM110                                                   F2C04130
       TRA     SYM150               MATCHES . GO TO TREAT R2.           F2C04140
SYM110 SUB     $RSYM3               DOESNT MATCH RSYM2, TRY RSYM3.      F2C04150
       TZE     SYM140                                                   F2C04160
SYM120 TXI     SYM130,1,-9          GET NEXT DOTAG                      F2C04170
SYM130 TXH     SYM90,1,0            (DEC IS DOTAG IX)                   F2C04180
       TRA     SYM40                IF END OF DOTAG, EXIT.              F2C04190
SYM140 CLA     $RSYM2               DOTAG SYMBOL MATCHES RSYM3,         F2C04200
       LDQ     $RSYM3               INTERCHANGE                         F2C04210
       STO     $RSYM3               RSYM2 AND                           F2C04220
       STQ     $RSYM2               RSYM3.                              F2C04230
SYM150 SXD     XR2,1                THIS DOTAG IS R2                    F2C04240
       SXD     LR2,2                SAVE ITS LEVEL .                    F2C04250
       LXD     L(1),2               IF DELTA IS                         F2C04260
       LXD     DELTA,4              TWO OR ONE, THEN                    F2C04270
       TXL     SYM160,4,2           NO TRAWORD SKIP.                    F2C04280
       LXD     L(2),2               OTHERWISE TRAWORD SKIP.             F2C04290
SYM160 TSX     TRAWRD,4                                                 F2C04300
       SXD     NEXTR2,1             SAVE INDEX LAST DOTAG HANDLED.      F2C04310
       TZE     SYM170               ARE THERE TRANSFERS OUT (TRABITS).  F2C04320
       LXD     XR2,1                YES. LOAD IX REG FOR MATCHING DOTAG.F2C04330
       LXD     L(2),2               A TWO TELLS PROCESS THAT            F2C04340
       TSX     PROCES,4             CALLER WAS SYM2. (2).               F2C04350
SYM170 LXD     DELTA,4              NO TRANSFERS OUT (TRABITS).         F2C04360
       TXL     SYM180,4,2           IF DELTA IS 3 , THEN                F2C04370
       LXD     XR2,1                LOAD INDEX REG FOR MATCHING DOTAG.  F2C04380
       LXD     LR2,2                AND LEVEL AND                       F2C04390
       TRA     SYM3                 GO TO THRID LEVEL SEARCH.           F2C04400
SYM180 LXD     NEXTR2,1             DELTA IS LESS THAN THREE,           F2C04410
       TRA     SYM130               CONTINUE SECOND LEVEL SEARCH.       F2C04420
       REM ROUTINE  SYM3 MAKES A THIRD LEVEL SEARCH OF DOTAG AMONG THOSEF2C04430
       REM DOS NESTED WITHIN THE DO MATCHING RSYM2, USES PROCESS IF     F2C04440
       REM NECESSARY, AND THEN RETURNS TO SYM2.                         F2C04450
SYM3   SXD     SYM200,2             INITIALIZE WITH LEVEL OF R2.        F2C04460
       TRA     SYM210                                                   F2C04470
SYM190 CLA     DOTGZ+5,1            GET LEVEL                           F2C04480
       PDX     0,2                  OF CURRENT DOTAG AND IF IT IS       F2C04490
SYM200 TXL     SYM130,2,0           OUT OF RANGE R2, EXIT.              F2C04500
       REM                          (DEC HAS LEVEL R2)                  F2C04510
       CLA     DOTGZ+1,1            CHECK FOR IDENTITY                  F2C04520
       SUB     $RSYM3               WITH THIRD FORTAG SYMBOL.           F2C04530
       TZE     SYM230               IF IDENTITY, GO TO ANALYZE. IF NOT, F2C04540
SYM210 TXI     SYM220,1,-9          GET NEXT DOTAG.                     F2C04550
SYM220 TXH     SYM190,1,0           IF END OF DOTAG (DEC IS DOTAG IX)   F2C04560
       TRA     SYM130               EXIT FROM THIRD LEVEL SEARCH        F2C04570
SYM230 SXD     XR3,1                SAVE IX OF MATCHING DO              F2C04580
       LXD     L(1),2               NO TRAWORD SKIP.                    F2C04590
       TSX     TRAWRD,4             GO TO HUNT TRANSFERS-OUT.           F2C04600
       TZE     SYM220               IF NO TRABITS, RETURN TO SEARCH.    F2C04610
       SXD     NEXTR3,1             TRNSFRS OUT. SAVE IX LAST DO        F2C04620
       REM                          HANDLED IN TRAWRD.                  F2C04630
       LXD     XR3,1                                                    F2C04640
       LXD     L(3),2               3 TELLS PROCESS THAT SYM3 CALLED.   F2C04650
       TSX     PROCES,4                                                 F2C04660
       LXD     NEXTR3,1             GET IX NEXT DOTAG AND               F2C04670
       TRA     SYM220               CONTINUE THIRD LEVEL SEARCH.        F2C04680
       REM ROUTINE PROCESS DETERMINES WHETHER OR NOT THERE EXISTS  A    F2C04690
       REM TAG IDENTICAL TO THE CURRENT RELCON TAG AND WHETHER  ITS     F2C04700
       REM TAG NAME HAS BEEN CHANGED. THE SEARCH FOR THIS IDENTICAL TAG F2C04710
       REM IS MADE THRU APPROPRIATE RANGES OF THAT DO WHOSE SYMBOL HAS  F2C04720
       REM BEEN FOUND TO MATCH ONE OF THE RELCON SYMBOLS. TRASTO ENTRIESF2C04730
       REM ARE ENTERED DEPENDING UPON WHICH OF THOSE CONDITIONS HOLDS.  F2C04740
PROCES SXD     DOX,1                SAVE DOTAG IX                       F2C04750
       SXD     SYMLNK,4             AND CALLER                          F2C04760
       SXD     PR10,2               AND INITIALIZE WITH B.              F2C04770
       LXD     DELTA,2                                                  F2C04780
       LXD     L(0),4                                                   F2C04790
PR10   TXH     PR20,2,0             DOES DELTA EXCEED B. (DEC IS B)     F2C04800
       LXD     L(1),4               IF NOT, THEN NO SKIP. OTHERWISE,    F2C04810
PR20   SXD     SKIP,4               SKIP IF C(SKIP)=0.                  F2C04820
       LXD     TAGIND,4             TRA IF SPECIAL CASE( MOST SIMPLE).  F2C04830
       TXH     PRSPEC,4,0           (TAGIND NOT ZERO)                   F2C04840
       CLA     DOTGZ,1              SEARCH NAME TABLE                   F2C04850
       ANA     DECMSK               GET RSYM1 DOTAG ALPHA IN DEC        F2C04860
       ADD     $TAG                 AND FORTAG IN ADDRESS.              F2C04870
GETNM  LXD     NAMAX,1              LOAD MAX NO. TABLE WORDS            F2C04880
       TRA     GETN3                                                    F2C04890
GETN1  CAS     NAMZ,1               DO   THE DOTAG ALPHA AND FORTAG     F2C04900
       TRA     GETN2                INDEX OF FIRST NAME ENTRY MATCH.    F2C04910
       TRA     GETN4                YES                                 F2C04920
GETN2  TXI     GETN3,1,-3           NO, GET NEXT NAME TABLE.            F2C04930
GETN3  TXH     GETN1,1,0            IS NAME EXHAUSTED (DEC HAS IX)      F2C04940
DOX    TXL     PR25,,0              YES, NOT FOUND (DEC HAS IX          F2C04950
       REM                          MATCHING DOTAG).                    F2C04960
GETN4  CLA     NAMZ+1,1             FOUND. GET NEW TAG NAME             F2C04970
       STO     TS                   AND SAVE IT.                        F2C04980
SYMLNK TXL     PR80,,0                                                  F2C04990
PR25   LXD     SKIP,4               NOT FOUND IN NAME TABLE,            F2C05000
       LXD     DOX,1                SEARCH FORTAG                       F2C05010
       TXH     PR30,4,0             IN PROPER RANGE.                    F2C05020
       LXD     L(1),2               INDICATE TINFOR SEARCH REQUIRED     F2C05030
       TSX     SP000,4                                                  F2C05040
       TRA     PR40                 NOT FOUND                           F2C05050
       TRA     PR90                 T FOUND                             F2C05060
PR30   TSX     TINFR,4                                                  F2C05070
       TRA     PR90                 FOUND, GO TO EXIT.                  F2C05080
PR40   LXD     L(0),2               T NOT FOUND, MAKE TYPE 6            F2C05090
       TSX     TRAENT,4             TRASTO ENTRY                        F2C05100
       REM MAKE ENTRY IN TABLE IRV                                      F2C05110
PR60   LXD     IRVXX,1              GET IX FOR ENTRY IN TABLE IRV.      F2C05120
       TXH     PR70,1,0                                                 F2C05130
       TSX     ERROR9,4             IRV TABLE IS FULL.                  F2C05140
PR70   CLA     $TAG                 PLACE TAG IN                        F2C05150
       ALS     18                   DECREMENT AND                       F2C05160
       ADD     $TAG                 ADDRESS AND                         F2C05170
       STO     IRVZ,1               STORE ENTRY IN TABLE IRV            F2C05180
       TXI     PR75,1,-1            BUMP IRV TABLE INDEX AND            F2C05190
PR75   SXD     IRVXX,1              SAVE IT FOR NEXT ENTRY.             F2C05200
       TRA     PR90                                                     F2C05210
PR80   LXD     L(1),2               MAKE TYPE ONE TRASTO ENTRY          F2C05220
       TSX     TRAENT,4                                                 F2C05230
PR90   LXD     SYMLNK,4             RESTORE INDEX REG                   F2C05240
       TRA     1,4                  AND RETURN TO CALLER                F2C05250
       REM ROUTINE PERSPEC IS FOR THE SPECIAL CASE OF A SINGLE SUBSCRIPTF2C05260
       REM RELCON WITH NO COEFFICIENT (TAGIND EQUALS ONE)               F2C05270
PRSPEC CLA     DOTGZ+8,1            IF DOTAGS                           F2C05280
       ARS     18                   TEST NAME                           F2C05290
       SUB     $TAG                 IS SAME AS                          F2C05300
       TNZ     PR100                CURRENT FORTAG                      F2C05310
       CLA     BIT18                AND IF                              F2C05320
       ANA     DOTGZ+6,1            THERE IS A                          F2C05330
       TZE     PR90                                                     F2C05340
       LXD     L(3),2               MAKE A TYPE 5 TRASTO ENTRY          F2C05350
       TSX     TRAENT,4                                                 F2C05360
       TRA     PR90                                                     F2C05370
PR100  TSX     TINFR,4              LOOK FOR PREV. PROC. 4 TAG.         F2C05380
       TRA     PR90                 FOUND.                              F2C05390
       LXD     L(2),2               NOT FOUND, MAKE A TYPE 1 TRASTO     F2C05400
       TSX     TRAENT,4             ENTRY                               F2C05410
       TRA     PR90                                                     F2C05420
       REM MAKE A TRASTO ENTRY. TRASTO TYPE ONE ENTRY IS MADE WHEN      F2C05430
       REM B IS ONE OR TWO, TYPE FIVE ENTRY WHEN B IS THREE, AND TYPE   F2C05440
       REM SIX TRASTO ENTRY WHEN B IS ZERO.                             F2C05450
TRAENT SXD     TE70,4                                                   F2C05460
       LXD     DOX,1                                                    F2C05470
       CLA     DOTGZ,1              GET ALPHA AND BETA                  F2C05480
       TXL     TE10,2,2             WHERE B IS 3 (TYPE5)                F2C05490
       SSM                          SET E1 NEG.                         F2C05500
TE10   STO     $E1                  AND STORE IN E1.                    F2C05510
       CLA     TL2                  GET LEVEL OF DOTAG                  F2C05520
       ARS     18                   INTO ADDRESS AND                    F2C05530
       TXH     TE20,2,0             WHERE B ZERO (TYPE 6),              F2C05540
       SSM                          SET NEG AND                         F2C05550
TE20   STO     $E2                  PUT IT INTO E2.                     F2C05560
       TXL     TE40,2,0             IS B=0 (TYPE 6).                    F2C05570
       TXL     TE30,2,1             IS B=1 (TYPE 1).                    F2C05580
       CLA     DOTGZ+8,1            B=2 OR 3(TYPE 1 OR 5).PREPARE       F2C05590
       ANA     DECMSK               DOTAG TEST NAME.                    F2C05600
       TXL     TE50,2,2             IS B=2 (SPECIAL TYPE 1).            F2C05610
       ORA     DOTGZ+2,1            B=3.PREPARE DOTAG PARAMETER.        F2C05620
       SSM                          N1 AND MAKE NEGATIVE.               F2C05630
       TRA     TE60                                                     F2C05640
TE30   LXA     TS,4                 B=1. PUT NEW TAG NAME               F2C05650
       PXD     0,4                  IN DECREMENT.                       F2C05660
       TRA     TE50                                                     F2C05670
TE40   CLA     L(MZ)                B=0. MAKE DEC MINUS ZERO.           F2C05680
TE50   ORA     $TAG                 PUT FORTAG IN ADDRESS.              F2C05690
TE60   STO     $E3                  STORE IN E3.                        F2C05700
       CAL     TRASTO               GET TRASTO KEY WORD.                F2C05710
       LXD     L(2),2               INDICATE TINFOR SEARCH NOT REQUIRED F2C05720
       LXD     SKIP,4                                                   F2C05730
       TXH     TE80,4,0             IF  SKIP IS 1 (DELTA GREATER THEN B)F2C05740
       TSX     SP000,4              GO TO SP.                           F2C05750
TE70   TXL     TE90,,0              (DEC SAVES TSX LINK)                F2C05760
TE80   TSX     $LIST,4              GO TO LIST IF SKIP IS ZERO.         F2C05770
TE90   LXD     TE70,4               RETURN FROM LIST.                   F2C05780
       TRA     1,4                  RETURN TO CALLER.                   F2C05790
       REM SUBROUTINE SP000 (IDENTICAL TO SPC000 IN BLOCK 2,            F2C05800
       REM EXCEPT FOR TABLE DEFINITIONS).                               F2C05810
SP000  SXD     SP115,1                                                  F2C05820
       SXD     SP060,2                                                  F2C05830
       SXD     SP105,4                                                  F2C05840
       STO     SPKEY                                                    F2C05850
       CLA     DOTGZ+5,1                                                F2C05860
       STD     SP050                                                    F2C05870
       CLA     DOTGZ,1                                                  F2C05880
       PAX     0,2                                                      F2C05890
       ANA     DECMSK                                                   F2C05900
       STO     $NEXTA                                                   F2C05910
       STO     $A                                                       F2C05920
       PXD     0,2                                                      F2C05930
       STO     $LASTB                                                   F2C05940
SP010  LXD     SP115,1                                                  F2C05950
SP020  TXI     SP040,1,-9                                               F2C05960
SP040  TXL     SP110,1,0                                                F2C05970
       CLA     DOTGZ+5,1                                                F2C05980
       PDX     0,2                                                      F2C05990
SP050  TXL     SP110,2,0                                                F2C06000
       CLA     DOTGZ+1,1                                                F2C06010
       SUB     $RSYM1                                                   F2C06020
       TZE     SP053                                                    F2C06030
       CLA     DOTGZ+1,1                                                F2C06040
       SUB     $RSYM2                                                   F2C06050
       TNZ     SP020                                                    F2C06060
SP053  CLA     DOTGZ,1                                                  F2C06070
       PAX     0,2                                                      F2C06080
       ANA     DECMSK                                                   F2C06090
       STO     $B                                                       F2C06100
       PXD     0,2                                                      F2C06110
       STO     $NEXTA                                                   F2C06120
       SXD     SP115,1                                                  F2C06130
SP055  LXD     SP060,2                                                  F2C06140
SP058  CLA     $A                                                       F2C06150
       SUB     $B                                                       F2C06160
       TZE     SP065                                                    F2C06170
       TXL     SPTIN,2,1                                                F2C06180
SP060  TXL     SPSTO,,0                                                 F2C06190
SP065  LXD     SP060,2                                                  F2C06200
       TXL     SP120,2,0                                                F2C06210
SP070  LXD     SP115,1                                                  F2C06220
       CLA     DOTGZ+5,1                                                F2C06230
       STD     SP100                                                    F2C06240
SP080  TXI     SP090,1,-9                                               F2C06250
SP090  TXL     SP110,1,0                                                F2C06260
       CLA     DOTGZ+5,1                                                F2C06270
       PDX     0,2                                                      F2C06280
SP100  TXH     SP080,2,0                                                F2C06290
       CLA     $NEXTA                                                   F2C06300
       STO     $A                                                       F2C06310
SP105  TXL     SP050,,0                                                 F2C06320
SP110  CLA     $NEXTA                                                   F2C06330
       STO     $A                                                       F2C06340
       CLA     $LASTB                                                   F2C06350
       STO     $B                                                       F2C06360
       LXD     SP060,2                                                  F2C06370
       CLA     L(0)                                                     F2C06380
       STD     SP060                                                    F2C06390
SP115  TXL     SP058,,0             STORAGE FOR TABLE KEY.              F2C06400
SP120  LXD     SP105,4                                                  F2C06410
       TRA     1,4                                                      F2C06420
SP130  LXD     SP105,4                                                  F2C06430
       TRA     2,4                                                      F2C06440
SPTIN  TSX     TINFX,4                                                  F2C06450
       TRA     SP130                                                    F2C06460
       TRA     SP065                                                    F2C06470
SPSTO  CLA     $B                                                       F2C06480
       ARS     18                                                       F2C06490
       ADD     $A                                                       F2C06500
       STO     $E1                                                      F2C06510
       CLA     SPKEY                                                    F2C06520
       TSX     $LIST,4                                                  F2C06530
       TRA     SP065                                                    F2C06540
SPKEY  PZE                                                              F2C06550
       REM SUBROUTINES TINFR AND TINFX (IDENTICAL TO TINFOR AND         F2C06560
       REM TINFXX IN BLOCK 2, EXCEPT FOR TABLE DEFINITIONS).            F2C06570
TINFR  CLA     DOTGZ,1                                                  F2C06580
       PAX     0,1                                                      F2C06590
       ANA     DECMSK                                                   F2C06600
       STO     $A                                                       F2C06610
       PXD     0,1                                                      F2C06620
       STO     $B                                                       F2C06630
TINFX  LXD     MAXFTG,1                                                 F2C06640
TINF1  CLA     FORTZ,1                                                  F2C06650
       ANA     DECMSK                                                   F2C06660
       CAS     $A                                                       F2C06670
       TRA     TINF4                                                    F2C06680
       NOP                                                              F2C06690
TINF2  TXI     TINF3,1,-1                                               F2C06700
TINF3  TXH     TINF1,1,0                                                F2C06710
       TRA     2,4                                                      F2C06720
TINF4  CAS     $B                                                       F2C06730
       TRA     2,4                                                      F2C06740
       NOP                                                              F2C06750
       CLA     FORTZ,1                                                  F2C06760
       TPL     TINF2                                                    F2C06770
       ANA     ADDMSK                                                   F2C06780
       SUB     $TAG                                                     F2C06790
       TNZ     TINF2                                                    F2C06800
       TRA     1,4                                                      F2C06810
       REM SUBROUTINE TRAWRD                                            F2C06820
TRAWRD SXD     TRAW65,4                                                 F2C06830
       CLA     L(0)                                                     F2C06840
       STO     TRABIT               INITIALIZE.                         F2C06850
       CLA     DOTGZ+5,1            LEVEL OF DOTAG                      F2C06860
       STD     TRAW30                                                   F2C06870
TRAW10 CAL     DOTGZ+7,1            GET T2 WORD.                        F2C06880
       ORS     TRABIT               OR INTO TRABIT                      F2C06890
       TXI     TRAW20,1,-9          TAKE NEXT DO                        F2C06900
TRAW20 TXL     TRAW70,1,0           IF NONE, EXIT (DEC IS DOTAG IX)     F2C06910
       CLA     DOTGZ+5,1            GET L WORD.                         F2C06920
       PDX     0,4                  PUT L IN XRC.                       F2C06930
TRAW30 TXL     TRAW70,4,0           EXIT IF DO IS NOT IN RANGE R1.      F2C06940
       REM                          (DEC HAS LEVEL DO).                 F2C06950
       TXL     TRAW10,2,1           IF COMPLETE TEST, NO TRWRD SKIP.    F2C06960
TRAW35 CLA     DOTGZ+1,1            IF INCOMPLETE TEST, IS THIS A       F2C06970
       SUB     $RSYM2               DO TO BE SKIPPED.                   F2C06980
       TZE     TRAW38               IF SO, GO TO TRAW38                 F2C06990
       CLA     DOTGZ+1,1            TEST RSYM3.                         F2C07000
       SUB     $RSYM3               IF NO SKIP                          F2C07010
       TNZ     TRAW10               GO BACK.                            F2C07020
TRAW38 CLA     DOTGZ+5,1            THIS DO IS TO BE SKIPPED.           F2C07030
       STD     TRAW60               PUT LEVEL OF THIS DO IN TEST INSTR. F2C07040
TRAW40 TXI     TRAW50,1,-9          TAKE NEXT DO IF ANY                 F2C07050
TRAW50 TXL     TRAW70,1,0           IF NOT, EXIT. IF SO,(DEC IS DO IX)  F2C07060
       CLA     DOTGZ+5,1            GET L WORD                          F2C07070
       PDX     0,4                  PUT L IN XRC                        F2C07080
TRAW60 TXH     TRAW40,4,0           IF DO IS IN RANGE R2, GO BACK.      F2C07090
TRAW65 TXL     TRAW30,,0            OTHERWISE, GO TO TRAW30.            F2C07100
TRAW70 LXD     TRAW65,4                                                 F2C07110
       CLA     L(36)                OBTAIN 36 IN DECREMENT              F2C07120
       SUB     TL2                  36-TL2 (LEVEL OF DOTAG)             F2C07130
       ARS     18                   IN ADDRESS                          F2C07140
       STA     TRAW90               INITIALIZE SHIFT                    F2C07150
       CLA     TL2                  OBTAIN TL2                          F2C07160
       ARS     18                   IN ADDRESS                          F2C07170
       STA     TRAW80               INITIALIZE SHIFT                    F2C07180
       CLA     L(0)                 ACC CONTAINS ZERO                   F2C07190
       LDQ     35ONES               MQ CONTAINS ALL ONES                F2C07200
TRAW80 LLS     **                   PUT TL2 ONES IN AC (LEV DOTAG)      F2C07210
TRAW90 ALS     **                   POSITION ONES IN AC.                F2C07220
       ANA     TRABIT               AND IN TRANSFER BITS                F2C07230
       TRA     1,4                  GO BACK TO CALLING INSTR PLUS ONE.  F2C07240
       REM SET UP TSXCOM                                                F2C07250
RDTSX  CLA     $LADDS+2             COMPUTE NR WDS IN TSXCOM.           F2C07260
       SUB     TCOMAD               TABLE AND                           F2C07270
       ALS     18                                                       F2C07280
       STO     TSCMWC               STORE WORD COUNT.                   F2C07290
       TZE     IRVSRT               IF IT IS EMPTY, EXIT.               F2C07300
       SSM                          IF NOT EMPTY,                       F2C07310
       ADD     TCOMAX               COMPUTE NR OF UNFILLED TSXCOM       F2C07320
       STO     TCOMWC               SPACES AND SAVE IT AS AN IX VALUE,  F2C07330
       REM               AND GO TO SORT TSXCOM.                         F2C07340
       REM SORT TSXCOM                                                  F2C07350
SORT   MSE     LIGHT                TURN OFF LIGHT                      F2C07360
       NOP                                                              F2C07370
       LXD     TCOMWC,1             INITIALIZE                          F2C07380
       TXI     SORT10,1,2                                               F2C07390
SORT10 TXH     MAKIRV,1,1000*M/N*2-2                                    F2C07400
       SXD     SORT80,1             INITIALIZE                          F2C07410
SORT20 LXD     TCOMAX,1                                                 F2C07420
SORT30 CLA     TCOMZ,1              GET 1ST WD, 1ST ENTRY TSXCOM(ALPHA).F2C07430
       CAS     TCOMZ+2,1            COMPARE IT AGAINST SECOND ENTRY.    F2C07440
       TRA     SORT50               OUT OF ORDER, REARRANGE ENTRY.      F2C07450
       TRA     SORT40               IN ORDER BY 1ST WDS, CHECK 2ND WDS. F2C07460
       TRA     SORT70               ENTRIES IN ORDER, IGNORE.           F2C07470
SORT40 CLA     TCOMZ+1,1            ALRIGHT- FIRST WORDS IN ORDER BUT   F2C07480
       CAS     TCOMZ+3,1            HOW DO THEIR 2ND WORDS COMPARE.     F2C07490
       TRA     SORT60               IF OUT OF ORDER, GO TO REARRANGE.   F2C07500
       TRA     SORT70               IF EQUAL OR                         F2C07510
       TRA     SORT70               IF IN ORDER, IGNORE.                F2C07520
SORT50 CLA     TCOMZ,1              1ST ENTRY GREATER, OUT OF ORDER.    F2C07530
       LDQ     TCOMZ+2,1            INTERCHANGE THE FIRST WORDS         F2C07540
       STO     TCOMZ+2,1            OF THE                              F2C07550
       STQ     TCOMZ,1              TWO ENTRIES.                        F2C07560
SORT60 CLA     TCOMZ+1,1            INTERCHANGE                         F2C07570
       LDQ     TCOMZ+3,1            THE                                 F2C07580
       STO     TCOMZ+3,1            SECOND WORDS                        F2C07590
       STQ     TCOMZ+1,1            OF THE ENTRIES.                     F2C07600
       PSE     LIGHT                INDICATE ENTRY OUT OF ORDER.        F2C07610
SORT70 TXI     SORT80,1,-2          BUMP FOR NEXT COMPARISON            F2C07620
SORT80 TXH     SORT30,1,0           IS PASS COMPLETE.                   F2C07630
       REM                          (DEC HAS UNUSED TSXCOM BUFF+3).     F2C07640
       MSE     LIGHT                YES, WAS AN ENTRY OUT OF ORDER.     F2C07650
       TRA     REMOVE               NO. GO TO MAKIRV.                   F2C07660
       LXD     SORT80,1             YES. NUMBER OF COMPARISONS          F2C07670
       TXI     SORT90,1,2           MADE IS DECREASED BY ONE            F2C07680
SORT90 SXD     SORT80,1             ON EACH PASS.                       F2C07690
       TRA     SORT20                                                   F2C07700
       REM BUILD UP TABLE IRV FROM TSXCOM                               F2C07710
MAKIRV LXD     IRVXX,2              (IX VALUE FOR NEXT IRV ENTRY)       F2C07720
       LXD     TCOMWC,1                                                 F2C07730
       SXD     MAK50,1                                                  F2C07740
       LXD     TCOMAX,1                                                 F2C07750
MAK10  CAL     TCOMZ+1,1            GET SECOND WORD OF TSXCOM.          F2C07760
       ANA     PREMSK               PULL OUT PREFIX.                    F2C07770
       TNZ     MAK40                IS ANYTHING THERE.                  F2C07780
       CLA     TCOMZ+1,1                                                F2C07790
       TXH     MAK20,2,0                                                F2C07800
       TSX     ERROR9,4             IRV TABLE IS FULL.                  F2C07810
MAK20  STO     IRVZ,2               STORE IRV.                          F2C07820
       TXI     MAK40,2,-1                                               F2C07830
MAK40  TXI     MAK50,1,-2                                               F2C07840
MAK50  TXH     MAK10,1,0            IS TSXCOM ENDED. (DEC IS UNUSED IX) F2C07850
MAK60  SXD     IRVXX,2              YES. SAVE INDICATION OF SIZE OF IRV.F2C07860
       REM SORT TABLE IRV.                                              F2C07870
IRVSRT LXD     IRVXX,1                                                  F2C07880
       TXI     IRVS10,1,1                                               F2C07890
IRVS10 TXH     END,1,600*M/N-1      IS THERE ONLY ONE ENTRY IN IRV.     F2C07900
       SXD     IRVS50,1                                                 F2C07910
       MSE     LIGHT                TURN OFF LITE.                      F2C07920
       NOP                                                              F2C07930
IRVS20 LXD     IRVMAX,1             INITIALIZE                          F2C07940
IRVS30 CLA     IRVZ,1               GET FIRST IRV ENTRY AND             F2C07950
       CAS     IRVZ+1,1             COMPARE AGAINST ITS NEIGHBOR.       F2C07960
       TRA     IRVS60               OUT OF ORDER. GO TO REARRANGE.      F2C07970
       NOP                                                              F2C07980
IRVS40 TXI     IRVS50,1,-1          BUMP FOR NEXT COMPARISON            F2C07990
IRVS50 TXH     IRVS30,1,0           IS PASS COMPLETE (DEC IS IRV IX)    F2C08000
       MSE     LIGHT                YES . WAS OUT OF ORDER NABBED.      F2C08010
       TRA     DELETE               NO. SORT COMPLETE.                  F2C08020
       TRA     IRVS20               YES. MAKE ANOTHER PASS.             F2C08030
IRVS60 LDQ     IRVZ+1,1             REARRANGE                           F2C08040
       STO     IRVZ+1,1             THE OUT OF ORDER                    F2C08050
       STQ     IRVZ,1               IRV ENTRIES AND                     F2C08060
       PSE     LIGHT                INDICATE SAME.                      F2C08070
       TRA     IRVS40                                                   F2C08080
       REM DELETE DUPE ENTRIES FROM TABLE IRV                           F2C08090
DELETE LXD     IRVXX,1                                                  F2C08100
       SXD     DEL30,1              INITIALIZE                          F2C08110
       LXD     IRVMAX,3             INIT STANDARD AND CANDIDATE XRS.    F2C08120
       TIX     DEL10,2,1            BUMP CANDIDATE IR.                  F2C08130
DEL10  CLA     IRVZ,2               GET CANDIDATE.                      F2C08140
       CAS     IRVZ,1               COMPARE AGAINST STANDARD.           F2C08150
       TRA     DEL40                CANDIDATE DOES NOT MATCH STANDARD.  F2C08160
       TRA     DEL20                CAND. MATCHES STANDARD.             F2C08170
       TSX     ERRORM,4             IRV ENTRIES ARE OUT OF ORDER        F2C08180
       REM                          OR MACHINE HAS FAILED IF XR2        F2C08190
       REM                          IRV IS LESS THAN XR1 IRV.           F2C08200
DEL20  TXI     DEL30,2,-1           BUMP FOR NEXT CANDIDATE.            F2C08210
DEL30  TXH     DEL10,2,0            IS IT END OF PASS(DEC IS IRV IX)    F2C08220
       TXI     DEL35,1,-1           YES. BUMP STANDARD IR.              F2C08230
DEL35  SXD     IRVXX,1              SAVE NEW IRV SIZE INDEX.            F2C08240
       TRA     END                  EXIT.                               F2C08250
DEL40  STO     IRVZ+1,1             NOT DUPE, PUT CANDIDATE BACK.       F2C08260
       TXI     DEL20,1,-1           AND INSTALL IT AS STANDARD.         F2C08270
END    CLA     IRVMAX               COMPUTE IRV                         F2C08280
       SUB     IRVXX                WD CT AND                           F2C08290
       STO     IRVWC                STORE IN WD PRECEDING TABLE (IN DEC)F2C08300
       CLA     $LADDS+1             COMPUTE TRASTO                      F2C08310
       SUB     TRSTAD               WD CT AND                           F2C08320
       STO     TRSTWC               STORE IN WD PRECEDING TABLE (IN ADD)F2C08330
       TRA     NORMRT                                                   F2C08340
ENDB   SYN     *+20                                                     F2C08350
LIGHT  EQU     100                  IF FORVAL EMPTY, LIGHT ON.          F2C08360
REMOVE SYN     MAKIRV                                                   F2C08370
       TCD     -1                                                      $F2C08375
       LBL     9F21,M                                                   F2C08380
       TTL     BLOCK D.                                                 F2C08390
*     SECTION TWO OF 709/7090 32K FORTRAN, BLOCK D.                     F2D00000
       HEAD    4                                                        F2D00010
       ORG     SYSCUR                                                  $F2D00020
       BCI     1,9F2100                                                $F2D00030
       ORG     (LODR)                                                  $F2D00040
       TXI     START,,210                                               F2D00060
M      SYN     1$M                  M/N IS THE RATIO OF TABLE SIZES     F2D00080
N      SYN     1$N                  TO NORMAL 32K SIZES.                F2D00090
       REM BLOCK 4                                                      F2D00100
       REM THIS PART COMPILES THE SUBROUTINES WHICH COMPUTE             F2D00110
       REM INDEX LOAD VALUES FOR PURE RELCONS.                          F2D00120
       REM THE LOAD VALUE FOR SUBSCRIPTS (C1I,C2J,C3K) IS               F2D00130
       REM (C1I-1)+(C2D1J-D1)+(C3D1D2K-D1D2)+1                          F2D00140
       REM TABLE IRV, PRODUCED BY BLOCK 3, GIVES A LIST OF THE          F2D00150
       REM SUBROUTINES REQUIRED.                                        F2D00160
       HEAD    0                                                        F2D00170
FIXCN  SYN     1$FIXCN                                                  F2D00180
FIXWC  SYN     FIXCN-1                                                  F2D00190
       REM           SUBROUTINES AND CELLS COMMON TO                    F2D00200
       REM           BLOCKS FOUR AND FIVE.                              F2D00210
       ORG     BITTWO+1                                                 F2D00220
L1DEC  OCT     1000000                                                  F2D00230
L(3)   OCT     3                                                        F2D00240
L(6)   OCT     6                                                        F2D00250
L(8)   OCT     10                                                       F2D00260
BCD2   OCT     020000000000                                             F2D00270
E2C    PZE                                                              F2D00280
E3C    PZE                                                              F2D00290
LINKC  PZE                                                              F2D00300
WRKSC  DUP     1,8                  EIGHT WRKSC WORDS.                  F2D00310
       PZE                                                              F2D00320
OR000  DUP     1,12                                                     F2D00330
       PZE                                                              F2D00340
OR012  OCT     010000000001                                             F2D00350
OR013  OCT     060000000003                                             F2D00360
OR014  DUP     1,4                                                      F2D00370
       PZE                                                              F2D00380
OR018  PZE                                                              F2D00390
OR019  DUP     1,7                                                      F2D00400
       PZE                                                              F2D00410
OR026  OCT     010000000003                                             F2D00420
OR027  PZE                                                              F2D00430
L(STO) BCI     1,STO000                                                 F2D00440
L(CLA) BCI     1,CLA000                                                 F2D00450
       REM COSE ROUTINE FORMS NAME OF EACH NONTRIVIAL COEFF. IN FIXCON  F2D00460
       REM TABLE, AND SETS SENSE LIGHTS ACCORDINGLY.                    F2D00470
COSE   LXA     L(6),1               INDEX TO SELECT SUBSCRIPTS IN TURN. F2D00480
       LXA     L(3),2               INITIALISE SENSE LT. SELECTION.     F2D00490
       SXD     LINKC,4                                                  F2D00500
COSE5  CLA     WRKSC+6,1            SELECT A S.C. COEFF.                F2D00510
       TZE     COSE08               TRA IF NO SUBSC. IN THIS DIMENSION. F2D00520
       SUB     L1DEC                                                    F2D00530
       TZE     COSE08               TRA IF COEFF. IS ONE.               F2D00540
       PSE     100,2                SET CORRESPONDING SENSE LIGHT.      F2D00550
       CLA     WRKSC+6,1            ENTER COEFF IN FIXCON IF            F2D00560
       TSX     FXCON,4              NOT ALREADY THERE.                  F2D00570
       STO     OR000+12,2           STORE NAME OF FIXCON ENTRY.         F2D00580
COSE08 TIX     COSE10,1,2                                               F2D00590
COSE10 TIX     COSE5,2,1            REPEAT FOR ALL SUBSCRIPTS.          F2D00600
       LXD     LINKC,4                                                  F2D00610
       TRA     1,4                  RETURN                              F2D00620
       REM *************************************************************F2D00630
       REM FIXCON SEARCHES THE FIXCN TABLE FOR THE PRESENCE OF          F2D00640
       REM A DESIRED FIXED POINT CONSTANT. IF THE DESIRED FIXCON        F2D00650
       REM IS NOT THERE AN ENTRY IS MADE. A SYMBOL IS                   F2D00660
       REM FORMED FOR THE CONSTANT AND LEFT IN THE ACCUMULATOR.         F2D00670
FXCON  SXD     E2C,1                SAVE INDEX REGISTERS.               F2D00680
       SXD     E3C,2                X                                   F2D00690
       LXA     FIXWC,1                                                 $F2D00700
       LXA     FIXWC,2                                                 $F2D00705
       TXI     *+1,2,FIXCN          AND COUNTER FOR                     F2D00710
       SXA     FC10,2               SCAN OF FIXCON.                     F2D00720
       SXA     FC13,2                                                   F2D00730
       AXT     1,2                  INITIALIZE ENTRY NO. COUNTER.       F2D00740
       TXL     FC13,1,0             TEST FOR EMPTY TABLE                F2D00750
FC10   CAS     0,1                  ADDRESS INITIALIZED.                F2D00760
       TXI     FC12,2,1                                                 F2D00770
       TXI     FC14,2,-1            ENTRY FOUND.                        F2D00780
       TXI     FC12,2,1                                                 F2D00790
FC12   TIX     FC10,1,1             ENTRY NOT FOUND, CONTINUE SCAN.     F2D00800
       TXH     FC16,2,LMXFIX        HAS TABLE OVERFLOWED                F2D00810
FC13   STO     **                                                       F2D00820
       SXA     FIXWC,2              UPDATE WORD COUNT.                  F2D00830
       TXI     *+1,2,-1                                                 F2D00840
FC14   PXA     0,2                  FORM FIXCON SYMBOL                  F2D00850
       ORA     BCD2                 IN ACCUMULATOR.                     F2D00860
       LXD     E2C,1                RESTORE INDEX REGISTERS             F2D00870
       LXD     E3C,2                AND                                 F2D00880
       TRA     1,4                  RETURN.                             F2D00890
FC16   TSX     ERRO10,4             FIXCON HAS OVERFLOWED.              F2D00900
       REM *************************************************************F2D00910
SUBCM  SXD     TAUREF,1             SAVE CALLERS INDEX                  F2D00920
       SXD     TAUREF+1,4           REGISTERS 1 AND 4.                  F2D00930
       LXA     L(8),4                                                   F2D00940
SUB010 STZ     WRKSC+8,4            INITIALIZE WRKSC                    F2D00950
       TIX     SUB010,4,1           TO ZEROES.                          F2D00960
       LRS     9                    ISOLATE TABLE NUMBER                F2D00970
       PAX     0,4                  (TAU 1,2 OR 3) IN IR4.              F2D00980
       CLM                                                              F2D00990
       LLS     9                                                        F2D01000
       ALS     1                    TWICE ENTRY NO. FOR TAU 1.          F2D01010
       TXL     SUB30,4,1            TRA IF TAU1.                        F2D01020
       ALS     1                    4 TIMES ENTRY NO. FOR TAU 2.        F2D01030
       TXL     SUB30,4,2            TRA IF TAU2.                        F2D01040
       STO     TAUERS                                                   F2D01050
       ARS     1                                                        F2D01060
       ADD     TAUERS               6 TIMES ENTRY NO. FOR TAU 3.        F2D01070
SUB30  PAC     0,1                  TABLE IX=ENTRY LENGTH X NO.         F2D01080
       CLA*    TAUREF+3,4                                               F2D01090
       STD     WRKSC                C1.                                 F2D01100
       TXL     SUB50,4,1                                                F2D01110
       ALS     18                                                       F2D01120
       STD     WRKSC+2              C2 (FOR TAU2 OR 3).                 F2D01130
       TXL     SUB50,4,2            TRA IF TAU2.                        F2D01140
SUB40  TXI     *+1,1,-1                                                 F2D01150
       CLA*    TAUREF+3,4                                               F2D01160
       STD     WRKSC+4              C3.                                 F2D01170
SUB50  TXI     *+1,1,-1                                                 F2D01180
       CLA*    TAUREF+3,4                                               F2D01190
       STO     WRKSC+1              S1.                                 F2D01200
       TXL     SUB060,4,1           TAU 1 FINISHED.                     F2D01210
       TXI     *+1,1,-1                                                 F2D01220
       CLA*    TAUREF+3,4                                               F2D01230
       STO     WRKSC+3              S2                                  F2D01240
       TXI     *+1,1,-1                                                 F2D01250
       CLA*    TAUREF+3,4                                               F2D01260
       STO     WRKSC+8,4            S3 IF TAU 3, D1 IF TAU 2.           F2D01270
       TXL     SUB060,4,2           TAU2 FINISHED.                      F2D01280
       TXI     *+1,1,-1                                                 F2D01290
       CLA*    TAUREF+3,4                                               F2D01300
       STD     WRKSC+6              D1 FOR TAU 3.                       F2D01310
       ALS     18                                                       F2D01320
       STD     WRKSC+7              D2.                                 F2D01330
SUB060 LXD     TAUREF,1             RESTORE CALLERS INDEX               F2D01340
       LXD     TAUREF+1,4           REGISTERS 1 AND 4.                  F2D01350
       TRA     1,4                                                      F2D01360
TAUERS PZE     **                                                       F2D01370
TAUREF PZE     TAU3,1,**            INDIRECT ADDRESSING                 F2D01380
       PZE     TAU2,1,**            REFERENCES TO                       F2D01390
       PZE     TAU1,1,**            TAU TABLES.                         F2D01400
       REM *************************************************************F2D01410
       HEAD    4                                                        F2D01420
A)BSZ  EQU     200                  SIZE OF CIT OUTPUT BUFFERS.         F2D01430
BOB    SYN     3$IRV                ADDITIONAL                          F2D01440
BOBWC  SYN     BOB-1                TABLE                               F2D01450
FIXCN  SYN     1$FIXCN              DEFINITIONS.                        F2D01460
FIXWC  SYN     FIXCN-1              FOR BLOCK 4.                        F2D01470
ADTAG  SYN     DMTGTB                                                   F2D01480
ADTGWC SYN     ADTAG-1                                                  F2D01490
A)B2   SYN     ADTGWC-A)BSZ                                             F2D01500
A)B1   SYN     A)B2-A)BSZ                                               F2D01510
       REM *************************************************************F2D01520
START  CLA     L(1)                 SAVE STATUS OF SENSE LIGHT 3.       F2D01530
       SLT     3                                                        F2D01540
       TRA     START0                                                   F2D01550
       STO     SENSE1                                                   F2D01560
*      ***                                                              F2D01570
START0 TSX     (TAPE),4             SKIP OVER FIRST                     F2D01580
       PZE     SKLST3,,(SKBP)       FILE OF                             F2D01590
       PZE     5$TAGL,,FTAPE4       TAGTAG TAPE.                        F2D01600
START1 LXD     BOBWC,1                                                  F2D01610
       TXL     FIN,1,0              EXIT IF NO ENTRIES IN IRV.          F2D01620
       AXT     0,2                                                      F2D01630
REPETE CLA     BOB,2                SELECT TABLE IRV ENTRY.             F2D01640
       STA     NAME1                PUT SUBCOM NAME IN NAME 1.          F2D01650
       ARS     18                   PUT TAU REFERENCE                   F2D01660
       STA     TAG1                 IN TAG1.                            F2D01670
ENTRY  SXD     BX,2                                                     F2D01680
       SXD     AX,1                                                     F2D01690
       TSX     $SUBCM,4             PICK UP TAU ENTRY.                  F2D01700
       TSX     COMPIL,4             COMPILE SUBROUTINE FRO COMPUTING    F2D01710
       LXD     BX,2                 LOAD VALUE.                         F2D01720
       LXD     AX,1                                                     F2D01730
       TXI     TEST,2,-1            STEP DOWN COUNT THROUGH TABLE IRV.  F2D01740
TEST   TNX     FINISH,1,1           END OF TABLE IRV.                   F2D01750
       TSX     LINKTR,4             COMPILE SUBROUTINE RETURN.          F2D01760
       TRA     REPETE                                                   F2D01770
EQUAL  TSX     STOTP,4                                                  F2D01780
       TRA     TEST-1                                                   F2D01790
FINISH TSX     LINKTR,4                                                 F2D01800
       TSX     CITSP,4              WRITE CIT BUFFER ON TAPE.           F2D01810
       TRA     FIN1                                                     F2D01820
*      ***                                                              F2D01830
FIN    TSX     (TAPE),4             WRITE FOUR                          F2D01840
       PZE     DSC2,,(WBNP)         ZERO WORDS FOR                      F2D01850
       PZE     A)FNL,,FTAPE3        EMPTY DOFILE C.                     F2D01860
*      ***                                                              F2D01870
FIN1   TSX     (TAPE),4             WRITE EOF                           F2D01880
       PZE     0,0,(WEFP)           AFTER                               F2D01890
       PZE     FILN8L,,FTAPE3       A) ROUTINES.                        F2D01900
       SLF                          TURN OFF ALL SENSE LIGHTS.          F2D01910
       CLA     SENSE1               RESTORE STATUS                      F2D01920
       TZE     *+2                  OF SENSE LIGHT 3.                   F2D01930
       SLN     3                                                        F2D01940
       TRA     5$AINIT                                                  F2D01950
DSC2   IORT    CIL00,,4                                                 F2D01960
A)FNL  BCI     1,A)FUNC                                                 F2D01970
SKLST3 PZE     0,,1                                                     F2D01980
FILN8L BCI     1,EOF1                                                   F2D01990
       REM *************************************************************F2D02000
COMPIL SXD     1XBOX,1                                                  F2D02010
       SXD     2XBOX,2                                                  F2D02020
       SXD     LINK1,4              SAVE LINKAGE                        F2D02030
       PSE     96                   TURN ALL SENSE LIGHTS OFF           F2D02040
       TSX     $COSE,4              GET NAME OF COEFF IN FIXCON.        F2D02050
       CLA     L(CLA)                                                   F2D02060
       STO     CIL01                THIS ROUTINE COMPILES               F2D02070
       CLA     OR000+13             THE INSTRUCTION                     F2D02080
       ANA     6ONES                                                    F2D02090
       STO     CIL02                CLA 6)+3,                           F2D02100
       CLA     $L(3)                WITH ZERO TAG,                      F2D02110
       ALS     18                                                       F2D02120
       STO     CIL03                TOGETHER WITH A SYMBOLIC            F2D02130
       CLA     NAME1                LOCATION OF                         F2D02140
       ORA     BCD10                                                    F2D02150
STOLOC STO     CIL00                10)+NAME1                           F2D02160
       TSX     CIT,4                ENTER INSTR. IN CIT                 F2D02170
       CLA     L(STO)                                                   F2D02180
       STO     CIL01                THIS ROUTINE COMPILES THE           F2D02190
       CLA     OR000+26             INSTRUCTION.                        F2D02200
       PAX     0,1                                                      F2D02210
       ANA     6ONES                STO 1)+3                            F2D02220
       SXD     CIL03,1              THESE COMPILED INSTR. PLACE         F2D02230
       STO     CIL02                1 IN ERASABLE STORAGE               F2D02240
       ZAC                                                              F2D02250
       STO     CIL00                                                    F2D02260
       TSX     CIT,4                ENTER INSTR. IN CIT                 F2D02270
       CLA     $WRKSC+1             TEST 1ST SSC SYMBOL.                F2D02280
       TZE     S2                   NO SYMBOL PRESENT                   F2D02290
       STO     OR000+1              SAVE S1 FOR LXC ROUTINE             F2D02300
       LXA     L(4),1               INDEX FOR NO. OF COMPILED INSTR.    F2D02310
       MSE     97                   DOES 1ST COEFF EXCEED 1             F2D02320
       TRA     COMP20               NO                                  F2D02330
       TXI     COMP30,1,2           YES. 6 INSTR. TO BE COMPILED        F2D02340
COMP20 CLA     KLX02                NO. COMPILE INSTR TO COMPUTE        F2D02350
       TRA     COMP30+1             S1-1+(1 ALREADY IN ERASABLE)        F2D02360
COMP30 CLA     KLX021               YES. COMPILE C1A1-1                 F2D02370
       TSX     LXC,4                +(1 AREADY IN ERASABLE)             F2D02380
S2     CLA     $WRKSC+3                                                 F2D02390
       TZE     S3                   TRA IF NO 2ND SUBSC. SYMBOL         F2D02400
       STO     OR000+4              SAVE S2 FOR LXC ROUTINE.            F2D02410
       CLA     $WRKSC+6             GET SYMBOLIC ADDRESS                F2D02420
       TSX     $FXCON,4             OF D1 IN FIXCON TABLE               F2D02430
       STO     OR000+7              AND STORE FOR LXC ROUTINE.          F2D02440
       LXA     $L(6),1              6 INSTR. TO BE COMPILED.            F2D02450
       MSE     98                   IS COEFF. C2 GREATER THAN 1.        F2D02460
       TRA     COMP40               NO. COMPILE D1*S2-D1+               F2D02470
       CLA     KLX03                YES. 8 INSTR. COMPILED TO           F2D02480
       TXI     COMP40+1,1,2         COMPUTE D1*S2*C3-D1+                F2D02490
COMP40 CLA     KLX031                                                   F2D02500
       TSX     LXC,4                + THAT ALREADY COMPUTED.            F2D02510
S3     CLA     $WRKSC+5             TEST FOR 3RD SUBSCRIPT              F2D02520
       TZE     COMP55               SYMBOL.                             F2D02530
       STO     OR000+21             STORE FOR LXC ROUTINE.              F2D02540
       LDQ     $WRKSC+6             COMPUTE D1*D2,                      F2D02550
       MPY     $WRKSC+7             AND OBTAIN                          F2D02560
       ALS     17                   NAME FOR THIS CONSTANT FROM         F2D02570
       TSX     $FXCON,4             FIXCON, AND STORE FOR               F2D02580
       STO     OR000+24             LXC ROUTINE.                        F2D02590
       LXA     $L(6),1              6 INSTR. TO BE COMPILED.            F2D02600
       MSE     99                   IS 3RD COEFF GREATER THAN 1.        F2D02610
       TRA     COMP50               NO. COMPILE D1D2*S3-D1D2+           F2D02620
       CLA     KLX05                YES, COMPILE D1D2*C3S3-D1D2+        F2D02630
       TXI     COMP50+1,1,2                                             F2D02640
COMP50 CLA     KLX051                                                   F2D02650
       TSX     LXC,4                + THAT ALREADY COMPUTED.            F2D02660
COMP55 LXD     BBOX,4                                                   F2D02670
       TXI     COMP55+2,4,4         STEP UP CIT BUFFER COUNT            F2D02680
       SXD     BBOX,4                                                   F2D02690
       TSX     STOTP,4              COMPILE INSTRUCTION TO STORE        F2D02700
       LXD     1XBOX,1              LOADING VALUE FOR SUBSCRIPT COMB.   F2D02710
       LXD     1XBOX,2                                                  F2D02720
       LXD     LINK1,4                                                  F2D02730
       TRA     1,4                  RETURN                              F2D02740
       REM *************************************************************F2D02750
STOTP  SXD     LINK2,4              ROUTINE COMPILES THE INSTR.         F2D02760
       CLA     L(0)                 TO STORE THE RESULTS OF             F2D02770
       STO     CIL00                THE SUBROUTINE COMPILATION IN       F2D02780
       STO     CIL03                THE TAG NAME.                       F2D02790
       CLA     L(STO)               THIS INSTRUCTION IS                 F2D02800
       STO     CIL01                                                    F2D02810
       CLA     NAME1                STO 12)+ NAME1                      F2D02820
       ORA     BCD14                                                    F2D02830
       STO     CIL02                                                    F2D02840
       TSX     CIT,4                ENTER IN CIT TABLE                  F2D02850
       LXD     LINK2,4                                                  F2D02860
       TRA     1,4                  RETURN                              F2D02870
       REM *************************************************************F2D02880
LINKTR CLA     L(0)                                                     F2D02890
       STO     CIL00                THIS ROUTINE COMPILES               F2D02900
       STO     CIL02                INSTRUCTION FOR RETURN              F2D02910
       CLA     L(TRA)               TO THE FORTRAN MASTER               F2D02920
       STO     CIL01                ROUTINE.                            F2D02930
       CLA     RELTG                TRA1,4                              F2D02940
       STO     CIL03                                                    F2D02950
       SXD     LINK1,4                                                  F2D02960
       TSX     CIT,4                FENTER IN CIT TABLE.                F2D02970
       LXD     LINK1,4                                                  F2D02980
       TRA     1,4                  RETURN                              F2D02990
L(TRA) BCI     1,TRA000                                                 F2D03000
RELTG  OCT     000001000004                                             F2D03010
       REM *************************************************************F2D03020
       REM ROUTINE COMPILES SETS OF INSTRUCTIONS, GIVEN STARTING LOCN.  F2D03030
       REM OF APPROPRIATE SKELETON IN ACC., AND NO. OF INSTR. IN IRA    F2D03040
LXC    SXD     LXC19,4                                                  F2D03050
       STO     ERLXC                SAVE LOCATION OF INSTR. SKELETON.   F2D03060
       PXD     0,1                  NO. OF INST TO BE COMPILED.         F2D03070
       ARS     18                                                       F2D03080
       ADD     ERLXC                FORM ADDRESS WHICH GIVES            F2D03090
       STA     LXC10                APPROPRIATE SKELETAL WORDS.         F2D03100
LXC08  CLA     L(0)                 SET CIT SYMBOLIC LOCN. TO ZERO      F2D03110
       STO     CIL00                                                    F2D03120
LXC10  LDQ     0,1                  SELECT NEXT SKELETAL WORD.          F2D03130
       LLS     0                    FOR COMPILATION. SET SIGN IN AC.    F2D03140
       LGL     18                   BCD. OPERATION IS IN DECREMENT.     F2D03150
       STQ     CIL01                STORE OPERATION                     F2D03160
       TMI     LXC20                CIT IS SHIFT TYPE INSTRUCTION.      F2D03170
       STA     LXC15                CIT IS SYMBOLIC ADDRESS TYPE.       F2D03180
LXC15  CLA     **                   ADD IS LOC OF SYMBOL ADDRESS.       F2D03190
       STO     CIL02                OF CIT.                             F2D03200
       CLA     L(0)                                                     F2D03210
       STO     CIL03                SET CIT TAG TO ZERO.                F2D03220
       CAL     CIL02                TEST FOR A COT                      F2D03230
       ANA     6ONES                SYMBOLIC ADDRESS OF THE TYPE        F2D03240
       TZE     LXC30                1)+3 OR6)+2 ERASABLE                F2D03250
       ANA     BIT01                STORAGE                             F2D03260
       TNZ     LXC30                NO                                  F2D03270
       CAL     CIL02                YES. SEPARATE ADDRESS LEAVING THE   F2D03280
       ALS     18                   CLASS OF SYMBOLS IN SYMBOLIC        F2D03290
       STD     CIL03                ADDRESS POSN. ALONE, AND            F2D03300
       CAL     6ONES                PLACING ADDEND IN REL. ADDRESS      F2D03310
       ANS     CIL02                POSITION.                           F2D03320
LXC19  TXL     LXC30,,0             UNCOND. TRANSFER LINKAGE IN DEC)    F2D03330
LXC20  ALS     18                   CIT IS SHIFT TYPE INSTRUCTION       F2D03340
       ANA     DECMSK               I.E. ABSOLUTE ADDRESS ONLY.         F2D03350
       STO     CIL03                STORE ADDRESS IN CIT REL. ADDRESS.  F2D03360
       CLA     L(0)                 STORE ZERO AS                       F2D03370
       STO     CIL02                SYMBOLIC ADDRESS.                   F2D03380
LXC30  TSX     CIT,4                MAKE CIT ENTRY.                     F2D03390
       TIX     LXC08,1,1            RETURN FOR NEXT SKELETON INST.      F2D03400
       LXD     LXC19,4              SKELETON COMPLETED.                 F2D03410
       TRA     1,4                  RETURN.                             F2D03420
LX100  PZE     14545,2,OR000+13     CLA. THESE WORDS                    F2D03430
       PZE     11494,6,OR000+26     STO. CONSTITUTE THE                 F2D03440
LX102  PZE     14545,2,OR000+1      CLA. CODING                         F2D03450
       PZE     11538,6,OR000+13     SUB. SKELETONS,                     F2D03460
       PZE     5396,2,OR000+26      ADD. AND ARE                        F2D03470
       PZE     11494,6,OR000+26     STO. CALLED UPON                    F2D03480
LX105  PZE     13608,4,OR000+1      LDQ. BY THE LXC                     F2D03490
       PZE     18936,4,OR000+9      MPY. ACCORDING                      F2D03500
       TNX     6386,2,17            ALS. TO THE                         F2D03510
       PZE     11538,6,OR000+13     SUB. DIFFERENT                      F2D03520
       PZE     5396,2,OR000+26      ADD. COMPUTATIONS                   F2D03530
       PZE     11494,6,OR000+26     STO. REQUIRED                       F2D03540
LX110  PZE     13608,4,OR000+4      LDQ.                                F2D03550
       PZE     18936,4,OR000+7      MPY. THE TAG AND                    F2D03560
       TNX     6386,2,17            ALS. ADDRESS ARE                    F2D03570
       PZE     11538,6,OR000+7      SUB. THE BCD                        F2D03580
       PZE     5396,2,OR000+26      ADD. EQUIVALENTS OF                 F2D03590
       PZE     11494,6,OR000+26     STO. THE CIT                        F2D03600
LX116  PZE     13608,4,OR000+4      LDQ. INSTRUCTIONS.                  F2D03610
       PZE     18936,4,OR000+10     MPY. THE SYMBOLIC                   F2D03620
       TNX     14962,4,18           LRS. DECREMENTS ARE                 F2D03630
       PZE     18936,4,OR000+7      MPY. THE LOCATIONS                  F2D03640
       TNX     6386,2,17            ALS. OF THE                         F2D03650
       PZE     11538,6,OR000+7      SUB. ADDRESSES IN                   F2D03660
       PZE     5396,2,OR000+26      ADD. THE CIT                        F2D03670
       PZE     11494,6,OR000+26     STO.                                F2D03680
LX124  PZE     13608,4,OR000+21     LDQ. THE NEGATIVE                   F2D03690
       PZE     18936,4,OR000+24     MPY. PREFIX INDICATES               F2D03700
       TNX     6386,2,17            ALS. A PURELY                       F2D03710
       PZE     11538,6,OR000+24     SUB. ABSOLUTE ADDRESSES             F2D03720
       PZE     5396,2,OR000+26      ADD.                                F2D03730
       PZE     11494,6,OR000+26     STO.                                F2D03740
LX130  PZE     13608,4,OR000+21     LDQ.                                F2D03750
       PZE     18936,4,OR000+11     MPY.                                F2D03760
       TNX     14962,4,18           LRS.                                F2D03770
       PZE     18936,4,OR000+24     MPY.                                F2D03780
       TNX     6386,2,17            ALS.                                F2D03790
       PZE     11538,6,OR000+24     SUB.                                F2D03800
       PZE     5396,2,OR000+26      ADD.                                F2D03810
       PZE     11494,6,OR000+26     STO.                                F2D03820
       REM *************************************************************F2D03830
       REM *************************************************************F2D03840
       REM CIT WRITES THE COMPILED INSTRUCTION                          F2D03850
       REM BUFFER ON TAPE, WHEN FULL, AND ENTERS                        F2D03860
       REM A NEW CIT INTO THE BUFFER.                                   F2D03870
CIT    SXD     $E2C,2                                                   F2D03880
       SXD     $E3C,4                                                   F2D03890
       LXD     BBOX,2                                                   F2D03900
       TXL     *+2,2,0              TEST FOR FULL BUFFER.               F2D03910
       TXL     CIT06,2,-A)BSZ                                           F2D03920
CIT01  AXT     4,4                                                      F2D03930
CIT02  CLA     CIL00+4,4            MOVE CIT TO OUTPUT                  F2D03940
CIT03  STO     A)B1,2               BUFFER.                             F2D03950
       TXI     *+1,2,-1                                                 F2D03960
       TIX     CIT02,4,1                                                F2D03970
       SXD     BBOX,2                                                   F2D03980
CIT04  LXD     $E2C,2               NOT FULL,                           F2D03990
CIT05  LXD     $E3C,4               RETURN.                             F2D04000
       TRA     1,4                                                      F2D04010
CIT06  AXC     -1,2                                                     F2D04020
*      ***                                                              F2D04030
CIT07  TSX     (TAPE),4             WRITE ONE RECORD                    F2D04040
       PZE     A)B2A,2,(WBNP)       OF A) CITS.                         F2D04050
       PZE     A)FNL,,FTAPE3                                            F2D04060
       CLA     DSC5,2               CHANGE OUTPUT                       F2D04070
       STA     CIT03                BUFFER ADDRESS.                     F2D04080
       SXA     CIT06,2              REVERSE SWITCH.                     F2D04090
       STZ     BBOX                 RESET WORD COUNT.                   F2D04100
       ZET     *+1                  IS THIS LAST RECORD.                F2D04110
CIT08  TRA     CIT01-3              NO, GO BACK TO MAKE AN ENTRY.       F2D04120
       TRA     CIT05                YES, RETURN.                        F2D04130
CITSP  SXD     $E3C,4                                                   F2D04140
       LDC     BBOX,4               IS LAST                             F2D04150
       TXL     CIT05,4,0            BUFFER EMPTY.                       F2D04160
       LAC     CIT06,2              NO, COMPUTE WORD COUNT              F2D04170
       PXD     ,4                   AND STORE IN                        F2D04180
       STD     A)B2A,2              CURRENT I/O COMMAND.                F2D04190
       STZ     CIT08                SET LAST-TIME SWITCH.               F2D04200
       TRA     CIT07                                                    F2D04210
DSC4   IORT    A)B1,,A)BSZ                                              F2D04220
A)B2A  PZE     A)B2                                                     F2D04230
DSC5   IORT    A)B2,,A)BSZ                                              F2D04240
A)B1A  PZE     A)B1                                                     F2D04250
BBOX   PZE                                                              F2D04260
CIL00  PZE                                                              F2D04270
CIL01  PZE                                                              F2D04280
CIL02  PZE                                                              F2D04290
CIL03  PZE                                                              F2D04300
       REM *************************************************************F2D04310
NAME1  PZE                                                              F2D04320
TAG1   PZE                                                              F2D04330
TAG2   PZE                                                              F2D04340
RECCNT PZE                                                              F2D04350
1XBOX  PZE                                                              F2D04360
2XBOX  PZE                                                              F2D04370
LINK1  PZE                                                              F2D04380
LINK2  PZE                                                              F2D04390
ERDRM  PZE                                                              F2D04400
ERLXC  PZE                                                              F2D04410
AX     PZE                                                              F2D04420
BX     PZE                                                              F2D04430
SENSE1 PZE                                                              F2D04440
BCD14  OCT     140000000000                                             F2D04450
BCD10  OCT     120000000000                                             F2D04460
6ONES  OCT     770000000000                                             F2D04470
BIT01  OCT     600000000000                                             F2D04480
L(0)   HTR     0                                                        F2D04490
L(1)   HTR     1                                                        F2D04500
L(4)   HTR     4                                                        F2D04510
KLX02  HTR     LX102                SKELETON KEYS                       F2D04520
KLX021 HTR     LX105                FOR LXC ROUTINE.                    F2D04530
KLX03  HTR     LX116                                                    F2D04540
KLX031 HTR     LX110                                                    F2D04550
KLX05  HTR     LX130                                                    F2D04560
KLX051 HTR     LX124                                                    F2D04570
       REM *************************************************************F2D04580
LADTG  EQU     3+400*M/N*4                                              F2D04590
LMXFIX EQU     1200*M/N                                                 F2D04600
OR000  SYN     $OR000                                                   F2D04610
OR012  SYN     OR000+12                                                 F2D04620
OR013  SYN     OR000+13                                                 F2D04630
OR018  SYN     OR000+18                                                 F2D04640
OR026  SYN     OR000+26                                                 F2D04650
       REM *************************************************************F2D04660
       TTL     BLOCK E.                                                 F2D04670
*     SECTION TWO OF 709/7090 32K FORTRAN, BLOCK E.                     F2E00000
       HEAD    5                                                        F2E00010
M      SYN     1$M                  M/N IS THE RATIO OF TABLE SIZES     F2E00020
N      SYN     1$N                  TO NORMAL 32K SIZES.                F2E00030
       REM  COMPILES DO LOOP INDEXING INSTRUCTIONS.                     F2E00040
       REM  INITIALIZATION                                              F2E00050
CIBSZ  EQU     200                  SIZE OF CIT OUTPUT BUFFERS.         F2E00060
DOCARZ SYN     ENDCOR                                                   F2E00070
DOCARE SYN     DOCARZ-400*M/N       ADDITIONAL TABLE                    F2E00080
CARWC  SYN     DOCARE-1             DEFINITIONS FOR                     F2E00090
SXTXZ  SYN     TSCMWC                                                   F2E00100
SXTX   SYN     SXTXZ-600*M/N*2      BLOCK 5.                            F2E00110
SXDWC  SYN     SXTX-1                                                   F2E00120
FIXCN  SYN     4$FIXCN                                                  F2E00130
FIXWC  SYN     FIXCN-1                                                  F2E00140
TAU3   SYN     1$TAU3                                                   F2E00150
TAU2   SYN     1$TAU2                                                   F2E00160
TAU1   SYN     1$TAU1                                                   F2E00170
ADTAG  SYN     4$ADTAG                                                  F2E00180
ADTGA  SYN     ADTAG-1                                                  F2E00190
OADTGA SYN     ADTGA-400*M/N-1                                          F2E00200
DOTAGZ SYN     OADTGA                                                   F2E00210
DOTAG  SYN     DOTAGZ-200*M/N*9                                         F2E00220
MXTGA  SYN     DOTAG                                                    F2E00230
OMXTGA SYN     MXTGA-1000*M/N                                           F2E00240
TAGZ   SYN     OMXTGA                                                   F2E00250
TAGTG  SYN     TAGZ-1000*M/N*4                                          F2E00260
DOFILE SYN     TAGTG-1500*M/N*4                                         F2E00270
BTWO   SYN     DOFILE-CIBSZ         ORIGIN OF CIT                       F2E00280
BONE   SYN     BTWO-CIBSZ           OUTPUT BUFFERS.                     F2E00290
TRLVL  BCI     1,TRALEV                                                 F2E00300
DTGBL  BCI     1,DOTAGB                                                 F2E00310
TAGL   BCI     1,TAGTAG                                                 F2E00320
TIFL   BCI     1,TIFGO                                                  F2E00330
SKLST4 MZE     1,,0                                                     F2E00340
AINIT  LXD     DORCCT,2             PICK UP DOTAG                       F2E00350
       SXD     DOTGRC,2             RECORD COUNT.                       F2E00360
       STZ     CARWC                                                    F2E00370
       STZ     SXDWC                                                    F2E00380
       CLA     LADMX                                                    F2E00390
       SUB     ADTGWC                                                   F2E00400
       PAX     0,1                                                      F2E00410
       SXD     ADTGS1,1                                                 F2E00420
       SLT     3                    TEST FOR EMPTY DOTAG.               F2E00430
       TRA     MAN                  NOT EMPTY.                          F2E00440
       SLN     3                    RESTORE SL AND                      F2E00450
       TRA     DF70                 SKIP BLOCK 5.                       F2E00460
       REM                                                              F2E00470
MAN    LXD     DOTGRC,1             LOAD REMAINING DOTAG RECORD CNT.    F2E00480
*      ***                                                              F2E00490
       TSX     (TAPE),4             READ                                F2E00500
       PZE     IOCOM2,,(RBNP)       IN                                  F2E00510
       PZE     TAGL,,FTAPE4         TAGTAG.                             F2E00520
*      ***                                                              F2E00530
       TSX     (TAPE),4             POSITION TAPE                       F2E00540
       PZE     SKLST4,,(SKBP)       TO WRITE                            F2E00550
       PZE     CMPDOL,,FTAPE4       COMPDO.                             F2E00560
       LXD     LMXTG,2              INITIALIZE TEST                     F2E00570
       TXI     *+1,2,4              IN NEST SEARCH                      F2E00580
       SXD     FIND10,2             ROUTINE.                            F2E00590
MAN01  SXD     DOTGRC,1                                                 F2E00600
       TXL     MAN70,1,0            TEST FOR END DOTAG.                 F2E00610
*      ***                                                              F2E00620
MAN03  TSX     (TAPE),4             READ ONE                            F2E00630
       PZE     DSC6,,(RBNC)         NEST OF                             F2E00640
       PZE     DTGBL,,FTAPE2        DOTAGS.                             F2E00650
       LXA     LMXTGA,2             INITIALIZE APPENDED                 F2E00660
MAN06  STZ     MXTGA,2              TAGTAG AND                          F2E00670
       TIX     MAN06,2,1            APPENDED                            F2E00680
       LXA     LZEKMX,2             ADTAG                               F2E00690
MAN08  STZ     ADTGA,2              TO ALL                              F2E00700
       TIX     MAN08,2,1            ZEROS.                              F2E00710
       STZ     BBOX                 INITIALIZE                          F2E00720
       STZ     DOIND                INDICATORS.                         F2E00730
       STZ     DOIND1                                                   F2E00740
       STZ     SWICH1                                                   F2E00750
       CLA     ALLONE                                                   F2E00760
       STO     VCTR                                                     F2E00770
*      ***                                                              F2E00780
       CLA     (SCHU)+FTAPE2        DETERMINE                           F2E00790
       STO     $E2C                 DOTAG AREA.                         F2E00800
       LXA     $E2C,1                                                   F2E00810
       TXL     *+2,1,DOTAGZ                                             F2E00820
       TSX     ERRORM,4             DOTAG RECORD OVERFLOWS A            F2E00830
       REM                          BUFFER OF THE SIZE OF THE           F2E00840
       REM                          ONE FROM WHICH IT WAS WRITTEN       F2E00850
       REM                          ONTO TAPE2 AS FILE 6.               F2E00860
       SXD     MAN16,1                                                  F2E00870
       AXT     DOTAGZ+2,1           FORM TEST FOR                       F2E00880
MAN16  TIX     *+1,1,0              SCAN OF DOTAG                       F2E00890
       SXD     DOGS60,1             IN DOGS ROUTINE.                    F2E00900
       SXD     MAN18,1              INITIALIZE                          F2E00910
       LXA     LMXDTG,1             WORD 7                              F2E00920
       CAL     T1MSK                OF DOTAG                            F2E00930
MAN17  ANS     DOTAGZ+6,1           FOR USE AS                          F2E00940
       TXI     *+1,1,-9             STORAGE OF VAR                      F2E00950
MAN18  TXH     MAN17,1,0            TXH LOCATION                        F2E00960
       TSX     TTG,4                READ NEST OF TAGTAGS.               F2E00970
MAN20  CLA     L(1)                 INITIALIZE LOCATION INDICATOR       F2E00980
       STO     LOCIND               FOR A CYCLE OF CODING.              F2E00990
       TSX     DOGS,4               SELECT BETA OR ALPHA.               F2E01000
       TRA     MAN50                END OF NEST                         F2E01010
MAN40  LXD     DOIND,2              SET UP ALPHA                        F2E01020
       CLA     DOTAGZ,2             WORD AND                            F2E01030
       STD     A                    BETA WORD IN                        F2E01040
       PAX     0,1                  PREPARATION FOR                     F2E01050
       SXD     B,1                  ALPHA OR BETA CYCLE.                F2E01060
       ANA     DECMSK               LEAVE BETA IN ACC DECREMENT.        F2E01070
       ZET     SWICH1               WHICH CYCLE IS APPROPRIATE.         F2E01080
       TSX     RTX,4                BETA CYCLE.                         F2E01090
       TSX     AC,4                 ALPHA CYCLE.                        F2E01100
       TRA     MAN20                RETURN FOR EITHER CYCLE             F2E01110
MAN50  TRA     DF01                 GO TO SORT A NEST OF CIT'S.         F2E01120
       SXD     BCNT,2               RETURN FROM DF ROUTINE.             F2E01130
       LXD     DOTGRC,1             END OF NEST,                        F2E01140
       TXI     MAN01,1,-1           AND CONSIDER NEXT NEST.             F2E01150
MAN70  SLF                          END OF DOTAG,                       F2E01160
       TRA     DF70                                                     F2E01170
FILN2L BCI     1,EOF2                                                   F2E01180
       REM BEGIN BETA STAGE                                             F2E01190
       REM THE BETA STATE IS CALLED BY MAN TO COMPUTE AND COMPILE       F2E01200
       REM INCREMENTING, TESTING, AND RESETTING INSTRUCTIONS FOR A GIVENF2E01210
       REM DO.                                                          F2E01220
RTX    SXD     RTX024,4                                                 F2E01230
       LXD     VCTR,1               VARIABLE CTR.  LAST BETA.           F2E01240
       LXD     B,2                  BETA OF NEW DO.                     F2E01250
       SXD     *+1,2                                                    F2E01260
       TXH     *+3,1,0              IS THIS THE FIRST BETA.             F2E01270
       STZ     LOCIND                                                   F2E01280
       TRA     RTX05                                                    F2E01290
       PXD     0,2                                                      F2E01300
       ADD     L(K1)                FIRST B. SET                        F2E01310
       STO     VCTR                 VCTR AND                            F2E01320
       CLA     ALLONE               INITIALIZE                          F2E01330
       STO     BLSW                 BLOCK INDICATOR.                    F2E01340
RTX05  CLA     L(0)                 INITIALIZE THE TEST TAG             F2E01350
       STO     TETTGX               INDEX FOR THIS DO TO ZERO.          F2E01360
       STO     XTG                                                      F2E01370
       STO     RTXTGX                                                   F2E01380
       STO     ADTGX                                                    F2E01390
       TSX     N3BIT,4              ISOLATE N3 BIT OF DOTAG             F2E01400
       TSX     SCAN,4                                                   F2E01410
RTXIN1 SXD     RTXTGX,1             STORE FIRST TTG FOR TX CYCLE.       F2E01420
       SXD     XTG,1                ENTRY THAT LIES BETWEEN A AND B     F2E01430
RTX06  TSX     FIND,4                                                   F2E01440
       TRA     RTX180               END OF DO, START DMTG CYCLE.        F2E01450
       SXD     XTG,1                SC MODIFIED BY DO, STORE.           F2E01460
       TSX     TETG,4               PLACE TEST BITS IN TAG WORD.        F2E01470
       TSX     PRES,4                                                   F2E01480
       REM AT THE END OF THIS ROUTINE THE BLOCK INDICATION IS IN XB.    F2E01490
       TXH     RTX160,2,4           BL F, NO INSTR., GET NEW TAG.       F2E01500
       TXH     RTX70,2,0            BLOCK DIFFERENT FROM A OR F.        F2E01510
       CLA     N3IND                BLOCK EQUALSA.                      F2E01520
       TNZ     RTX68                DECREMENT OF RXA IS VARIABLE        F2E01530
RTX020 LXD     TAG3,1               DECREMENT IS CONSTANT.              F2E01540
       TXH     RTX50,1,0            TEST FOR INSERTED COUNTER.          F2E01550
       CLA     TAG3                 OR RESET TAG.                       F2E01560
       LRS     11                                                       F2E01570
       LBT                                                              F2E01580
RTX024 TXL     RTX30,,0             RESET                               F2E01590
       TRA     RTX34                COUNTER.                            F2E01600
RTX30  CLA     TAG3                 IF RESET TAG, PUT TAG               F2E01610
       ANA     11BITS               NAME IN ACCUMULATOR AND             F2E01620
       TRA     RTX51                GO TO SUBCOM.                       F2E01630
RTX34  TSX     ENTR,4               IF COUNTER, MAKE                    F2E01640
       TRA     RTX52                ARTIFICIAL ENTRY IN WRKSC.          F2E01650
RTX50  PXD     0,1                  CURRENT TAG.                        F2E01660
       ARS     18                   GET TAG NAME                        F2E01670
RTX51  TSX     $SUBCM,4             LAY OUT TAU ENTRY.                  F2E01680
RTX52  CLA     L(TXI)               COMPILE                             F2E01690
       STO     CIL01                TXI                                 F2E01700
       LXA     POSIND,1             PREPARE FOR                         F2E01710
       LXD     DOIND,2              EXIT ROUTINE.                       F2E01720
       TSX     CN3IJ,4              ROUTINE COMPUTES DECREMENT N3G      F2E01730
       STO     ERTX01               AND STORES IN ERTX01.               F2E01740
       LXA     POSIND,1                                                 F2E01750
       CLA     TAG4                 TEST FOR DUPLICATE                  F2E01760
       LRS     12                   SUBSCRIPTS AND COMPUTE              F2E01770
       LLS     4,1                  DECREMENT FOR THEM.                 F2E01780
       LBT                          TEST ON S1,S2, OR S3 FOR DUPES.     F2E01790
       TRA     RTX66                NO DUPLICATES FOR THIS SUBSCRIPT.   F2E01800
       ARS     1                                                        F2E01810
       LBT                          TEST FOR S1 OR S2 DUPES.            F2E01820
       TXI     RTX62+3,1,2          DUPES ARE 1,3 ON TRANSFER.          F2E01830
       TXI     RTX61,1,1                                                F2E01840
RTX61  STO     ERTX02               STORE STATUS OF AC. DUPES ARE       F2E01850
       TSX     CN3IJ,4              1,2 OR 2,3 OR 1,2,3.                F2E01860
       LXA     POSIND,1             COMPUTE DECREMENT ADJUSTMENT        F2E01870
       ADD     ERTX01               FOR NEXT LEFT SUBSCRIPT.            F2E01880
       STO     ERTX01               REPLACE ADJUSTED DECREMENT IN ERTX01F2E01890
RTX62  TXI     RTX62+1,1,2                                              F2E01900
       TXH     RTX66,1,3            NOT 3RD SUBSCRIPT CASE.             F2E01910
       CLA     ERTX02               LOW ORDER BIT IS SSC LEFT OF DOSUB. F2E01920
       ARS     1                                                        F2E01930
       LBT                          TEST FOR S1 DUPE.                   F2E01940
       TRA     RTX66                                                    F2E01950
       LXD     DOIND,2                                                  F2E01960
       TSX     CN3IJ,4              COMPUTE DECREMENT ADJUSTMENT FOR S1 F2E01970
       ADD     ERTX01               IN 1,2,3 AND 1,3 CASES.             F2E01980
       STO     ERTX01               FINAL DECREMENT ADJUSTMENT.         F2E01990
RTX66  CLA     ERTX01                                                   F2E02000
       STA     CIL01                AFTER DECREMENT IS COMPUTED, FILL   F2E02010
       TSX     CIL023,4             OUT 4 WORDS OF                      F2E02020
       TSX     CIT,4                COMPILED INSTRUCTION.P              F2E02030
       TRA     RTX69                AND CONTINUE.                       F2E02040
RTX68  TSX     CILV,4               DEC IS VARIABLE. ASSIGN LOCATION    F2E02050
       CLA     CIL00                PREPARE VCTR LOCATION               F2E02060
       ANA     ADMSK                FOR TGA ROUTINE.                    F2E02070
       TSX     TGA,4                PUT LOC IN APP TAGTAG WORD          F2E02080
       TSX     CIL23,4              AND THEN FILL OUT                   F2E02090
       CLA     L(TXI)               REMAINING WORDS OF                  F2E02100
       STO     CIL01                COMPILED INSTRUCTION                F2E02110
       TSX     CIT,4                COMPILER ROUTINE.                   F2E02120
RTX69  CLA     TAG4                 TEST FOR SYMBOL                     F2E02130
       TPL     RTX160               INDICATION                          F2E02140
       LXD     DOIND,2              FORVAR                              F2E02150
       CLA     DOTAGZ+5,2           OCCURRANCE.                         F2E02160
       ANA     BIT1                                                     F2E02170
       TZE     RTX160               NO FORVAR, CONTINUE.                F2E02180
       CLA     L(0)                 FORVAR EXISTS.                      F2E02190
       STO     CIL00                                                    F2E02200
       CLA     TAG3                 COMPILE                             F2E02210
       ANA     ADMSK                STORE                               F2E02220
       STO     CIL03                INSTRUCTION                         F2E02230
       CLA     L(SXD)               FOR                                 F2E02240
       STO     CIL01                FORVAR OCCURRANCE.                  F2E02250
       LXD     DOIND,2                                                  F2E02260
       CLA     DOTAGZ+1,2           PUT FORVAR SUBSCRIPT                F2E02270
       STO     CIL02                IN RELATIVE ADDRESS                 F2E02280
       TSX     CIT,4                WORD FOR SXD INSTRUCTION.           F2E02290
       TRA     RTX160                                                   F2E02300
RTX70  TXH     RTX90,2,1            BLOCK IS B,C,D OR E.                F2E02310
       SXD     BLKNUM,2                                                 F2E02320
       LXD     TAG2,2               BLOCK B FIRST DETERMINE             F2E02330
       TSX     NBITS,4              IF DECREMENT IS VARIABLE            F2E02340
       ADD     N3IND                                                    F2E02350
       TNZ     RTX80                DECREMENT IS VARIABLE.              F2E02360
       CLA     TAG3                 DECREMENT IS CONSTANT.              F2E02370
       ARS     18                                                       F2E02380
       TSX     $SUBCM,4             LAY OUT TAU INTO WRKSC.             F2E02390
       LXD     DOIND,2              PREPARE FOR                         F2E02400
       LXA     POSIND,1             EXIT ROUTINE.                       F2E02410
       TSX     CN3IJ,4              COMPUTE N3G AND                     F2E02420
       STO     ERTX01               STORE IN ERTX01.                    F2E02430
       LXD     TAG2,2                                                   F2E02440
       LXA     POSIND,1             MOVE POSIND TO LEFT SUB             F2E02450
       TXI     RTX72,1,1            AND COMPUTE XN3G                    F2E02460
RTX72  TSX     XMIN1,4              FOR LEFT SUB WHICH IS TEST.         F2E02470
       STO     ERTX02                                                   F2E02480
       ADD     ERTX01               ADDN3G FOR THIS SUBSCRIPT           F2E02490
       STO     ERTX01               RESULT IS TXI DECREMENT.            F2E02500
       TSX     EDCB,4               COMPILE TXI SXD TIX.                F2E02510
       TRA     RTX160               CHECK BEST TEST.                    F2E02520
RTX80  TSX     BCDE,4               BLOCK B IS VARIABLE.                F2E02530
       TRA     RTX160                                                   F2E02540
RTX90  TXH     RTX110,2,2           BLOCK IS C,D, OR E.                 F2E02550
       SXD     BLKNUM,2             BLOCK IS C, PUT IN XB.              F2E02560
       LXD     TAG2,2               ISOLATE                             F2E02570
       TSX     NBITS,4              NBITS INTO N1N2N3.                  F2E02580
       ADD     N3IND                                                    F2E02590
       TNZ     RTX100               DECREMENT IS VARIABLE, TSX BCDE.    F2E02600
       CLA     TAG3                 DECREMENT IS CONSTANT.              F2E02610
       ARS     18                   LAY OUT TAU                         F2E02620
       TSX     $SUBCM,4             ENTRY INTO WRKSC.                   F2E02630
       LXD     TAG2,2               COMPUTE                             F2E02640
       LXA     L(3),1               XN3G-1                              F2E02650
RTX91  TSX     XMIN1,4              FOR                                 F2E02660
       STO     ERTX02               SUBSCRIPT.                          F2E02670
       LXA     POSIND,1             THEN COMPUTE N3G                    F2E02680
       LXD     DOIND,2              FOR RIGHT                           F2E02690
       TSX     CN3IJ,4              SUBSCRIPT.                          F2E02700
       ADD     ERTX02               RESULT IS                           F2E02710
       STO     ERTX01               ERTX01.                             F2E02720
       LDI     TAG4                 TEST                                F2E02730
       RNT     1000                 FOR DUPES.                          F2E02740
       TRA     RTX95                NO DOSUB DUPE.                      F2E02750
       LXA     POSIND,1             DOSUB IS DUPE.                      F2E02760
       TXI     RTX93,1,1            COMPUTE ADJUSTMENT                  F2E02770
RTX93  TSX     CN3IJ,4              FOR DECREMENT AND                   F2E02780
       ADD     ERTX01               STORE IN ERTX01.                    F2E02790
       STO     ERTX01               XN3G(L) + N3G(R) + N3G(C) - 1)      F2E02800
RTX95  TSX     EDCB,4               COMPILE TXI SXD TIX.                F2E02810
       TRA     RTX160                                                   F2E02820
RTX100 TSX     BCDE,4               BLOCK DECREMENT IS VARIABLE.        F2E02830
       TRA     RTX160                                                   F2E02840
RTX110 TXH     RTX140,2,3           D OR E.                             F2E02850
       SXD     BLKNUM,2             STORE BLOCK NUMBER D.               F2E02860
       LXD     TAG2+1,2             BLOCK D CONSIDERED.                 F2E02870
       TSX     NBITS,4              ISOLATE NBITS                       F2E02880
       ADD     N3IND                CHECK FOR VARIABLE DECREMENT.       F2E02890
       TNZ     RTX130               DECREMENT IS VARIABLE.              F2E02900
       CLA     TAG3                 DECREMENT IS CONSTANT.              F2E02910
       ARS     18                   SET UP TAG                          F2E02920
       ANA     11BITS               NAME AND                            F2E02930
       TSX     $SUBCM,4             LAY OUT TAU ENTRY.                  F2E02940
       LXD     TAG2+1,2             CONSIDER CENTER SUBSCRIPT           F2E02950
       LXD     XTG,4                                                    F2E02960
       LXA     L(2),1                                                   F2E02970
       CLA     TAGZ+3,4             DOES CARRY EXIST FOR                F2E02980
       ANA     CRMSK                TWO INNER DOS.                      F2E02990
       TZE     RTX111               IF NOT, GO TO RTX111.               F2E03000
       TSX     CXIJ,4               YES, COMPUTE                        F2E03010
       LXD     $WRKSC,4             XN3G                                F2E03020
       SXA     ERTX02,4             MINUS                               F2E03030
       SUB     ERTX02               C1.                                 F2E03040
       TRA     RTX112                                                   F2E03050
RTX111 TSX     XMIN1,4              COMPUTE (X-1)N3G                    F2E03060
RTX112 STO     ERTX02               FOR CENTER SUBSCRIPT.               F2E03070
       LXA     POSIND,1             PREPARE DOSUB SUBSCRIPT             F2E03080
       LXD     DOIND,2              FOR CN3IJROUTINE.                   F2E03090
       TSX     CN3IJ,4              COMPUTE N3G FOR                     F2E03100
       STO     ERTX01               DOSUB SUBSCRIPT.                    F2E03110
       CLA     TAG4                 TEST                                F2E03120
       ARS     9                    FOR                                 F2E03130
       ANA     L(7)                 DUPES.                              F2E03140
       TZE     RTX126               NORMAL BLOCK D, NO DUPES.           F2E03150
       LBT                                                              F2E03160
       TRA     RTX118               XX0 BLOCK D, OR 0XX.                F2E03170
       LXA     POSIND,1             X0X BLOCK D.                        F2E03180
       TXI     RTX114,1,2           SWITCH RIGHT OR LEFT POSIND.        F2E03190
RTX114 TSX     CN3IJ,4              COMPUTE N3G                         F2E03200
       ADD     ERTX01               DECREMENT ADJUSTMENT                F2E03210
       STO     ERTX01               FOR X0X                             F2E03220
       TRA     RTX126               DUPES.                              F2E03230
RTX118 LXD     TAG2+1,2             COMPUTE XN3G                        F2E03240
       LXA     $L(3),1              DECREMENT                           F2E03250
RTX122 TSX     XMIN1,4              ADJUSTMENT                          F2E03260
       ADD     ERTX02               FOR CENTER                          F2E03270
       STO     ERTX02               SUBSCRIPT.                          F2E03280
RTX126 CLA     ERTX02               SUB1 AND                            F2E03290
       ADD     ERTX01               YIELDING TXI                        F2E03300
       STO     ERTX01               DECREMENT.                          F2E03310
       TSX     EDCB,4               COMPILE TXI SXD TIX.                F2E03320
       TRA     RTX160               END CHECK FOR TEST TAG.             F2E03330
RTX130 TSX     BCDE,4               BLOCK D IS VARIABLE.                F2E03340
       TRA     RTX160                                                   F2E03350
RTX140 SXD     BLKNUM,2             BLOCK E                             F2E03360
       LXD     TAG2,2               PUT N BITS FOR S1                   F2E03370
       TSX     NBITS,4              PLACE N BITS PLUS                   F2E03380
       ADD     N3IND                N3IND FOR S1                        F2E03390
       STO     ERTX01               AND S2 INTO ERTX01                  F2E03400
       LXD     TAG2+1,2             FOR VARIABLE DECREMENT              F2E03410
       TSX     NBITS,4              TEST.  IF SUM IS NOT ZERO,          F2E03420
       ADD     ERTX01               THEN THE DECREMENT IS VARIABLE.     F2E03430
       TNZ     RTX154               DECREMENT IS VARIABLE.              F2E03440
       CLA     TAG3                 CONSTANT CASE, LAY                  F2E03450
       ARS     18                   OUT TAU ENTRY INTO                  F2E03460
       TSX     $SUBCM,4             WRKSC.                              F2E03470
       LXD     TAG2+1,2             SET UP CENTER SUBSCRIPT             F2E03480
       LXA     L(2),1               FOR EXIT ROUTINE.                   F2E03490
       TSX     XMIN1,4              COMPUTE XN3G FOR CENTER.            F2E03500
       STO     ERTX02               IN ERTX02.                          F2E03510
       LXA     POSIND,1             COMPUTE N3G                         F2E03520
       LXD     DOIND,2              FOR RIGHT                           F2E03530
       TSX     CN3IJ,4              SUBSCRIPT (DOSUB).                  F2E03540
       ADD     ERTX02               PUT FIRST TXI DECREMENT             F2E03550
       STO     ERTX01               IN ERTX01.                          F2E03560
       TSX     EDCB,4               COMPILES FIRST                      F2E03570
       LXD     TAG2,2               THREE OF BLOCK E.                   F2E03580
       LXA     POSIND,1             COMPUTE XN3G FOR                    F2E03590
       TXI     RTX150,1,2           LEFT SUBSCRIPT.                     F2E03600
RTX150 TSX     XMIN1,4              TO COMPILE 2ND                      F2E03610
       STO     ERTX01               BLOCK E, THE BLOCK                  F2E03620
       STO     ERTX02               NUMBER IS SET TO                    F2E03630
       LXD     BLKNUM,4             APPEAR LIKE BLOCK C SO              F2E03640
       TIX     RTX152,4,2           THATTHE SXD LOCATION IS STORED      F2E03650
RTX152 SXD     BLKNUM,4             PROPERLY INTO DOTAG.                F2E03660
       TSX     EDCB,4               COMPILE 2ND TXI SXD TIX.            F2E03670
       TRA     RTX160                                                   F2E03680
RTX154 TSX     BCDE,4               E IS VARIABLE.  THIS TAKES          F2E03690
       TSX     CILV,4               CARE OF FIRST 3 INSTRUCTIONS.P      F2E03700
       TSX     CIL23,4              THE REMAINING THREE ARE             F2E03710
       CLA     L(TXI)                                                   F2E03720
       STO     CIL01                NOW COMPILED.                       F2E03730
       TSX     CIT,4                                                    F2E03740
       LXD     BLKNUM,4             CHANGE BLKNUM                       F2E03750
RTX157 TIX     RTX157,4,2           FROM E                              F2E03760
       SXD     BLKNUM,4             TO C AND                            F2E03770
       TSX     CSXD,4               TSX CSXD.                           F2E03780
       LXD     BLKNUM,4                                                 F2E03790
       TXI     RTX157+5,4,2                                             F2E03800
       SXD     BLKNUM,4                                                 F2E03810
       LXD     TAG2,2               PLACE LOCATION OF SXD               F2E03820
       CLA     CIL00                INSTRUCTION IN PROPER DOTAG ENTRY   F2E03830
       ANA     ADMSK                AND POSITION. (LEFT SUB DO).        F2E03840
       ALS     12                                                       F2E03850
       ORS     DOTAGZ+6,2                                               F2E03860
       TSX     CILV,4               GENERATE AND                        F2E03870
       TSX     CIL23,4                                                  F2E03880
       CLA     L(TIX)               COMPILE REMAINING INSTRC.           F2E03890
       STO     CIL01                                                    F2E03900
       TSX     CIT,4                PUT INTO BUFFER.                    F2E03910
RTX160 LXD     DOIND,2              FINDING S.C. WHICH                  F2E03920
       CLA     DOTAGZ+8,2           HAS AN S THAT IS THE TEST.          F2E03930
       ANA     TETMSK                                                   F2E03940
       STO     ERTX01               TEST NAME.                          F2E03950
       CLA     TAG3                 COMPARE TAG NAME                    F2E03960
       ALS     18                   WITH BEST TEST                      F2E03970
       ANA     DECMSK               OF CURRENT DO.                      F2E03980
       SUB     ERTX01               IF THIS TAG IS                      F2E03990
       TNZ     RTX164               BEST TEST,                          F2E04000
       CLA     XTG                  STORE ITS INDEX                     F2E04010
       STO     TETTGX               IN TETTGX.                          F2E04020
RTX164 TRA     RTX06                GO TO FIND FOR NEXT TAG.            F2E04030
RTX180 CLA     INST26               RTX184 LOCATION.                    F2E04040
       STA     RTX69+1              RESET AT END OF ROUTINE.            F2E04050
       LXA     LADMX,4              PREPARE FOR ADTAG TXI.              F2E04060
       TXI     RTX180+4,4,4                                             F2E04070
       SXD     XTG,4                                                    F2E04080
       CLA     INST20               ADTGA LOCATION.                     F2E04090
       STA     TGA8                                                     F2E04100
RTX184 TSX     ADTGSE,4             SEARCH FOR ADTAG.                   F2E04110
       TRA     RTX192               END OF TABLE, START TX PHASE.       F2E04120
       PXD     0,2                  ENTRY FOUND, CONTINUE ADTG CYCLE.   F2E04130
       ARS     18                   POSIND IN ADDRESS.                  F2E04140
       STO     POSIND                                                   F2E04150
       CLA     TAG4                 LOOK AT                             F2E04160
       ARS     21                   CARRY BITS.                         F2E04170
       TXH     RTX190,2,2           S1, BLOCK A.                        F2E04180
       TXL     RTX188,2,1           S3                                  F2E04190
       ARS     2                    S2                                  F2E04200
RTX188 ANA     $L(3)                                                    F2E04210
       TNZ     RTX184               CARRY T1 OR T2 BLOCK F.             F2E04220
RTX190 CLA     N3IND                                                    F2E04230
       TZE     RTX020               DECREMENT IS CONSTANT.              F2E04240
       TSX     CILV,4               DECREMENT IS VARIABLE.              F2E04250
       CLA     CIL00                INSTRUCTION IS COMPILED             F2E04260
       ANA     ADMSK                AND ENTRY IS MADE                   F2E04270
       TSX     TGA,4                IN APPENDED DRM TG WORD.            F2E04280
       TSX     CIL23,4                                                  F2E04290
       CLA     L(TXI)               COMPILE                             F2E04300
       STO     CIL01                TXI AND PUT                         F2E04310
       TSX     CIT,4                IN CIB.                             F2E04320
       TRA     RTX184               GET NEW ADTAG.                      F2E04330
RTX192 CLA     INST24               RESET MODIFIED                      F2E04340
       STA     RTX69+1              ADDRESSES FOR                       F2E04350
       CLA     INST22               TXI CYCLE.                          F2E04360
       STA     TGA8                                                     F2E04370
RTX195 LXD     TETTGX,1             DETERMINE IF THIS DO HAS A TEST.    F2E04380
       TXH     RTX197,1,0           THIS DO HAS A TEST.                 F2E04390
RTX196 LXD     DOIND,2              NO TXL,                             F2E04400
       CLA     DOTAGZ,2             MAKE                                F2E04410
       ALS     4                    ENTRY                               F2E04420
       ARS     4                    INTO                                F2E04430
       LXD     CARWC,1              DOCARE.                             F2E04440
       STO     DOCARE,1                                                 F2E04450
       TXI     *+1,1,-1             UPDATE DOCARE WORD COUNT.           F2E04460
       SXD     CARWC,1                                                  F2E04470
       TRA     RTX280                                                   F2E04480
RTX197 PSE     096                  CLEAR SENSE LIGHTS.                 F2E04490
       TSX     TGFM,4               FILL OUT TAG WORDS.                 F2E04500
       TSX     ISC,4                FIND DOSUB.                         F2E04510
       TSX     ERRORM,4             DOIND (XR VALUE OF CURRENT          F2E04520
       REM                          DOTAG ENTRY) MUST MATCH ONE 3       F2E04530
       REM                          OF THE 3 TAG2 WDS TAKEN FROM        F2E04540
       REM                          THE XR1 TAGTAG ENTRY (FILE 2        F2E04550
       REM                          TAPE 4). THIS IS AN ERROR           F2E04560
       REM                          RETURN FROM ISC.                    F2E04570
       PXD     0,2                  FORM                                F2E04580
       ARS     18                   POSITION                            F2E04590
       STO     POSIND               INDICATOR.                          F2E04600
       TSX     CILV,4               OBTAIN LOCATION FOR TEST,           F2E04610
       LXD     DOIND,2              ISOLATE                             F2E04620
       TSX     NBITS,4              NBITS.                              F2E04630
       STO     N1N2N3                                                   F2E04640
       CLA     DOTAGZ+3,2                                               F2E04650
       ANA     6ONES                                                    F2E04660
       TNZ     RTX210               N2 IS VARIABLE                      F2E04670
       LXA     POSIND,1                                                 F2E04680
RTX198 TNX     RTX200,1,1           IS POSITION S3.                     F2E04690
       CLA     TAG4                 CHECK FOR DORC                      F2E04700
       ANA     BITMSK+2,1                                               F2E04710
       STO     N1SBX                N1 BIT.                             F2E04720
       TSX     N1S02,4                                                  F2E04730
       TNZ     RTX210               TXL VARIABLE DECREMENT.             F2E04740
RTX200 LXD     TAG3,1                                                   F2E04750
       TXH     RTX201,1,0                                               F2E04760
       TSX     ENTR,4               NOT NORMAL TAG, LAY OUT SIMULATED   F2E04770
       TRA     RTX202               TAU ENTRY INTO WRKSC.               F2E04780
RTX201 CLA     TAG3                 PREPARE FOR                         F2E04790
       ARS     18                   SUBCOM ROUTINE.                     F2E04800
       TSX     $SUBCM,4             LAY OUT TAU ENTRY.                  F2E04810
RTX202 LXD     DOIND,2              PREPARE FOR AND CALL CXIJ           F2E04820
       LXA     POSIND,1             ROUTINE TO COMPUTE XGN3.            F2E04830
       CLA     DOTAGZ+3,2           PTCH06 CALLS TELC ROUTINE           F2E04840
       TSX     CXIJ+2,4                                                 F2E04850
       TNX     RTX204,1,1                                               F2E04860
       TSX     TELC+2,4             COMPUTES LOAD VALUE FOR             F2E04870
       TRA     RTX205               DEC, STO IN ERTX01.MAX.OF 32767 (26)F2E04880
RTX204 STO     CIL01                FINAL TXL DECREMENT.                F2E04890
       CAL     L(TXL)                                                   F2E04900
       ORS     CIL01                                                    F2E04910
       TSX     CILNAM,4             ENTER TAG NAME IN CIL03.            F2E04920
       CLA     A                    ALPHA PLUS ONE IS                   F2E04930
       ADD     $L1DEC               ENTERED AS SYMBOLIC                 F2E04940
       STO     CIL02                ADDRESS.                            F2E04950
       TSX     CIT,4                ENTER TXL IN BUFFER.                F2E04960
       CLA     L(0)                 ELIMINATE VARIABLE INDICATOR BIT.   F2E04970
       TRA     RTX214                                                   F2E04980
RTX210 CLA     L(TXL)               COMPILE INSTR FOR VARIABLE DECR.    F2E04990
       STO     CIL01                                                    F2E05000
       TSX     CILNAM,4             ENTER TAG NAME.                     F2E05010
       CLA     A                    ALPHA PLUS ONE IS                   F2E05020
       ADD     $L1DEC               ENTERED AS THE                      F2E05030
       STO     CIL02                SYMBOLIC ADDRESS.                   F2E05040
       TSX     CIT,4                ENTER COMPILED TXL IN BUFFER.       F2E05050
       CLA     BIT20                TEST VARIABLE INDICATOR.            F2E05060
RTX214 LXD     DOIND,2              ENTERONE IN BIT 20 IF               F2E05070
       ORS     DOTAGZ+8,2           VARIABLE DECREMENT.                 F2E05080
       CLA     CIL00                STORE LOCATION                      F2E05090
       ALS     24                   OF                                  F2E05100
       ORS     DOTAGZ+6,2           TEST.                               F2E05110
       PSE     097                  SET SENSE INDICATOR SO              F2E05120
RTX222 LXD     RTXTGX,1             START SCAN FOR TIXING.              F2E05130
       SXD     XTG,1                                                    F2E05140
RTX226 TSX     FIND,4               FIND VALID TAG.  FILL TAG WORDS.    F2E05150
       TRA     RTX260               END OF DO.                          F2E05160
       SXD     XTG,1                SAVE IX OF TAG UNDER CONSIDERATION. F2E05170
RTX228 TSX     SCLMN1,4             COMPARE LARGEST S INDES             F2E05180
       SUB     DOIND                WITH INDEX OF THE DO.               F2E05190
       TZE     RTX234               DO IS OUTER, OBTAIN TAG.            F2E05200
       LXD     TAG3,2                                                   F2E05210
       TXH     RTX229,2,0           CURRENT TAG VALID, FILL OUT WRKSC.  F2E05220
       CLA     TAG3                 NEW TAG, DETERMINE                  F2E05230
       ARS     11                   IF TAU ENTRY                        F2E05240
       LBT                          EXISTS.                             F2E05250
       TRA     RTX229+5             NO,TSX ENTR.                        F2E05260
       CLA     TAG3                 YES, TSX                            F2E05270
       TRA     RTX229+2             SUBCOM.                             F2E05280
RTX229 CLA     TAG3                 CURRENT TAG                         F2E05290
       ARS     18                   VALID.                              F2E05300
       ANA     11BITS               FILL OUT                            F2E05310
       TSX     $SUBCM,4             WRKSC AND                           F2E05320
       TRA     RTX230               CONTINUE.                           F2E05330
       TSX     ENTR,4               ARTIFICIAL WRKSC ENTRY.             F2E05340
RTX230 LXA     POSIND,4                                                 F2E05350
       TIX     CLA,4,1              MOVE RIGHT ONE POSITION.            F2E05360
       TRA     RTX232               POSITION IS RIGHT, IGNORE CARRY.    F2E05370
CLA    CLA     TAG4                 POSITION IS LEFT OR CENTER,         F2E05380
       ARS     1                    OR TYPE 1 AND 2                     F2E05390
       ORA     TAG4                 CARRY BITS FOR LEFT                 F2E05400
       TXL     ARS,4,1              AND CENTER POSITIONS.               F2E05410
       ARS     23                   S2 CARRY BIT IN POSITION 35.        F2E05420
       TRA     LBT                                                      F2E05430
ARS    ARS     21                   S3 CARRY BIT IN POSITION 35         F2E05440
LBT    LBT                          TEST FOR DOSUB CARRY BIT.           F2E05450
       TRA     RTX232               NO CARRY, CONTINUE.                 F2E05460
       CLA     TETTGX               CARRY, SEE IF THIS                  F2E05470
       SUB     XTG                  TAG IS BEST TEST.                   F2E05480
       TNZ     RTX254               NO, GET NEXT TAG.                   F2E05490
RTX232 CLA     L(TIX)               COMPILE TIX INSTRUCTION.            F2E05500
       STO     CIL01                                                    F2E05510
       CLA     N1N2N3               TEST FOR VARIABLE DECREMENT.        F2E05520
       TZE     RTX238               DECREMENT IS CONSTANT.              F2E05530
       MSE     097                  DECREMENT IS VARIABLE8 TURN OFF     F2E05540
       NOP                          LIGHT INDICATION FIRST              F2E05550
       TSX     CILV,4               TIX AFTER TXL AND ASSIGN            F2E05560
       TSX     CIL23,4              LOCATION.                           F2E05570
       CLA     CIL00                WHEN DECREMENT IS VARIABLE, LOCATIONF2E05580
       ANA     ADMSK                MUST BE STORED IN TGA WORD          F2E05590
       TSX     TGAT,4               FOR SXD ADDRESS IS OBJECT TIME.     F2E05600
       TRA     RTX250               NOW PERFORM COMPILING.              F2E05610
RTX234 CLA     L(DED)               COMPILE OP WHICH INDICATES          F2E05620
       STO     CIL01                SC IS DEAD.                         F2E05630
       TRA     RTX242               ASSIGN LOCATION IF NECESSARY.       F2E05640
RTX238 LXA     POSIND,1             DECREMENT IS CONSTANT.              F2E05650
       LXD     DOIND,2              TEST FOR DUPLICATES                 F2E05660
       TSX     CXIJ,4               AND COMPUTE ACCORDINGLY.            F2E05670
       STO     ERTX01               XN3G IN ERTX01.                     F2E05680
       LDQ     TAG4                 TEST                                F2E05690
       LLS     27,1                 FOR                                 F2E05700
       LBT                          DUPES.                              F2E05710
       TRA     RTX240               NO DUPES.                           F2E05720
RTX239 TXI     RTX239+1,1,1         DUPES EXIST                         F2E05730
       LDQ     TAG4                 TEST DUPE                           F2E05740
       LLS     27,1                 BITS OF POSITIONS                   F2E05750
       LBT                          TO THE LEFT OF DOSUB                F2E05760
       TRA     RTX239               UNTIL THAT POSITION IS              F2E05770
       TSX     CXIJ,4               IN XA, THEN CALLCXIJ                F2E05780
       ADD     ERTX01               AND COMPUTE AND ADD                 F2E05790
       STO     ERTX01               DECREMENT ADJUSTMENT.               F2E05800
RTX240 CLA     ERTX01               PUT COMPUTED DE EREMTN              F2E05810
       STA     CIL01                IN CIL01 WORD.                      F2E05820
RTX242 MSE     097                  A LOC MUST BE ASSIGNED IF           F2E05830
       TRA     RTX246                                                   F2E05840
       TSX     CILV,4               THIS IS FIRST TIX AFTER             F2E05850
       TSX     CIL23,4              TEST.                               F2E05860
       TRA     RTX250                                                   F2E05870
RTX246 TSX     CIL023,4                                                 F2E05880
RTX250 TSX     CIT,4                COMPILE INST.                       F2E05890
RTX254 TRA     RTX226               RETURN FOR NEXT TG.                 F2E05900
RTX260 LXA     LADMX,4              START DRMTG SEARCH AND              F2E05910
       TXI     RTX260+2,4,4                                             F2E05920
       SXD     XTG,4                COMPILING                           F2E05930
RTX264 TSX     ADTGSE,4             FIND VALID TAG, FILL OUT TAG WDS.   F2E05940
       TRA     RTX270               END OF TABLE                        F2E05950
       PXD     0,2                  STORE POSITION                      F2E05960
       ARS     18                   OF DOSUB                            F2E05970
       STO     POSIND               IN POSIND.                          F2E05980
       CLA     INST30               MODIFY TGTG                         F2E05990
       STA     RTX254               TIX COMPILING                       F2E06000
       CLA     INST20               ROUTINE TO                          F2E06010
       STA     TGA8                                                     F2E06020
       TRA     RTX228               AND EXECUTE.                        F2E06030
RTX270 CLA     INST32               ADTG PORTION FINISHED.              F2E06040
       STA     RTX254               REMODIFY TIX COMPILING              F2E06050
       CLA     INST22               ROUTINE FOR TGTGS.                  F2E06060
       STA     TGA8                 END OF BETA CYCLE8 RETURN TO 1 PLUS F2E06070
RTX280 LXD     RTX024,4             LOCATION OF THE INSTRUCTION         F2E06080
       TRA     2,4                                                      F2E06090
       REM                                                              F2E06100
       REM                                                              F2E06110
       REM BEGIN ALPHA STATE                                            F2E06120
       REM THE ALPHA STATE, AC, IS CALLED BY MAN TO COMPILE ALL INITIALIF2E06130
       REM ZATION  AND LOAD INSTRUCTIONS WHEN AN ALPH OF A DO IS UNDER CF2E06140
       REM CONSIDERATION.                                               F2E06150
AC     SXD     AC248,4              SAVE LINKAGE.                       F2E06160
       STO     VCTR                                                     F2E06170
       LAC     SXDWC,1                                                  F2E06180
       CLA     DOTAGZ+6,2           2                                   F2E06190
       ARS     27                   WORD                                F2E06200
       ANA     6ONESR               ENTRY                               F2E06210
       ALS     3                    IN                                  F2E06220
       ADD     B                    SXDTX                               F2E06230
       STO     SXTX+1,1                                                 F2E06240
       CLA     DOTAGZ,2                                                 F2E06250
       ANA     NOPRET                                                   F2E06260
       STO     SXTX,1                                                   F2E06270
       LXA     SXDWC,1              UPDATE SXDTX WORD COUNT.            F2E06280
       TXI     AC03,1,2                                                 F2E06290
AC03   SXA     SXDWC,1                                                  F2E06300
AC05   CLA     ALLONE               INITIALIZE CIL WORDS                F2E06310
       STO     BLSW                 BLOCK INDICATOR.                    F2E06320
       TSX     SCAN,4               SCAN AND FIND PICK                  F2E06330
       SXD     RTXTGX,1                                                 F2E06340
       SXD     XTG,1                BY A DO WITHIN ALPHA                F2E06350
AC010  TSX     FIND,4               AND BETA.                           F2E06360
       TRA     AC240+1              END OF DO FOR DOTAG.                F2E06370
       SXD     XTG,1                STORE TGTG INDEX IN XTG.            F2E06380
AC014  TSX     SCLMN1,4             OBTAIN X FOR MINLEV OF S.C.         F2E06390
       LXD     XTG,1                SET UP FOR FIND ROUTINE.            F2E06400
       SUB     DOIND                TEST TO SEE IF THIS IS              F2E06410
AC016  TNZ     AC010                THE OUTERMOST DO.                   F2E06420
       LXD     TAG3,1               IF IT IS PROCEED TO                 F2E06430
       TXH     AC018,1,0            COMPILE PROPER INST.                F2E06440
       CLA     TAG3                 NO CURRENT TG, USE NEW TG.          F2E06450
       ARS     11                   CHECK RESET TAG BIT                 F2E06460
       LBT                          OR INSERTED COUNTER.                F2E06470
       TRA     AC016I               RESET TYPE ENTRY, USE NEW TAG.      F2E06480
       TSX     ENTR,4               CTR. TYPE ENTRY, SIMULATE           F2E06490
       TRA     AC020                WRKSC AND CONTINUE.                 F2E06500
AC016I CLA     TAG3                 RESET TYPE ENTRY                    F2E06510
       ANA     11BITS               LAY OUT TAU ENTRIES                 F2E06520
       TSX     $SUBCM,4                                                 F2E06530
       TRA     AC021                DECRENENT AND CONTINUE.             F2E06540
AC018  CLA     TAG3                 CURRENT TAG VALID, LAY              F2E06550
       ARS     18                   OUT TAU DNTRIES INTO                F2E06560
AC019  TSX     $SUBCM,4             WRKSC AND CONTINUE                  F2E06570
AC020  TSX     N1STET,4                                                 F2E06580
       CLA     N1SBX                VALUE IS CONSTANT                   F2E06590
       TNZ     AC030                VARIABLE, TRA AC030.                F2E06600
       TSX     TELC,4               COMPUTE LOAD                        F2E06610
       CLA     ERTX01               VALUE                               F2E06620
       ALS     18                   AND PLACE                           F2E06630
       ADD     $L1DEC               IN                                  F2E06640
       TSX     $FXCON,4             FIXCON.                             F2E06650
       STO     CIL02                FIXCON LOCATION SYMBOL.             F2E06660
       TRA     AC022                CONTINUE.                           F2E06670
AC021  CLA     BCD0                                                     F2E06680
       STO     CIL02                LXD ADDRESS TO BCD ZERO.            F2E06690
       STZ     N1SBX                                                    F2E06700
AC022  CLA     L(LXD)                                                   F2E06710
       STO     CIL01                LXD                                 F2E06720
       TSX     CIL03I,4             FILL OUT LOCATION AND TG WORDS.     F2E06730
       CLA     CIL02                PLACE LXD ADDRESS                   F2E06740
       STO     ORO00+27             IN ORO TABLE.                       F2E06750
       PAX     0,4                  RELATIVE PART OF FIXCON NAME        F2E06760
       ANA     6ONES                                                    F2E06770
       STO     CIL02                ADDRESS.                            F2E06780
       SXD     CIL03,4              RELATIVE ADDRESS.                   F2E06790
       CLA     LOCIND               TEST LOCATION INDICATOR.            F2E06800
       TZE     AC024                                                    F2E06810
       SUB     L(1)                                                     F2E06820
       STO     LOCIND               A LOCATION MUST BE                  F2E06830
       CLA     A                    ASSIGNED FOR 1ST LXD                F2E06840
       STO     CIL00                COMPILED FOR AN ALPHA.              F2E06850
AC024  TSX     CIT,4                PUT IN DOFILE.                      F2E06860
AC030  CLA     TAG4                 VARIABLE CASE, THE BITS FOR         F2E06870
       ARS     3                    DEFINING A SUB BY A DO OR           F2E06880
       ANA     L(7)                 A RELCON OR BOTH ARE                F2E06890
       STO     RELCO                ISOLATED IN 3 SEPARATE              F2E06900
       CLA     TAG4                 WORDS, DEFDO, RELCO, AND            F2E06910
       ANA     L(7)                 ORDEDO.                             F2E06920
       STO     DEFDO                                                    F2E06930
       ORA     RELCO                                                    F2E06940
       STO     OREDO                                                    F2E06950
       CLA     N1SBX                IF CONSTANT LOAD,                   F2E06960
       TZE     AC100+2              TRA AC100+2.                        F2E06970
       CLA     L(2)                 IF VARIABLE LOAD, FILL              F2E06980
       TSX     BITP,4               ORO TABLE.                          F2E06990
       TRA     AC040                S1 NOT DEFINED.                     F2E07000
       STO     ORO00+1              S1 DEFINED. STO SYMBOL IN ORO+1.    F2E07010
AC040  CLA     L(1)                 REPEAT FOR                          F2E07020
       TSX     BITP,4               S2.                                 F2E07030
       TRA     AC046                S2 NOT DEFINED.                     F2E07040
       STO     ORO00+4              S2 DEFINED. PUT SUBSCRIPT           F2E07050
       CLA     $WRKSC+6             SYMBOL IN ORO+4 AND                 F2E07060
       TSX     $FXCON,4             D1 SYMBOL                           F2E07070
       STO     ORO00+7              IN ORO+7.                           F2E07080
AC046  CLA     L(0)                 REPEAT FOR                          F2E07090
       TSX     BITP,4                                                   F2E07100
       TRA     AC048-1                                                  F2E07110
       STO     ORO00+21             S3 DEFINED. PUT SUBSCRIPT           F2E07120
       LDQ     $WRKSC+6             SYMBOL IN ORO+21                    F2E07130
       MPY     $WRKSC+7             AND                                 F2E07140
       ALS     17                   PUT                                 F2E07150
       TSX     $FXCON,4             D1D2 IN                             F2E07160
       STO     ORO00+24             ORO+24.                             F2E07170
       CLA     $WRKSC+6                                                 F2E07180
       TSX     $FXCON,4             GET SYMBOL FOR D1                   F2E07190
       STO     ORO00+7              AND STORE IN ORO+7.                 F2E07200
       PSE     96                   TURN OFF SENSE LIGHTS.              F2E07210
AC048  TSX     $COSE,4              TEST COEFFS OVER 1.                 F2E07220
       CLA     OPMSK                                                    F2E07230
       ANA     TAG4                 COEFS, 011 RELCONS, 100 CUPE.       F2E07240
       TNZ     AC049                SOME OF ABOVE EXIST.                F2E07250
       LXD     TAG21,1              NONE OF ABOVE EXIST,                F2E07260
       TXL     AC048+7,1,0          IF S2 DEF BY DO,                    F2E07270
       CAL     DOTAGZ+2,1           ISOLATE N1.                         F2E07280
       LXD     TAG22,1              IF S3 DEF BY DO,                    F2E07290
       TXL     AC048+10,1,0         OR N1S OF S2 AND S3.                F2E07300
       ORA     DOTAGZ+2,1           IF EITHER N1 IS GREATER             F2E07310
       SUB     L(1)                 THAN 1, RETURN.                     F2E07320
       TZE     AC048I               IS S1 IS                            F2E07330
       TPL     AC049                DEFINED BY A DO,                    F2E07340
AC048I LXD     TAG2,1               IS/LATE N1.                         F2E07350
       TXL     AC048I+4,1,0         IF NOT ISOLATE                      F2E07360
       CLA     DOTAGZ+2,1           S1 (BCD).                           F2E07370
       TRA     AC048I+5                                                 F2E07380
       CLA     $WRKSC+1                                                 F2E07390
       STO     CIL02                STO S1 OR N1 SYMBOL.                F2E07400
       TSX     CIL03I,4             FILL OUT                            F2E07410
       CLA     L(LXD)               COMPILED INSTRUCTION                F2E07420
       STO     CIL01                WORDS AND CONTINUE                  F2E07430
       TRA     AC100-1              TO INIT PORTION,                    F2E07440
AC049  LXA     L(2),1                                                   F2E07450
       CLA     OREDO                IS LEFT SUB A RELCON,               F2E07460
       ANA     L(4)                 DORC, OR DOSUB.                     F2E07470
       TZE     AC049A               NO, COMPILE CLA, SUB.               F2E07480
       LXD     TAG2,2               YES, IS IT A DOSUB.                 F2E07490
       TXL     AC049B,2,0           NO.                                 F2E07500
       CLA     DOTAGZ+2,2           YES, IS N1(S1)=1.                   F2E07510
       SUB     L(1)                                                     F2E07520
       TNZ     AC049B               NO.                                 F2E07530
AC049A CLA     KLX01                                                    F2E07540
       TSX     LXC,4                COMPILE CLA, SUB.                   F2E07550
AC049B CLA     OREDO                                                    F2E07560
       ARS     2                    DEFINITION.                         F2E07570
       LBT                          OF S1.                              F2E07580
       TRA     AC064                S1 IS NOT DEF., TAKE S2.            F2E07590
       LXA     $L(3),1              S1 DEFINED, GO TO                   F2E07600
       TSX     OP2,4                OPTIMIZING ROUTINE.                 F2E07610
       LXA     L(2),1               AT LEAST 4 COMP INST.               F2E07620
       MSE     97                   TEST ON COEF                        F2E07630
       TRA     AC050                GREATER THAN 1.                     F2E07640
       TXI     AC050I,1,2                                               F2E07650
AC050  CLA     KLX02                L(LXI02)                            F2E07660
       TRA     AC050I+1                                                 F2E07670
AC050I CLA     KLX02I               L(LXI05)                            F2E07680
       TSX     LXC,4                COMPILER.                           F2E07690
AC064  CLA     OREDO                                                    F2E07700
       ARS     1                    S2                                  F2E07710
       LBT                          DEFINED.                            F2E07720
       TRA     AC080                S2 NOT DEFINED. S3.                 F2E07730
       LXA     L(2),1               CALL OP2 ROUTINE                    F2E07740
       TSX     OP2,4                TO OPTIMIZE.                        F2E07750
       LXA     $L(6),1              COUNTER FOR COMPILING.              F2E07760
       MSE     98                   IS COEF GREATER THAN 1.             F2E07770
       TRA     AC068                NO                                  F2E07780
       CLA     KLX03                YES.                                F2E07790
       TXI     AC068+1,1,2          INCREMENT COMPILING COUNTER.        F2E07800
AC068  CLA     KLX03I                                                   F2E07810
       TSX     LXC,4                COMPILE S2 LOAD VALUE.              F2E07820
AC080  CLA     OREDO                                                    F2E07830
       LBT                                                              F2E07840
       TRA     AC096                S3 NOT DEFINED, EXIT.               F2E07850
       LXA     L(1),1               CALL OP2 ROUTINE                    F2E07860
       TSX     OP2,4                FOR OPTIMIZATION.                   F2E07870
       LXA     $L(6),1              COMPILING COUNTER.                  F2E07880
       MSE     99                   TEST FOR COEF GREATER THAN 1.       F2E07890
       TRA     AC084                NONE.                               F2E07900
       CLA     KLX05                C3 GREATER THAN 1, COMPILE          F2E07910
       TXI     AC084+1,1,2          KLX05 BLOCK.                        F2E07920
AC084  CLA     KLX05I               C3=1, COMPILE KLX05I                F2E07930
       TSX     LXC,4                BLOCK.                              F2E07940
AC096  TSX     CIL03I,4             COMPILE                             F2E07950
       CLA     L(LXD)               LXD.                                F2E07960
       STO     CIL01                                                    F2E07970
       CLA     ORO00+26             ERASABLE OBJECT TIME SYMBOL.        F2E07980
       PAX     0,1                                                      F2E07990
       ANA     6ONES                                                    F2E08000
       SXD     CIL03,1                                                  F2E08010
       STO     CIL02                                                    F2E08020
       TSX     CIT,4                PUT IN BUFFER.                      F2E08030
AC100  CLA     ORO00+26                                                 F2E08040
       STO     ORO00+27                                                 F2E08050
       LXA     $L(3),1              PREPARE TO                          F2E08060
AC109  SXD     AX,1                 CHECK FOR                           F2E08070
       CLA     TAG2+3,1             DUPES.                              F2E08080
       PDX     0,2                  SAVE INDEX OF S.                    F2E08090
       TXL     AC160,2,0            POS. NOT MOD. BY DO.                F2E08100
AC110  TNX     AC116,1,1                                                F2E08110
       CAS     TAG2+3,1             SKIP DUPES                          F2E08120
       TRA     AC110                EXCEPT                              F2E08130
       TRA     AC160                RIGHTMOST.                          F2E08140
       TRA     AC110                                                    F2E08150
AC116  CLA     DOTAGZ+8,2           ISOLATE                             F2E08160
       ANA     6TO17                NAME OF TEST                        F2E08170
       STO     TETTG                FOR THIS DO                         F2E08180
       CLA     TAG3                 AND                                 F2E08190
       ANA     24TO35               COMPARE                             F2E08200
       ALS     18                   WITH                                F2E08210
       CAS     TETTG                CURRENT TAG.                        F2E08220
       TRA     AC160                NOT A TEST TAG.                     F2E08230
       TRA     AC120                THIS IS A TEST TAG.                 F2E08240
       TRA     AC160                NOT A TEST TAG.                     F2E08250
AC120  CLA     DOTAGZ+3,2           THIS IS TEST TAG,                   F2E08260
       ANA     6ONES                18 N2 CONSTANT.                     F2E08270
       TNZ     AC128                                                    F2E08280
       CLA     DOTAGZ+8,2           IF RIGHT TEST HAS VARIABLE DECREMENTF2E08290
       ANA     BIT20                GO TO AC138 +4                      F2E08300
       TZE     AC138                INSTEAD OF                          F2E08310
       TRA     AC138+4                                                  F2E08320
AC128  CLA     DOTAGZ+3,2                                               F2E08330
       STO     CIL02                PUT N2 WORD AS                      F2E08340
       CLA     L(0)                 SYMBOLIC ADDRESS AND                F2E08350
       STO     CIL03                ZERO AS THE                         F2E08360
       TRA     AC140                RELATIVE ADDRESS.                   F2E08370
AC138  LDQ     DOTAGZ+6,2           CONSTANT N2 CASE.                   F2E08380
       RQL     9                    IS TEST                             F2E08390
       LGL     12                   MODIFIED.                           F2E08400
       TZE     AC160                NO, TAKE NEXT SUB.                  F2E08410
       CLA     DOTAGZ+3,2           YES, ISOLATE N2.                    F2E08420
       LXD     AX,1                                                     F2E08430
       TSX     CXIJ+2,4             IF POSITION IS                      F2E08440
       TNX     AC139,1,1                                                F2E08450
       STO     ESTORE                                                   F2E08460
       CLA     DOTAGZ+8,2           DOES TEST                           F2E08470
       ANA     BIT20                HAVE VARIABLE DECREMENT.            F2E08480
       TNZ     AC139-1                                                  F2E08490
       CLA     ESTORE                                                   F2E08500
       TSX     TELC+2,4                                                 F2E08510
       TRA     AC139                                                    F2E08520
       CLA     ESTORE                                                   F2E08530
AC139  ALS     18                                                       F2E08540
       TSX     $FXCON,4             ASSIGN SYMBOL FOR                   F2E08550
       PAX     0,1                  LOAD PORTION                        F2E08560
       ANA     6ONES                AND COMPILE                         F2E08570
       STO     CIL02                CLAL(GN2 + LOAD PORT.)              F2E08580
       CLA     L(0)                                                     F2E08590
       STO     CIL03                                                    F2E08600
       SXD     CIL03,1                                                  F2E08610
       TRA     AC144                                                    F2E08620
AC140  CLA     L(1)                                                     F2E08630
       LXD     AX,1                 COMPUTE G AND DETERMINE             F2E08640
       TSX     CXIJ+2,4             IF GREATER THAN ONE.                F2E08650
       SUB     L(1)                                                     F2E08660
       TNZ     AC146                                                    F2E08670
AC144  CLA     L(CLA)               G = 1,                              F2E08680
       STO     CIL01                COMPILE                             F2E08690
       CLA     L(0)                 CLA N2, FOLLOWED                    F2E08700
       STO     CIL00                LATER BY STD.                       F2E08710
       TSX     CIT,4                                                    F2E08720
       TRA     AC150                                                    F2E08730
AC146  ADD     L(1)                 G GREATER THAN 1,                   F2E08740
       ALS     18                   COMPILE                             F2E08750
       TSX     $FXCON,4             LDQ, MPY, ALS.                      F2E08760
       STO     ORO00+9                                                  F2E08770
       CLA     CIL02                                                    F2E08780
       STO     ORO00+1                                                  F2E08790
       CLA     KLX02I                                                   F2E08800
       LXA     $L(3),1                                                  F2E08810
       TSX     LXC,4                                                    F2E08820
AC150  LXD     AX,1                                                     F2E08830
       CLA     TAG3,1                                                   F2E08840
       PDX     0,2                                                      F2E08850
       CLA     DOTAGZ+8,2                                               F2E08860
       ANA     BIT20                                                    F2E08870
       LXD     AX,2                                                     F2E08880
       TZE     AC157                                                    F2E08890
       TNX     AC157,2,1                                                F2E08900
       LXA     L(1),1                                                   F2E08910
       CLA     KLX01I                                                   F2E08920
       TSX     LXC,4                                                    F2E08930
       CLA     INST13                                                   F2E08940
       STO     AC096                                                    F2E08950
       TSX     $COSE,4                                                  F2E08960
       LXD     AX,2                                                     F2E08970
       TXL     AC080,2,2                                                F2E08980
       TRA     AC064                                                    F2E08990
AC155  CLA     INST14                                                   F2E09000
       STO     AC096                                                    F2E09010
       LXD     AX,2                                                     F2E09020
       LXD     BBOX,4                                                   F2E09030
       TXI     AC155+5,4,4                                              F2E09040
       SXD     BBOX,4                                                   F2E09050
AC157  TSX     TESTLO,4                                                 F2E09060
       CLA     TETLOC               IN TETLO.                           F2E09070
       STO     CIL02                COMPILE                             F2E09080
       CLA     L(STD)               STD TETLO                           F2E09090
       STO     CIL01                AND RETURN TO                       F2E09100
       SXD     CIL00,0              AC160 TO                            F2E09110
       SXD     CIL03,0              CONSIDER NEXT                       F2E09120
       TSX     CIT,4                SUB OF TAG.                         F2E09130
AC160  LXD     AX,1                                                     F2E09140
       TIX     AC109,1,1            REDUCE POS. CTR.                    F2E09150
       CLA     TAG4                 CHECK SUSBIT                        F2E09160
       TPL     AC165                FOR FORVAR.                         F2E09170
       LXD     DOIND,2              FORVAR, IS IT                       F2E09180
       CLA     DOTAGZ+5,2           WITHIN THE CURRENT DO.              F2E09190
       ANA     BIT1                                                     F2E09200
       TZE     AC165                NO, AC165.                          F2E09210
       CLA     L(0)                 YES,                                F2E09220
       STO     CIL02                COMPILE                             F2E09230
       TSX     CIL03I,4             INSTRUCTIONS                        F2E09240
       CLA     L(PXD)               TO                                  F2E09250
       STO     CIL01                STORE                               F2E09260
       TSX     CIT,4                THE                                 F2E09270
       CLA     DOTAGZ+1,2           VALUE                               F2E09280
       STO     CIL02                OF                                  F2E09290
       CLA     L(STO)               THE                                 F2E09300
       STO     CIL01                SUBSCRIPT                           F2E09310
       PXD     0,0                  INTO                                F2E09320
       STO     CIL03                ITS                                 F2E09330
       TSX     CIT,4                SYMBOL.                             F2E09340
AC165  CLA     XTG                  START SCANNING                      F2E09350
       ARS     2                    TGA FOR LOCATIONS                   F2E09360
       PDX     0,1                  INDICATING VARIABLE                 F2E09370
       CAL     MXTGA,1              DECREMENTS OF TXI                   F2E09380
       SLW     WRKTGA               AND TIX INSTRUCTIONS-               F2E09390
       TZE     AC240                NONE, AC240.                        F2E09400
       LXA     $L(3),1              YES, ISOLATE                        F2E09410
AC166  SXD     AX,1                 APP. TGTG AND                       F2E09420
       CAL     WRKTGA               CHECK FOR                           F2E09430
       ARS     18                   LOCATIONS                           F2E09440
AC168  TNX     AC170,1,1            OF TXI                              F2E09450
       ARS     6                    INSTRUCTIONS                        F2E09460
       TRA     AC168                WITH VARIABLE                       F2E09470
AC170  ANA     6ONESR               DECREMENTS.                         F2E09480
       TZE     AC190                NONE, AC190.                        F2E09490
       ALS     3                    STORE                               F2E09500
       STO     TETLOC               LOC. OF TXI.                        F2E09510
       LXA     L(0),4                                                   F2E09520
       LXD     AX,1                 IS                                  F2E09530
       CLA     TAG4                 POSITION                            F2E09540
       TXL     AC173,1,2                                                F2E09550
       ANA     BIT8                 POSITION IS S1, IS                  F2E09560
AC171  TNZ     AC172                THIS BLOCK D SPECIAL.               F2E09570
       CLA     TAG4                 NO, BLOCK A.                        F2E09580
       TRA     AC176                TSX AORO                            F2E09590
AC172  LDQ     $WRKSC+2             TES, SET UP                         F2E09600
       MPY     $WRKSC+6             C1D1 AS G                           F2E09610
       ALS     17                   FOR XX POSITION.                    F2E09620
       STO     ORO00+20             C1 IS G FOR                         F2E09630
       CLA     $WRKSC               N3X POSITION.                       F2E09640
       STO     ORO00+19             PREPARE TO                          F2E09650
       LXA     $L(3),1              CALL PC ROUTINE                     F2E09660
       SXD     N3X,1                TO COMPILE                          F2E09670
       LXA     L(2),1               INITIALIZATION                      F2E09680
       SXD     XX,1                 INSTRUCTIONS                        F2E09690
       TSX     PC,4                 FOR BLOCK D SPECIAL.                F2E09700
       TRA     AC190                                                    F2E09710
AC173  TXL     AC174,1,1            IS POSITION S3)                     F2E09720
       ARS     3                    ISOLATE BLKNUM                      F2E09730
AC174  ARS     29                   FROM TAG4 AND                       F2E09740
       ANA     L(7)                 CALLPROPER ROUTINE                  F2E09750
       PAX     0,4                  TO COMPILE INITIALIZATION           F2E09760
AC176  TXH     AC176+3,4,0          INSTRUCTIONS FOR THAT BLOCK.        F2E09770
       TSX     AORO,4               BLOCK A                             F2E09780
       TRA     AC190                                                    F2E09790
       TXH     AC178,4,1                                                F2E09800
       TSX     BORO,4               BLOCK B                             F2E09810
       TRA     AC190                                                    F2E09820
AC178  TXH     AC182,4,2                                                F2E09830
       TSX     CORO,4               BLOCK C                             F2E09840
       TRA     AC190                                                    F2E09850
AC182  TXH     AC186,4,3                                                F2E09860
       TSX     DORO,4               BLOCK D.                            F2E09870
       TRA     AC190                                                    F2E09880
AC186  TSX     EORO,4               BLOCK E.                            F2E09890
       TRA     AC190                                                    F2E09900
AC190  LXD     AX,1                 IF ALL SUBS HAVE NOT BEEN           F2E09910
       TIX     AC166,1,1            CONSIDERED FOR TXIS, TAKE NEXT RT.  F2E09920
       LXA     L(3),1               THIS REPRESENTS END OF              F2E09930
AC200  SXD     AX,1                 TXI PHASE, START TIX.               F2E09940
       CLA     WRKTGA               ISOLATE APP. TGTG ENTRY.            F2E09950
AC210  TNX     AC214+1,1,1                                              F2E09960
       ARS     6                                                        F2E09970
AC214  TRA     AC210                                                    F2E09980
       ANA     6ONESR                                                   F2E09990
       TZE     AC236                IS THERE A TIX VAR. DEC. LOC.       F2E10000
       ALS     3                    YES, STORE TIX REL. LOC.            F2E10010
       STO     TETLOC               IN TETLOC WORD.                     F2E10020
       LXD     AX,1                                                     F2E10030
       CLA     TAG2+3,1             ISOLATE                             F2E10040
       PDX     0,2                  N3 FOR                              F2E10050
ACI21  CLA     DOTAGZ+4,2           THIS DO.                            F2E10060
       SUB     L(1)                 DOES N3 = 1.                        F2E10070
       TZE     AC220+2                                                  F2E10080
       TSX     XORO,4               NO, PLACE N SYMBOLS                 F2E10090
       LXA     L(6),1               IN APPROP. ORO LOCS                 F2E10100
       LXD     AX,2                 AND COMPUTE                         F2E10110
AC220  CLA     KTX00+3,2            X QUANTITY                          F2E10120
       TSX     LXC,4                ON O.C. LEVEL.                      F2E10130
       LXD     AX,1                                                     F2E10140
       CLA     INST4                TRA AC224. MODIFY ADRO              F2E10150
       STO     AORO30               ROUTINE TO COMPUTE G.               F2E10160
       CLA     INST5                TRAAC228.                           F2E10170
       STO     AORO40                                                   F2E10180
       TSX     AORO,4               COMPUTE G, PUT IN ORO+19.           F2E10190
AC224  TRA     AC230                G1 = 1.                             F2E10200
AC228  LXD     AX,1                 G1 NOT = 1,                         F2E10210
       CLA     TAG2+3,1             COMPILE INSTRUCTIONS                F2E10220
       PDX     0,2                  TO COMPUTE AND INITIALIZE           F2E10230
       CLA     DOTAGZ+4,2           TIX DECREMENT.                      F2E10240
       SUB     L(1)                                                     F2E10250
       TNZ     AC228I               N3 NOT = 1.                         F2E10260
       CLA     DOTAGZ+2,2           N3 = 1, DOES                        F2E10270
       SUB     L(1)                 N1 = 1.                             F2E10280
       TNZ     ACI22                N1 NOT = 1.                         F2E10290
       CLA     DOTAGZ+3,2           N3, N1=1.                           F2E10300
       STO     ORO00                G GREATER THAN 1.                   F2E10310
       CLA     K1AORO                                                   F2E10320
       LXA     L(4),1                                                   F2E10330
       TSX     LXC,4                                                    F2E10340
       TRA     AC234                EXIT TIX INITIALIZATION.            F2E10350
ACI22  TSX     OP3,4                N3= 1, N1 NOT = 1,                  F2E10360
       CLA     L(ADD)               COMPILE                             F2E10370
       STO     CIL01                TIX                                 F2E10380
       CLA     ORO00+13             INITIALIZATION                      F2E10390
       PAX     0,1                  GROUP                               F2E10400
       ANA     6ONES                FOR                                 F2E10410
       STO     CIL02                THIS                                F2E10420
       SXD     CIL03,1              CASE.                               F2E10430
       TSX     CIT,4                                                    F2E10440
       CLA     L(STO)                                                   F2E10450
       STO     CIL01                                                    F2E10460
       CLA     L(0)                                                     F2E10470
       STO     CIL03                                                    F2E10480
       CLA     ORO00+26             ERASEABLE STORAGE                   F2E10490
       PAX     0,4                  SYMBOL FOR ADDRESS.                 F2E10500
       ANA     6ONES                                                    F2E10510
       STO     CIL02                                                    F2E10520
       SXD     CIL03,4                                                  F2E10530
       TSX     CIT,4                                                    F2E10540
       CLA     ORO00+26             PLACE ERASEABLE SYMBOL              F2E10550
       STO     ORO00                IN ORO00 FOR LXC BLOCK.             F2E10560
       LXA     L(4),1                                                   F2E10570
       CLA     K1AORO                                                   F2E10580
       TSX     LXC,4                                                    F2E10590
       TRA     AC234                EXIT TIX INITIALIZATION.            F2E10600
AC228I LXA     L(4),1                                                   F2E10610
       CLA     LTX040               COMPILE TIX INITIALIZATION          F2E10620
       TSX     LXC,4                GROUP FOR THIS CASE.                F2E10630
       TRA     AC234                EXIT TIX INITIALIZATION.            F2E10640
AC230  LXD     AX,1                 G=1,                                F2E10650
       CLA     TAG2+3,1             DOES                                F2E10660
       PDX     0,2                  N3 = 1.                             F2E10670
       CLA     DOTAGZ+4,2                                               F2E10680
       SUB     L(1)                                                     F2E10690
       TNZ     AC230I               NO.                                 F2E10700
       CLA     DOTAGZ+2,2           YES, DOES N1= 1.                    F2E10710
       SUB     L(1)                                                     F2E10720
       TNZ     ACI23                NO.                                 F2E10730
       CLA     DOTAGZ+3,2           G,N3,N1 = 1,                        F2E10740
       STO     ORO00                COMPILE TIX                         F2E10750
       CLA     K2AORO               INITIALIZATION                      F2E10760
       LXA     L(2),1               FOR THIS                            F2E10770
       TSX     LXC,4                CASE.                               F2E10780
       TRA     AC234                EXIT TIX INITIALIZATION.            F2E10790
ACI23  TSX     OP3,4                N3=1, N1 NOT = 1.                   F2E10800
       CLA     L(ADD)               COMPILE                             F2E10810
       STO     CIL01                TIX                                 F2E10820
       CLA     ORO00+13             INITIALIZATION                      F2E10830
       PAX     0,1                  FOR                                 F2E10840
       ANA     6ONES                THIS                                F2E10850
       STO     CIL02                CASE.                               F2E10860
       SXD     CIL03,1                                                  F2E10870
       TSX     CIT,4                                                    F2E10880
       CLA     K3AORO                                                   F2E10890
       LXA     L(1),1                                                   F2E10900
       TSX     LXC,4                                                    F2E10910
       TRA     AC234                EXIT TIX INITIALIZATION.            F2E10920
AC230I LXA     L(2),1               G =1, N3 NOT = 1.                   F2E10930
       CLA     LTX042                                                   F2E10940
       TSX     LXC,4                THIS CASE.                          F2E10950
AC234  CLA     INST3                RESET MODIFIED AORO.                F2E10960
       STO     AORO30               LXC L(4),1.                         F2E10970
       CLA     INST2                                                    F2E10980
       STO     AORO40               LXD L(2),1.                         F2E10990
AC236  LXD     AX,1                                                     F2E11000
       TIX     AC200,1,1                                                F2E11010
AC240  TRA     AC010                                                    F2E11020
       LXA     LADMX,2              START ADTG COMPILING.               F2E11030
       TXI     AC240+3,2,4                                              F2E11040
       SXD     XTG,2                                                    F2E11050
       CLA     INST8                L(TRA AC244).                       F2E11060
       STA     AC240                MODIFY RETURN FOR ADTG ENTRY.       F2E11070
       STA     AC016                                                    F2E11080
       CLA     INST10                                                   F2E11090
       STA     AC165+3                                                  F2E11100
AC244  TSX     ADTGSE,4             FIND VALID ADTG ENTRY.              F2E11110
       TRA     AC250                END OF TABLE , GET NEXT DO.         F2E11120
AC248  TXL     AC014,,0             VALID ENTRY, CONTINUE AC CYCLE.     F2E11130
AC250  CLA     INST11               REINITIALIZE INSTRUCTIONS           F2E11140
       STA     AC240                MODIFIED FOR                        F2E11150
       STA     AC016                DRUMTAG                             F2E11160
       CLA     INST12               CYCLE.                              F2E11170
       STA     AC165+3                                                  F2E11180
       CLA     LOCIND               IF NO INSTRUCTIONS HAVE BEEN        F2E11190
       TZE     AC260                COMPILED FOR THIS ALPHA,            F2E11200
       CLA     L(BSS)                                                   F2E11210
       STO     CIL01                INSURES THAT THE EXTERNAL           F2E11220
       CLA     A                    ALPHA WILL HAVE A CORRESPON-        F2E11230
       STO     CIL00                DING INTERNAL ALPHA.                F2E11240
       STZ     CIL02                                                    F2E11250
       STZ     CIL03                                                    F2E11260
       TSX     CIT,4                                                    F2E11270
AC260  LXD     AC248,4                                                  F2E11280
       TRA     1,4                  EXIT ALPHA CYCLE                    F2E11290
       REM *************************************************************F2E11300
       REM DOGS IS CALLED BY MAN TO SELECT AN ALPHA OR BETA TO BE PRO   F2E11310
       REM CESSED BY THE APPROPRIATE STATE (ALPHA OR BETA).             F2E11320
DOGS   CLA     L(0)                 INITIALIZING TO ZERO                F2E11330
       STO     A                    ALL CALLS REQUIRED FOR              F2E11340
       STO     B                    COMPARISON FOR EACH DO              F2E11350
       STO     SWICH                                                    F2E11360
       STO     TEBBOX                                                   F2E11370
       LXD     DOIND1,1             IF LEVEL OF LAST                    F2E11380
       TXL     DOGS20,1,0                                               F2E11390
       CLA     SWICH1                                                   F2E11400
       TNZ     DOGS20                                                   F2E11410
       CLA     DOTAGZ+5,1           ANALYZED DOTAG ENTRY                F2E11420
       PDX     0,1                  IS ONE THEN THE NEST                F2E11430
       TXH     DOGS20,1,1           HAS BEEN COMPLETELY                 F2E11440
       TRA     1,4                  ANALYZED. IF NOT                    F2E11450
DOGS20 LXA     LMXDTG,1             START SCAN AT FIRST ENTRY           F2E11460
DOGS22 CLA     SWICH                                                    F2E11470
       TNZ     DOGS25               B PORTION UNDER CONSIDERATION       F2E11480
       CLA     DOTAGZ,1             A PORTION UNDER CONSIDERATION       F2E11490
       ANA     BIT1                                                     F2E11500
       TNZ     DOGS50               CONTINUE, ALREADY ANALYZED          F2E11510
       CLA     DOTAGZ,1             SETS UP A PORTION OF                F2E11520
       PDX     0,2                  DO FOR COMPARISON                   F2E11530
       SXD     B,2                  PUT A OF DO IN INDICATOR B          F2E11540
       TRA     DOGS30               PROCEED T/ COMPARISON               F2E11550
DOGS25 CLA     DOTAGZ,1             B PORTION UNDER CONSIDERATION       F2E11560
       ANA     BIT2                 MASK TO INDICATE LOOKED AT          F2E11570
       TNZ     DOGS50               ALREADY ANALYZED, CONTINUE          F2E11580
       CLA     DOTAGZ,1             SET UP A IN                         F2E11590
       PDX     0,2                  B WORD FOR COMPARISON               F2E11600
       SXD     A,2                                                      F2E11610
       PAX     0,2                                                      F2E11620
       SXD     B,2                                                      F2E11630
DOGS30 CLA     B                                                        F2E11640
       CAS     TEBBOX                                                   F2E11650
       TRA     DOGS45               T-B1 STORE B IN TEBBOX              F2E11660
       TRA     DOGS40               T=B1 COMPARE AS                     F2E11670
       TRA     DOGS50               T-B1 CONTINUE                       F2E11680
DOGS40 CLA     TEABOX               CONPARE AS                          F2E11690
       CAS     A                                                        F2E11700
       TRA     DOGS50               T-A CONTINUE                        F2E11710
       TSX     ERRORM,4             TEABOX(IFN OF PRECEDING DO)         F2E11720
       REM                          SHOULD NOT EQUAL A (IFN OF          F2E11730
       REM                          SUCCEEDING DO).                     F2E11740
DOGS45 CLA     A                    T-A STORE B IN TRBBOX               F2E11750
       STO     TEABOX                                                   F2E11760
       CLA     B                                                        F2E11770
       STO     TEBBOX                                                   F2E11780
       SXD     DOIND1,1             RECORD THE DO POSITION              F2E11790
       CLA     SWICH                RECORD SWITCH                       F2E11800
       STO     SWICH1                                                   F2E11810
DOGS50 CLA     SWICH                REVERSE SWITCH FOR                  F2E11820
       SUB     L(1)                 EITHER B OF SAME DO OR              F2E11830
       SSP                          A OF NEXT DO                        F2E11840
       STO     SWICH                                                    F2E11850
       TNZ     DOGS60               TESTS A,B STATUS IF A               F2E11860
       TXI     DOGS60,1,-9          LOWERS INDEX FOR NEXT DO            F2E11870
DOGS60 TXH     DOGS22,1,0                                               F2E11880
       LXD     DOIND1,1             END OF SCAN                         F2E11890
       SXD     DOIND,1              DO INDICATOR SET                    F2E11900
       LXA     SWICH1,2                                                 F2E11910
       CLA     BIT1                 ORDER TO PLACE BIT IN               F2E11920
       TXL     DOGS70,2,0           A OR B USED                         F2E11930
       ARS     1                    INDICATOR POSITION                  F2E11940
DOGS70 ORS     DOTAGZ,1                                                 F2E11950
       TRA     2,4                  EXIT AFTER FINDING DO               F2E11960
       REM *************************************************************F2E11970
       REM SCAN SCANS TAGTAG FOR THE FIRST ENTRY THAT IS MODIFIED BY A DF2E11980
       REM DO WHOSE ALLPHA IS LESS THAT THE CURRENT DOTAG BETA.         F2E11990
       REM THIS TAG IS CALLED RTXTGX.                                   F2E12000
SCAN   LXD     FNEST,1              COMPARE B WITH DOFOR                F2E12010
SCAN05 CLA     B                    DOTAG A OF EACH TAGTAG              F2E12020
       CAS     TAGZ,1               ENTRY IN NEST.                      F2E12030
       TXI     SCAN10,1,4           SEARCH COMPLETED.                   F2E12040
       TSX     ERRORM,4             THE IFN IN B(FROM CURRENT           F2E12050
       REM                          DOTAG ENTRY) SHOULD NOT BE          F2E12060
       REM                          EQUAL TO THE FIRST WORD             F2E12070
       REM                          OF XR1 TAGTAG ENTRY. TAGTAG IS      F2E12080
       REM                          FROM FILE 2 TAPE 4.                 F2E12090
       TXI     SCAN05,1,-4          G LESS THAN A.                      F2E12100
SCAN10 TRA     1,4                                                      F2E12110
       REM *************************************************************F2E12120
       REM FIND, BEGINNING WITH RTXTGX, SEARCHES FOR A TAGTAG ENTRY MODIF2E12130
       REM FIED BY THE CURRENT DO.                                      F2E12140
FIND   SXD     FIND22,4                                                 F2E12150
       LXD     XTG,1                                                    F2E12160
FIND04 TXI     FIND10,1,-4          BUMP TO NEXT TGTG ENTRY.            F2E12170
FIND10 TXH     FIND20,1,0           DEC CONTAINS TAGTAG COUNT.          F2E12180
       LXD     FIND22,4                                                 F2E12190
       TRA     1,4                  END OF TGTG TABLE AND DO.           F2E12200
FIND20 CLA     A                    COMPARE DOTAGA WITH                 F2E12210
       CAS     TAGZ,1               TGTG DOFOR DOTAG A.                 F2E12220
       TRA     FIND10+1             END OF DO.                          F2E12230
       NOP                                                              F2E12240
       TSX     TGFM,4                                                   F2E12250
       TSX     ISC,4                                                    F2E12260
FIND22 TXL     FIND04,,0            POSIND=3 IF LEFTMOST SYMBOL.        F2E12270
       PXD     0,2                  2IF CENTER.                         F2E12280
       ARS     18                   1 IF RIGHTMOST.                     F2E12290
       STO     POSIND                                                   F2E12300
       LXD     FIND22,4                                                 F2E12310
       TRA     2,4                  SUCCESSFUL SEARCH.                  F2E12320
       REM *************************************************************F2E12330
       REM ISC IS CALLED BY FIND TO TEST FOR MODIFICATION.              F2E12340
ISC    LXA     L(1),2               COMPARE SUBSCRIPT                   F2E12350
       CLA     DOIND                WITH THE INDEX                      F2E12360
       SUB     TAG2+3,2             OF THE CURRENT DO.                  F2E12370
       TZE     2,4                  CURRENT DO MODIFIES THIS TAG.       F2E12380
       TXI     ISC+5,2,1            TRY NEXT LEFT                       F2E12390
       TXL     ISC+1,2,3            SUBSCRIPT.                          F2E12400
       TRA     1,4                  NO MODIFICATION, ERROR RETURN.      F2E12410
       REM *************************************************************F2E12420
       REM TGFM TAKES A TAG ENTRY AND STORES ITS INFORMATION INTO       F2E12430
       REM WORKING TGTG.                                                F2E12440
TGFM   CLA     TAGZ,1                                                   F2E12450
       STD     TAG1                 IN WORKING TGTG.                    F2E12460
       PAX     0,2                  A, X1, X2, X3, TG, TG1.             F2E12470
       SXD     TAG2,2                                                   F2E12480
       CLA     TAGZ+1,1                                                 F2E12490
       STD     TAG2+1                                                   F2E12500
       PAX     0,2                                                      F2E12510
       SXD     TAG2+2,2                                                 F2E12520
       CLA     TAGZ+2,1                                                 F2E12530
       STO     TAG3                                                     F2E12540
       CLA     TAGZ+3,1                                                 F2E12550
       STO     TAG4                                                     F2E12560
       TRA     1,4                                                      F2E12570
       REM *************************************************************F2E12580
       REM ENTR SIMJLATES A TAU ENTRY AND SPREADS IS INTO WORKING TAG--(F2E12590
ENTR   LXD     DOIND,2              SYMBOL OF DO IS                     F2E12600
       CLA     DOTAGZ+1,2           PLACED IN WRKSC                     F2E12610
       STO     $WRKSC+1             AND COEF. IS SET                    F2E12620
       CLA     $L1DEC               =1. THIS SIMULATES                  F2E12630
       STO     $WRKSC               A TAU TABLE ENTRY.                  F2E12640
       TRA     1,4                                                      F2E12650
       REM *************************************************************F2E12660
       REM LOCO ASSIGNS A RELATIVE LOCATION (INSTRUCTION NUMBER), AND UPF2E12670
       REM DATES A COUNTER FOR THE NEXT ASSIGNMENT.                     F2E12680
LOCO   CLA     LOCIND                                                   F2E12690
       TZE     1,2                  LOCATION ALREADY ASSIGNED.          F2E12700
       CLA     L(0)                 IF LOCIND GREATER                   F2E12710
       STO     LOCIND                                                   F2E12720
       CLA     CIL00                TO ZERO.                            F2E12730
       TNZ     1,2                  IF CIL00 HAS NOT BEEN               F2E12740
       CLA     VCTR                                                     F2E12750
       STO     CIL00                UPDATE VCTR.                        F2E12760
       ADD     $L(8)                                                    F2E12770
       STO     VCTR                                                     F2E12780
       TRA     1,2                  START COMPARING BUFFER              F2E12790
       REM *************************************************************F2E12800
       REM SCLMN1 ISOLATES THE INNERMOST DOTAG CONTROLLING A GIVEN TAG. F2E12810
SCLMN1 LXD     TAG2,1               S1 INDEX QUANTITY.                  F2E12820
       LXD     TAG2+1,2             S2 INDEX QUANTITY.                  F2E12830
       SXD     SCLMN2,2             THIS ROUTINE                        F2E12840
SCLMN2 TXH     SCLMN3,1,0           COMPARES SIZES                      F2E12850
       LXD     SCLMN2,1             OF THE INDEX                        F2E12860
SCLMN3 LXD     TAG2+2,2             QUANTITIES OF                       F2E12870
       SXD     SCLMN4,2             EACH SUBSCRIPT IN A TAG.            F2E12880
SCLMN4 TXH     SCLMN5,1,0           LARGEST 2.X. QUANTITY               F2E12890
       LXD     SCLMN4,1             IS FOUND AND LEFT IN                F2E12900
SCLMN5 PXD     0,1                  ACC FOR COMPARISON WITH DOIND.      F2E12910
       TRA     1,4                                                      F2E12920
       REM *************************************************************F2E12930
       REM TELC MONITORS THE COMPUTING OF THE LOAD PORTION OF THE TEST  F2E12940
       REM DECREMENT.                                                   F2E12950
TELC   LXA     $L(3),1                                                  F2E12960
       CLA     L(0)                                                     F2E12970
       STO     ERTX01                                                   F2E12980
       SXD     $LINKC,4                                                 F2E12990
TELC05 CLA     TAG2+3,1             SEQUENCE.  PUT S IN XB TO PREPARE   F2E13000
       PDX     0,2                  FOR CN1IJ ROUTINE.                  F2E13010
       TXL     TELC10-2,2,0         NO S, GO TO NEXT S.                 F2E13020
       TSX     CN1IJ,4              COMPUTE (CN1-1)IJ ETC.              F2E13030
       ADD     ERTX01                                                   F2E13040
       STO     ERTX01               (C1N1)+(C2N1-1)D1+(C3N1-1)D1D2.     F2E13050
TELC10 TIX     TELC05,1,1           GO TO NEXT S FOR CN1IJ ROUTINE.     F2E13060
       LXD     $LINKC,4                                                 F2E13070
       TRA     1,4                                                      F2E13080
       REM *************************************************************F2E13090
       REM CN1IJ COMPUTES THE LOAD VALUE FOR A GIVEN SUBSCRIPT IN A     F2E13100
       REM SUBSCRIPT COMBINATION. (C1N1-1), OR (C2N1-1)D1               F2E13110
       REM (C3N1-1)D1D2.                                                F2E13120
CN1IJ  LDQ     DOTAGZ+2,2           N2 INTO MQ.                         F2E13130
       LLS     18                                                       F2E13140
       TXL     CN1IJ2,1,2           S2 OR S3, TRANSFER.                 F2E13150
       MPY     $WRKSC               S1,                                 F2E13160
       SUB     L(2)                                                     F2E13170
       TRA     CN1IJ8                                                   F2E13180
CN1IJ2 TXL     CN1IJ4,1,1           DIVIDE BY 2 AND RETURN.             F2E13190
       MPY     $WRKSC+2             S2                                  F2E13200
       SUB     L(2)                 COMPUTE                             F2E13210
       LRS     18                   (2C2N1-2)D1D2 THEN                  F2E13220
       MPY     $WRKSC+6             GO TO CN1IJ8 TO DIVIDE              F2E13230
       TRA     CN1IJ8               BY 2 AND RETURN.                    F2E13240
CN1IJ4 MPY     $WRKSC+4             S3,                                 F2E13250
       SUB     L(2)                 COMPUTE                             F2E13260
       LRS     18                   (2C3N1-2)D1D2 THEN                  F2E13270
       MPY     $WRKSC+6             GO TO CN1IJ8 TO DIVIDE              F2E13280
       LRS     18                   DIVIDE BY 2 AND                     F2E13290
       MPY     $WRKSC+7             RETURN.                             F2E13300
CN1IJ8 ARS     1                    DIVIDE BY 2.  RESULT IS (C1N1-1)    F2E13310
       TRA     1,4                  OR (C2N1-1)D1 OR (C3N1-1)D1D2.      F2E13320
       REM *************************************************************F2E13330
       REM CXIJ COMPUTES GN3X.  WHEN THE ROUTINE CXIJ+2 IS CALLED,      F2E13340
       REM GQ IS COMPUTED, Q BEING WHATEVER PARAMETER IS LEFT IN THE ACCF2E13350
       REM BY THE CALLER.                                               F2E13360
XMIN1  CLA     DOTAGZ+5,2                                               F2E13370
       ANA     ADMSK                                                    F2E13380
       SUB     DOTAGZ+4,2                                               F2E13390
       TRA     CXIJ+2                                                   F2E13400
CXIJ   CLA     DOTAGZ+5,2                                               F2E13410
       ANA     ADMSK                ISOLATE X QUANTITY.                 F2E13420
       STO     ERTX03                                                   F2E13430
       TXH     CXIJ+6,1,1           S2 OR S1.                           F2E13440
       LDQ     $WRKSC+4             S3, LOAD C3                         F2E13450
       TRA     CXIJ2                                                    F2E13460
       TXL     CXIJ1,1,2            S2.                                 F2E13470
       LDQ     $WRKSC               S1, LOAD C1.                        F2E13480
       TRA     CXIJ2                                                    F2E13490
CXIJ1  LDQ     $WRKSC+2             S2, LOAD C1.                        F2E13500
CXIJ2  MPY     ERTX03                                                   F2E13510
       TXH     CXIJ4,1,2            IF S1, FINISHED.                    F2E13520
       LRS     18                                                       F2E13530
       MPY     $WRKSC+6             CX TIMES D1.                        F2E13540
       TXH     CXIJ4,1,1            IF S2, FINISHED.                    F2E13550
       LRS     18                                                       F2E13560
       MPY     $WRKSC+7             CXD1 TIMES D2.                      F2E13570
CXIJ4  LLS     17                                                       F2E13580
       TRA     1,4                  IN ACC. AND RETURN.                 F2E13590
       REM *************************************************************F2E13600
       REM CSXD COMPILES AN SXD INSTRUCTION WHERE THE ADDRESS IS NOT YETF2E13610
       REM KNOWN, BUT IS KNOWN TO BE THE TEST FOR A GIVEN DO.  THE      F2E13620
       REM ADDRESS WORD IS FILLED IN WITH THAT DOTAG ALPHA-BETA AND THE F2E13630
       REM LOCATION OF THE SXD IS STORED IN THAT DOTAG SO THAT A TABLE (F2E13640
       REM (SXDTX) MAY BE MADE FOR REFERENCE BY SECTION 3 TO FILL IN THEF2E13650
       REM PROPER ADDRESS DURING MERGE.                                 F2E13660
CSXD   SXD     ERTX01,4             ROUTINE FOR                         F2E13670
       TSX     CILV,4               COMPILING AN                        F2E13680
       CLA     L(0)                 SXD INSTRUCTION                     F2E13690
       STO     CIL03                WHERE THE                           F2E13700
       STO     CIL02                                                    F2E13710
       LXD     BLKNUM,4                                                 F2E13720
       TXL     CSXD4,4,2            BLOCKS B,C.                         F2E13730
       LXD     TAG21,4              BLOCKS D,E, LOAD S2 INDEX.          F2E13740
       TRA     CSXD4+1                                                  F2E13750
CSXD4  LXD     TAG2,4               BLOCKS B,C, LOAD S1 INDEX.          F2E13760
       CLA     DOTAGZ,4             FOR BLOCKS B,C, FILL IN             F2E13770
       ANA     NOPRET               SYMBOLIC ADDRESS OF SXD             F2E13780
       STO     CIL02                FROM WD1 OF S1 DOTAG.               F2E13790
       CLA     TAG3                 NOT KNOWN.                          F2E13800
       STA     CIL03                                                    F2E13810
       CLA     L(SXD)                                                   F2E13820
       STO     CIL01                                                    F2E13830
       TSX     CIT,4                                                    F2E13840
       LXD     ERTX01,4                                                 F2E13850
       TRA     1,4                                                      F2E13860
       REM *************************************************************F2E13870
       REM ADTGSE FINDS A VALID DRMTG (ADTAG) ENTRY FOR CONSIDERATION   F2E13880
       REM AND SPREADS IT INTO WORKING TAG (WRKSC).                     F2E13890
ADTGSE LXD     XTG,1                                                    F2E13900
ADTGS  TXI     ADTGS+1,1,-4                                             F2E13910
       SXD     XTG,1                                                    F2E13920
ADTGS1 TXH     ADTGS5,1,0                                               F2E13930
       TRA     1,4                  END OF TABLE.                       F2E13940
ADTGS5 CLA     ADTGMX,1             COMPARE ADTG DDA WITH               F2E13950
       ANA     DECMSK               DOTAG A AND B UNTIL                 F2E13960
       CAS     A                    WE FIND AN ADTAG                    F2E13970
       TRA     ADTGS4               MODIFIED BY A DO THAT               F2E13980
       TRA     ADTGS4               IS WITHIN THE RANGE                 F2E13990
       TRA     ADTGS                OF THE CURRENT DO                   F2E14000
ADTGS4 CAS     B                                                        F2E14010
       TRA     ADTGS                NOT IN RANGE, SELECT NEXT.          F2E14020
       TSX     ERRORM,4             THE IFN IN B(FROM CURRENT           F2E14030
       REM                          DOTAG ENTRY) SHOULD NOT BE          F2E14040
       REM                          EQUAL TO THE XR1 VALUE OF           F2E14050
       REM                          ADTAG.                              F2E14060
       CLA     ADTGMX,1             IN RANGE, FILL                      F2E14070
       PDX     0,2                  OUT WORKING TAG.                    F2E14080
       SXD     TAG1,2               DDA IN TAG1 DECREMENT.              F2E14090
       PAX     0,2                                                      F2E14100
       SXD     TAG2,2               S1 INDEX IN TAG2.                   F2E14110
       CLA     ADTGMX+1,1                                               F2E14120
       PDX     0,2                                                      F2E14130
       SXD     TAG2+1,2             S2 INDEX IN TAG2+1                  F2E14140
       PAX     0,2                                                      F2E14150
       SXD     TAG2+2,2             S3 INDEX IN TAG2+2.                 F2E14160
       CLA     ADTGMX+2,1                                               F2E14170
       STO     TAG3                 TAG NAME IN TAG3.                   F2E14180
       CLA     ADTGMX+3,1                                               F2E14190
       STO     TAG4                 ADTG WD4 IN TAG4.                   F2E14200
ADTGS8 LXA     L(1),2               INIT FOR POSING.                    F2E14210
       CLA     TAG2+3,2                                                 F2E14220
       SUB     DOIND                TEST FOR MODIFICATION.              F2E14230
       TZE     2,4                  PROPER ENTRY FOUND.                 F2E14240
       TXH     ADTGS,2,2            NOT MOD BY DO, TAKE NEXT SUBSCRIPT. F2E14250
       TXI     ADTGS8+1,2,1         ADTG NOT MOD BY DO, TAKE NEXT ADTG. F2E14260
       REM *************************************************************F2E14270
       REM N1STET ISOLATES VARIABLE N1 BITS FOR A TAG AND ORS THEM TO  LF2E14280
       REM LAST 3 BITS OF THE WORD N1SBX.                               F2E14290
N1STET CLA     TAG4                                                     F2E14300
       ARS     3                    ONE BIT                             F2E14310
       ANA     L(7)                 IS STORED IN N1SBX.                 F2E14320
       ALS     3                                                        F2E14330
       STO     N1SBX                                                    F2E14340
       LXA     $L(3),1                                                  F2E14350
N1S02  CLA     TAG2+3,1             A CONATAINS POSIND.                 F2E14360
       PDX     0,2                                                      F2E14370
       TXL     N1S05,2,0            NO TAG FOR THIS POS.                F2E14380
       CLA     DOTAGZ,2             ISOLATE                             F2E14390
       ARS     15                   VARIABLE                            F2E14400
       ANA     L(4)                 N1                                  F2E14410
       ARS     3,1                  BIT.                                F2E14420
       ORS     N1SBX                OR N1BIT TO N1SBX.                  F2E14430
N1S05  TIX     N1S02,1,1            REPEAT FOR NEXT RIGHT S.            F2E14440
       CLA     N1SBX                                                    F2E14450
       TRA     1,4                                                      F2E14460
       REM *************************************************************F2E14470
       REM OP2 IS CALLED BY THE ALPHA STATE TO TEST FOR OPTIMIZATION IN F2E14480
       REM THE COMILATION OF LOAD VALUE COMPUTATION.  IT OPTIMIZES WHEN F2E14490
       REM (CN1-1)=0 OR IS COMPUTABLE AT EXECUTIVE TIME.                F2E14500
OP2    CLA     32766,4                                                  F2E14510
       STA     RETURN               LINKAGE.                            F2E14520
       CLA     TAG2+3,1             IF S IS NOT                         F2E14530
       PDX     0,2                  DEFINED BY A DO,                    F2E14540
       TXH     OP2P,2,0                                                 F2E14550
       TRA     1,4                                                      F2E14560
OP2P   CLA     DOTAGZ+2,2           IF NOT DEFINED BY                   F2E14570
       ANA     6ONES                                                    F2E14580
       TNZ     1,4                  RETURN TO MAIN ROUTINE.             F2E14590
       CLA     DOTAGZ+2,2           IF CONSTANT, COMPUTE                F2E14600
       TSX     CN1IJ,4                                                  F2E14610
       TZE     RETURN               RETURN AND CONSIDER S2.             F2E14620
       ALS     18                   OTHERWISE COMPUTE                   F2E14630
       TXL     OP2P1,1,2                                                F2E14640
       ADD     $L1DEC               TO (CN1-1).                         F2E14650
OP2P1  TSX     $FXCON,4                                                 F2E14660
       TXL     OP2P2,1,2                                                F2E14670
       STO     ORO00+1                                                  F2E14680
       TIX     AC050,1,1                                                F2E14690
OP2P2  PAX     0,1                                                      F2E14700
       ANA     6ONES                ASSIGN FIXCON SYMBOL.               F2E14710
       STO     CIL02                CHECK SUBSCRIPT. IF                 F2E14720
       PXD     0,1                  S1, TRA RETURN (3RD).  OTHERWISE    F2E14730
       STO     CIL03                COMPILE ADD L(SYMBOL).              F2E14740
       CLA     L(ADD)               STO 1)+3.                           F2E14750
       STO     CIL01                                                    F2E14760
       CLA     L(0)                                                     F2E14770
       STO     CIL00                                                    F2E14780
       LXD     BBOX,1                                                   F2E14790
       TXI     OP24,1,4                                                 F2E14800
OP24   SXD     BBOX,1                                                   F2E14810
       TSX     CIT,4                                                    F2E14820
       CLA     L(STO)                                                   F2E14830
       STO     CIL01                                                    F2E14840
       CLA     L3DEC                                                    F2E14850
       STO     CIL03                                                    F2E14860
       CLA     ORO00+26                                                 F2E14870
       ANA     6ONES                                                    F2E14880
       STO     CIL02                                                    F2E14890
       TSX     CIT,4                                                    F2E14900
RETURN TRA     0                    ADDRESS MODIFIED.                   F2E14910
       REM *************************************************************F2E14920
       REM OP3 TESTS  FOR VARIABLE NS AND IF CONSTANT COMPILES A        F2E14930
       REM CLA L(N2-N1), OR IF VARIABLE CLA L(N2)....SUBL(N1).          F2E14940
OP3    SXD     EROP3,4                                                  F2E14950
       CLA     DOTAGZ,2             ARE ALL                             F2E14960
       ARS     15                   N PARAMETERS                        F2E14970
       ANA     L(7)                 CONSTANT.                           F2E14980
       TNZ     OP31                 NO, OP31.                           F2E14990
       CLA     DOTAGZ+3,2           YES,                                F2E15000
       SUB     DOTAGZ+2,2           FORM                                F2E15010
       ALS     18                   N2-N1.                              F2E15020
       TSX     $FXCON,4             OBTAIN FIXCON SYMBOL.               F2E15030
       PAX     0,4                  COMPILE                             F2E15040
       ANA     6ONES                CLA                                 F2E15050
       STO     CIL02                L(N2-N1)                            F2E15060
       PXD     0,4                  AND                                 F2E15070
       STO     CIL03                RETURN                              F2E15080
       CLA     L(CLA)               TO                                  F2E15090
       STO     CIL01                THE                                 F2E15100
       CLA     L(0)                 CALLER.                             F2E15110
       STO     CIL00                ZERO LOCATION.                      F2E15120
       TSX     CIT,4                                                    F2E15130
       LXD     EROP3,4                                                  F2E15140
       TRA     1,4                                                      F2E15150
OP31   ARS     1                                                        F2E15160
       LBT                                                              F2E15170
       TRA     OP32                                                     F2E15180
       CLA     DOTAGZ+3,2           N2 VARIABLE,                        F2E15190
       STO     CIL02                COMPILE                             F2E15200
       CLA     L(0)                 CLA L(N2).                          F2E15210
       STO     CIL03                                                    F2E15220
       TRA     OP33                                                     F2E15230
OP32   CLA     DOTAGZ+3,2                                               F2E15240
       ALS     18                                                       F2E15250
       TSX     $FXCON,4                                                 F2E15260
       PAX     0,4                                                      F2E15270
       ANA     6ONES                                                    F2E15280
       STO     CIL02                                                    F2E15290
       PXD     0,4                                                      F2E15300
       STO     CIL03                                                    F2E15310
OP33   CLA     L(0)                                                     F2E15320
       STO     CIL00                                                    F2E15330
       CLA     L(CLA)                                                   F2E15340
       STO     CIL01                                                    F2E15350
       TSX     CIT,4                                                    F2E15360
       CLA     DOTAGZ,2                                                 F2E15370
       ARS     17                                                       F2E15380
       LBT                                                              F2E15390
       TRA     OP34                                                     F2E15400
       CLA     DOTAGZ+2,2           N1IS VARIABLE,                      F2E15410
       STO     CIL02                PREPARE TO                          F2E15420
       CLA     L(0)                 COMPILE                             F2E15430
       STO     CIL03                SUBL(N1).                           F2E15440
       TRA     OP35                                                     F2E15450
OP34   CLA     DOTAGZ+2,2           N1 CONSTANT,                        F2E15460
       ALS     18                   OBTAIN                              F2E15470
       TSX     $FXCON,4             FIXCON SYMBOL                       F2E15480
       PAX     0,4                  FOR N1                              F2E15490
       ANA     6ONES                AND PREPARE                         F2E15500
       STO     CIL02                TO COMPILE                          F2E15510
       SXD     CIL03,4              SUB L(N1).                          F2E15520
OP35   CLA     L(SUB)               COMPILE                             F2E15530
       STO     CIL01                SUB                                 F2E15540
       TSX     CIT,4                L(N1)                               F2E15550
       LXD     EROP3,4                                                  F2E15560
       TRA     1,4                                                      F2E15570
       REM *************************************************************F2E15580
TTG    LXD     FIND10,1             PICK UP VALUE FOR LAST ENTRY        F2E15590
       TXI     *+1,1,-4             OF NEST AND BUMP TO VALUE FOR       F2E15600
       SXD     FNEST,1              FIRST ENTRY OF NEXT NEST.           F2E15610
TTG10  CLA     TAGZ,1               SEARCH FOR                          F2E15620
       SUB     ALLONE               END OF NEST                         F2E15630
       TZE     *+4                  FENCE.                              F2E15640
       TXI     *+1,1,-4                                                 F2E15650
       TXH     TTG10,1,0                                                F2E15660
       TSX     ERRORM,4             A FENCE OF 4 WORDS OF ALLONES       F2E15670
       REM                          SHOULD END THE TAGTAG TABLE.        F2E15680
       SXD     FIND10,1                                                 F2E15690
       TRA     1,4                                                      F2E15700
FNEST  PZE     0                                                        F2E15710
IOCOM2 IOST    TAGTG,,1000*M/N*4                                        F2E15720
       REM *************************************************************F2E15730
CIT    SXD     $E2C,4                                                   F2E15740
       SXD     $E3C,2                                                   F2E15750
       TSX     LOCO,2               CITSP PART.                         F2E15760
       LXD     BBOX,2                                                   F2E15770
       NZT     BLSW                 IF FIRST CIT OF A BLOCK,            F2E15780
       TRA     CIT02                (NOT FIRST, OMIT)                   F2E15790
       CLA     CIL00                SET SIGN                            F2E15800
       SSM                          MINUS                               F2E15810
       STO     CIL00                AND STORE.                          F2E15820
       STZ     BLSW                 RESET SIGNAL.                       F2E15830
CIT02  LXA     L(4),4               MOVE THE                            F2E15840
       CLA     CIL00+4,4            CIT                                 F2E15850
       STO     DOFILE,2             TO                                  F2E15860
       TXI     CIT04,2,-1           DOFILE                              F2E15870
CIT04  TIX     CIT02+1,4,1          BUFFER.                             F2E15880
       TXH     *+2,2,-LMXDF-1                                           F2E15890
       TSX     ERRO13,4             DOFILE IS FULL.                     F2E15900
       SXD     BBOX,2               SAVE DOFILE XR VALUE.               F2E15910
       LXD     $E3C,2                                                   F2E15920
       LXD     $E2C,4                                                   F2E15930
       TRA     1,4                                                      F2E15940
       REM *************************************************************F2E15950
       REM DF01 SORTS A NEST OF CITS AND WRITES THEM ON TAPE 4.         F2E15960
DF01   STZ     NTEST                ERASE 6AST BLOCK INDICATOR.         F2E15970
       LXD     BCNT,2               LOAD WITH VALUE FOR NEXT BUFFER.    F2E15980
       LXD     BBOX,1               LOAD WITH VALUE FOR LAST DOFILE WD. F2E15990
DF20   SXD     DF40,1               SET END OF BLOCK TEST VALUE.        F2E16000
       TXI     *+1,1,4                                                  F2E16010
       CAL     DOFILE,1             SEARCH FOR BEGINNING                F2E16020
       PBT                          OF BLOCK OF CITS.                   F2E16030
       TXI     *-2,1,4                                                  F2E16040
       STO     DOFILE,1             RESET P BIT TO ZERO IN CIT.         F2E16050
DF31   TXH     DF34,1,0             TEST FOR LAST BLOCK OF NEST.        F2E16060
       CLA     ALLONE               END OF                              F2E16070
       STO     NTEST                NEST FLAG.                          F2E16080
DF34   SXA     BLOCK,1              SAVE XR TO FIND NEXT BLOCK.         F2E16090
DF36   CLA     DOFILE,1             MOVE A WORD TO BUFFER               F2E16100
DF37   STO     BONE+CIBSZ,2         1 OR 2 (ADD. IS SWITCHED).          F2E16110
       TXI     *+1,1,-1                                                 F2E16120
       TNX     DF50,2,1             IS BUFFER FULL.                     F2E16130
DF40   TXH     DF36,1,**            TEST FOR END OF BLOCK.              F2E16140
       ZET     NTEST                TEST FOR END OF NEST.               F2E16150
       TRA     MAN50+1              END OF NEST.                        F2E16160
       LXA     BLOCK,1              END OF BLOCK. RESET XR              F2E16170
       TRA     DF20                 AND GO TO FIND NEXT BLOCK.          F2E16180
DF50   AXC     -1,2                 LOAD BUFFER INDEX.                  F2E16190
*      ***                                                              F2E16200
DF51   TSX     (TAPE),4             WRITE ONE                           F2E16210
       PZE     B1Z,2,(WBNP)         RECORD OF                           F2E16220
       PZE     CMPDOL,,FTAPE4       COMPDO CIT'S.                       F2E16230
       CLA     DSC7,2               SWITCH BUFFER                       F2E16240
       STA     DF37                 ADDRESS.                            F2E16250
       SXA     DF50,2                                                   F2E16260
       AXT     CIBSZ,2                                                  F2E16270
       TXH     DF40,1,0             IS THIS LAST BUFFER(XR1=0).         F2E16280
*      ***                                                              F2E16290
DFEXIT TSX     (TAPE),4             WRITE END OF                        F2E16300
       PZE     ,,(WEFP)             FILE                                F2E16310
       PZE     FILN2L,,FTAPE4       FOR COMPDO.                         F2E16320
*      ***                                                              F2E16330
       TSX     (TAPE),4             POSITION TAPE 2                     F2E16340
       PZE     SKLST5,,(SKBP)       FOR                                 F2E16350
       PZE     TIFL,,FTAPE2         SECTION THREE.                      F2E16360
*      ***                                                              F2E16370
       TSX     (TAPE),4             REWIND TAPE 4                       F2E16380
       PZE     REWIND,,(SKBP)       FOR                                 F2E16390
       PZE     TRLVL,,FTAPE4        SECTION THREE.                      F2E16400
*      ***                                                              F2E16410
       TSX     (LOAD),4             GO TO SECTION THREE.                F2E16420
       PZE                                                              F2E16430
DF70   CLA     DF50                 PICK UP                             F2E16440
       PAC     ,2                   BUFFER INDEX.                       F2E16450
       CLA     B1Z,2                COMPUTE WORD COUNT                  F2E16460
       ANA     DECMSK               FOR LAST BUFFER,                    F2E16470
       SUB     BCNT                 AND STORE                           F2E16480
       STD     B1Z,2                IN I/O COMMAND.                     F2E16490
       AXT     0,1                  INDICATE LAST BUFFER AND            F2E16500
       TRA     DF51                 GO TO WRITE.                        F2E16510
CMPDOL BCI     1,COMPDO                                                 F2E16520
SKLST5 MZE     9,,1                                                     F2E16530
BLOCK  PZE     0                                                        F2E16540
NTEST  PZE     0                                                        F2E16550
BLSW   PZE                                                              F2E16560
BCNT   PZE     ,,CIBSZ                                                  F2E16570
B2Z    PZE     BTWO+CIBSZ                                               F2E16580
DSC7   IORT    BONE,,CIBSZ                                              F2E16590
B1Z    PZE     BONE+CIBSZ                                               F2E16600
DSC8   IORT    BTWO,,CIBSZ                                              F2E16610
LMXDF  EQU     1000*M/N*4                                               F2E16620
       TRA     1,4                                                      F2E16630
       REM *************************************************************F2E16640
       REM CILV IS CALLED WHEN AN INSTRUCTION NUMBER IS NEEDED FOR A COMF2E16650
       REM PILED BETA STATE INSTRUCTION.                                F2E16660
CILV   CLA     VCTR                 THIS ROUTINE UPDATES                F2E16670
       STO     CIL00                VCTR AND                            F2E16680
       ADD     $L(8)                STORE INTO CIL00                    F2E16690
       STO     VCTR                 IT IS CALLED WHEN                   F2E16700
       ANA     ADMSK                WE NEED A LOCATION                  F2E16710
       SUB     MAXLOC               FOR A COMPILED                      F2E16720
       TZE     CILV1                INSTRUCTION.                        F2E16730
       TRA     1,4                                                      F2E16740
CILV1  TSX     ERRO12,4             SOURCE PROGRAM ERROR.               F2E16750
       REM *************************************************************F2E16760
       REM N3BIT PLACES THE VARIABLE N3 BIT OF A DO IN THE WORK N3IND.  F2E16770
N3BIT  LXD     DOIND,2              THIS ROUTIN E ISOLATES              F2E16780
       CLA     DOTAGZ,2             THE N3 BIT SO THAT                  F2E16790
       ARS     15                   IT CAN BE EASILY TESTED.            F2E16800
       ANA     L(1)                                                     F2E16810
       STO     N3IND                                                    F2E16820
       TRA     1,4                  RETURN                              F2E16830
       REM TETG DETERMINES FOR WHICH DOS A GIVEN TAG IS A TEST.  THIS   F2E16840
       REM INFORMATION IS RECORDED IN TAG4.                             F2E16850
TETG   CLA     TAG3                 ISOLATE                             F2E16860
       ANA     ADMSK                TAG NAME.                           F2E16870
       STO     ER40                                                     F2E16880
       CLA     TAG4                 ISOLATE DUPES INDICATORS            F2E16890
       ARS     9                                                        F2E16900
       ANA     L(7)                 IF THERE ARE DUPES                  F2E16910
       STO     ER41                 THIS INSURES THAT TEST BITS         F2E16920
       SUB     L(1)                 ARE ENTERED ONLY FOR                F2E16930
       ANS     ER41                 RIGHTMOST DUPE.                     F2E16940
       LXA     $L(3),1                                                  F2E16950
       CLA     TAG2+3,1             SELECT DOTAG WHICH                  F2E16960
       TZE     TETG5                CONTROLS THIS                       F2E16970
       PDX     0,2                  SUBSCRIPT.                          F2E16980
       CLA     DOTAGZ+8,2                                               F2E16990
       ANA     TETMSK               ISOLATE TEST NAME                   F2E17000
       ARS     18                   OF THIS SUBSCRIPT.                  F2E17010
       SUB     ER40                 DOES TEST NAME EQUAL TAG NAME.      F2E17020
       TNZ     TETG5                NO, GO TO NEXT SUBSCRIPT.           F2E17030
       LDQ     ER41                 TEST NAME EQUALS TAG NAME,          F2E17040
       LLS     36,1                 SEE IF THIS SUBSCRIPT               F2E17050
       LBT                          IS A LEFT DUPE.                     F2E17060
       TRA     TETG3                NOT A LEFT DUPE, ENTER TEST BIT.    F2E17070
       TRA     TETG5                LEFT DUPE, IGNORE.                  F2E17080
TETG3  CLA     BIT1                 ENTER TEST BIT                      F2E17090
       ARS     10,1                 FOR THIS                            F2E17100
       ORS     TAG4                 SUBSCRIPT.                          F2E17110
TETG5  TIX     TETG+10,1,1          DEAL WITH NEXT SUBSCRIPT.           F2E17120
       TRA     1,4                                                      F2E17130
       REM *************************************************************F2E17140
       REM PRES DETERMINES THE TXI BLOCK NJMBER FOR A GIVEN TAG AND PUTSF2E17150
       REM IT IN INDEX REGISTER B.                                      F2E17160
PRES   CLA     TAG4                 FIRST THE TEST                      F2E17170
       LRS     26                   BITS ARE ISOLATED                   F2E17180
       ALS     33                   AND STORED.                         F2E17190
       STO     ER40                 TEST BITS 1,2.                      F2E17200
       LLS     5                    THEN THE GROUP NO.                  F2E17210
       ALS     20                   IS LEFT                             F2E17220
       ORA     TAG4                 IN THE MQ WHILE THE                 F2E17230
       ARS     21                   CARRY BITS ARE ORED                 F2E17240
       ANA     L(5)                 AND STORED.                         F2E17250
       STO     ER41                 CARRY BITS 101.                     F2E17260
       LLS     5                    THE GROUP NO. IS THEN               F2E17270
       ORA     POSIND               SHIFTED TO BE COMBINED              F2E17280
       LDQ     ER40                 WITH THE POS. THE TEST              F2E17290
       LLS     1                    BITS ARE SEPARATED SO THAT          F2E17300
       ALS     1                    THEY CAN OR PROPERLY WITH           F2E17310
       LLS     2                    CARRY BITS LT, LC, CT, CC.          F2E17320
       ORA     ER41                 THIS RESULTS IN THE MASK            F2E17330
       STO     ARG                  USED FOR TABLE SEARCH.              F2E17340
       SXD     ER40,4                                                   F2E17350
       LXA     L(1),1               THIS BLOCK REPRESENTS               F2E17360
       TXI     PRES10,1,38          SETS OF CALLING SEQUENCES TO        F2E17370
PRES10 SXD     S3,1                 SEARCH ROUTINE. MASK IS             F2E17380
       TXI     PRES20,1,9           STORED AND BLOCK TEST               F2E17390
PRES20 CLA     SMSK1                INDEX DECREMENT IS STORED.          F2E17400
       STO     SMSK                 FIRST 11 ENTRIES ARE                F2E17410
       TSX     SEARCH,4             SEARCHED. THEN 12,12,4.             F2E17420
       CLA     SMSK2                RETURN TO ROUTINE                   F2E17430
       STO     SMSK                 AFTER SEARCHING LAST                F2E17440
       TIX     PRES30,1,12          BLOCK INDICATES AN ERROR.           F2E17450
PRES30 SXD     S3,1                                                     F2E17460
       TXI     PRES40,1,12                                              F2E17470
PRES40 TSX     SEARCH,4                                                 F2E17480
       CLA     SMSK4                                                    F2E17490
       STO     SMSK                                                     F2E17500
       TIX     PRES50,1,20                                              F2E17510
PRES50 SXD     S3,1                                                     F2E17520
       TXI     PRES60,1,20                                              F2E17530
PRES60 TSX     SEARCH,4                                                 F2E17540
       CLA     SMSK3                                                    F2E17550
       STO     SMSK                                                     F2E17560
       TIX     PRES70,1,6                                               F2E17570
PRES70 SXD     S3,1                                                     F2E17580
       TXI     PRES80,1,6                                               F2E17590
PRES80 TSX     SEARCH,4                                                 F2E17600
       TSX     ERRORM,4             ERROR RETURN FROM SEARCH.           F2E17610
       REM                          IF LAST BLOCK OF RX TABLE           F2E17620
       REM                          IS SEARCHED AND NO  XR1 RX          F2E17630
       REM                          WORD (MODIFIED BY SEARCH,           F2E17640
       REM                          STORED IN WRKRXT) IS FOUND          F2E17650
       REM                          TO MATCH ARG(ALSO MODIFIED          F2E17660
       REM                          BY SMSK), THIS RETURN IS            F2E17670
       REM                          TAKEN.                              F2E17680
       REM *************************************************************F2E17690
       REM SEARCH IS CALLED BY PRES TO COMPARE CONSTANTS IN THE RX TABLEF2E17700
       REM AGAINST VARIOUS PERMUTATIONS OF AN ARGUMENT WORD.  A MATCHINGF2E17710
       REM COMPARISON MEANS THE CONSTANT WILL YIELD THE CORRECT BLOCK NUF2E17720
       REM NUMBER.                                                      F2E17730
SEARCH CLA     RXTA+48,1                                                F2E17740
       ARS     3                    THIS ROUTINE TAKES                  F2E17750
       STO     WRKRXT               THE ARGUMENT MASK, EDITS            F2E17760
       CLA     ARG                  IT AND THEN SEARCHES                F2E17770
       ANA     SMSK                 PRESCRIBED BLOCKS OF                F2E17780
       SUB     WRKRXT               THE RX TABLE.                       F2E17790
       TZE     S8                   SUCCESSFUL SEARCH.                  F2E17800
       TIX     S3,1,1               INDEX FOR NEXT ENTRY.               F2E17810
S3     TXH     SEARCH,1,0           TEST FOR END OF BLOCK.              F2E17820
       TRA     1,4                                                      F2E17830
S8     CLA     RXTA+48,1            TABLE ENTRY CONTAINS                F2E17840
       ANA     L(7)                 BLOCK NOS. 0-5 WHICH                F2E17850
       PAX     0,2                  CORRESPOND TO BLOCKS                F2E17860
       LXD     ER40,4               A-F.                                F2E17870
       TRA     1,4                                                      F2E17880
RXTA   OCT     6600                 6L, 760 MASK                        F2E17890
       OCT     6400                 6C                                  F2E17900
       OCT     6200                 6R                                  F2E17910
       OCT     5600                 5L                                  F2E17920
       OCT     4600                 4L                                  F2E17930
       OCT     4200                 4R                                  F2E17940
       OCT     3400                 3C                                  F2E17950
       OCT     2400                 2C                                  F2E17960
       OCT     1600                 1L                                  F2E17970
       OCT     5501                 5C, 774 MASK                        F2E17980
       OCT     5400                 5C                                  F2E17990
       OCT     5302                 5R                                  F2E18000
       OCT     5200                 5R                                  F2E18010
       OCT     4541                 4C                                  F2E18020
       OCT     4501                 4C                                  F2E18030
       OCT     4445                 4C                                  F2E18040
       OCT     4400                 4C                                  F2E18050
       OCT     1541                 1C                                  F2E18060
       OCT     1501                 1C                                  F2E18070
       OCT     1445                 1C                                  F2E18080
       OCT     1400                 1C                                  F2E18090
       OCT     1215                 1R, 773 MASK                        F2E18100
       OCT     1200                 1R                                  F2E18110
       OCT     2723                 2L                                  F2E18120
       OCT     2733                 2L                                  F2E18130
       OCT     2623                 2L                                  F2E18140
       OCT     2633                 2L                                  F2E18150
       OCT     3324                 3R                                  F2E18160
       OCT     3302                 3R                                  F2E18170
       OCT     3223                 3R                                  F2E18180
       OCT     3200                 3R                                  F2E18190
       OCT     3723                 3L,BL. A, LEFT + CENTER TEST.       F2E18200
       OCT     3700                 3L, BL. A, LEFT TEST.               F2E18210
       OCT     3623                 3L, BL. D, CENTER TEST.             F2E18220
       OCT     3600                 3L, BL. A, NO TEST.                 F2E18230
       OCT     1334                 1R                                  F2E18240
       OCT     1324                 1R                                  F2E18250
       OCT     1315                 1R                                  F2E18260
       OCT     1302                 1R                                  F2E18270
       OCT     1233                 1R                                  F2E18280
       OCT     1223                 1R                                  F2E18290
       OCT     2600                 2L, 763 MASK                        F2E18300
       OCT     2610                 2L                                  F2E18310
       OCT     2233                 2R                                  F2E18320
       OCT     2223                 2R                                  F2E18330
       OCT     2215                 2R                                  F2E18340
       OCT     2200                 2R                                  F2E18350
       REM *************************************************************F2E18360
       REM CN3IJ COMPUTES THE INDEX INCREMENTING VALUE FOR EACH PASS THRF2E18370
       REM THROUGH A DO LOOP.  THIS IS THE NORMAL TXI DECREMENT.        F2E18380
CN3IJ  LDQ     DOTAGZ+4,2           COMPUTES DECREMENT AND              F2E18390
       LLS     18                   LEAVES IT IN ACCUMULATOR.           F2E18400
       TXH     CN3IJ5,1,2           IF POSIND=3, S1 POS.                F2E18410
       MPY     $WRKSC+6             D1N3 FOR S2 OR S3.                  F2E18420
       LRS     18                                                       F2E18430
       TXH     CN3IJ5,1,1           POSIND=2 S2 POS.                    F2E18440
       MPY     $WRKSC+7             D2D1N3 FOR S3.                      F2E18450
       LRS     18                                                       F2E18460
CN3IJ5 PXD     0,1                  PLACE TWICE                         F2E18470
       ALS     1                    POSIND IN                           F2E18480
       PDX     0,1                  INDEX REGISTER.                     F2E18490
       MPY     $WRKSC+6,1           CN3D1D2 OR CN3D1 OR CN3.            F2E18500
       ARS     1                                                        F2E18510
       TRA     1,4                  RESULT IS N3G.                      F2E18520
       REM *************************************************************F2E18530
       REM CIL023 FILLS OUT THE LOCATION, ADDRESS, AND TAG NAME WORDS FOF2E18540
       REM FOR NON-LOCATION COMPILED INSTRUCTIONS ADDRESSING THE FOLLOWIF2E18550
       REM ING INSTRUCTIONS                                             F2E18560
CIL023 CLA     L(0)                 ROUTINE PLACES SPECIAL              F2E18570
       STO     CIL00                                                    F2E18580
       CLA     $L1DEC               SYMBOL FOR ADDRESS.                 F2E18590
       STO     CIL03                                                    F2E18600
       CLA     BCD15                AND INITIALIZES LOC. WORD           F2E18610
       STO     CIL02                AND PLACES TAG IN                   F2E18620
       CLA     TAG3                 TAG WD. THIS IS DOEN                F2E18630
       STA     CIL03                FOR INST. OF K DECREMENT.           F2E18640
       TRA     1,4                                                      F2E18650
       REM *************************************************************F2E18660
       REM TGA MAKES AN ENTRY IN APPENDED TAGTAG SHOWING THE LOCATION OFF2E18670
       REM A GIVEN VARIABLE DECREMENT TXI OR TIX.  FOR REFERENCE BY THE F2E18680
       REM ALPHA STATE WHEN COMPILING CECREMENT INITIALIZATION          F2E18690
       REM INSTRUCTIONS.                                                F2E18700
TGA    ALS     18                   FOR RX LOC.                         F2E18710
TGAT   ARS     3                    FOR TX LOC, DIV VCTOR BY 8.         F2E18720
       STO     ERTGA                                                    F2E18730
       LXA     POSIND,1                                                 F2E18740
       CLA     XTG                  CALCULATES X LOC OF TTGA.           F2E18750
       ARS     2                    INDEX QUANTITY FOR TTGA IS          F2E18760
       PDX     0,2                  ONE FOURTH THAT FOR TTG.            F2E18770
       CLA     ERTGA                                                    F2E18780
TGA5   TIX     TGA10,1,1            SHIFT LEFT FOR S1 OR S2             F2E18790
TGA8   ORS     MXTGA,2              ADDRESS IS ORIGIN PLUS MAX          F2E18800
       TRA     1,4                  ADD TG WD. LINKAGE TRANSFER.        F2E18810
TGA10  ALS     6                                                        F2E18820
       TRA     TGA5                                                     F2E18830
       REM *************************************************************F2E18840
       REM EDCB COMPILES TXI-SXD-TIX INSTRUCTIONS AND STORES THE SXD LOCF2E18850
       REM ATION FOR BLOCKS B,C,D, OR E WHEN THE DECREMENTS ARE CONSTANTF2E18860
       REM AND KNOWN.                                                   F2E18870
EDCB   SXD     EDCB5,4              COMPILES TXI SXD TIX                F2E18880
       CLA     L(TXI)               INSTRUCTIONS WHEN                   F2E18890
       STO     CIL01                DECREMENTS ARE KNOWN.               F2E18900
       CLA     ERTX01               ASSUMES DECREMENTS TO               F2E18910
       STA     CIL01                BE IN ERTX01 AND                    F2E18920
       TSX     CIL023,4             ERTX02.                             F2E18930
       TSX     CIT,4                COMPILE TXI INSTRUCITON.            F2E18940
       TSX     CSXD,4               COMPILE SXD SKELETON.               F2E18950
       CLA     CIL00                                                    F2E18960
       ANA     ADMSK                                                    F2E18970
       ALS     12                   BELOW, PLACE SXD LOC. INTO          F2E18980
       LXD     BLKNUM,4             DOTAG WORD 7. APPROPRIATE           F2E18990
       TXH     EDCB10,4,2           BITS DEPEND ON BLOCK NOS.           F2E19000
       LXD     TAG2,2               BLOCKS D, E SHIFT LEFT 12.          F2E19010
       TXH     EDCB5,4,1            BLOCKS C, B USE S1 DOTAG.           F2E19020
       ALS     6                    BLOCK C, SHIFT LEFT 12.             F2E19030
EDCB5  TXL     EDCB20,,0            BLOCK B, SHIFT LEFT 18.             F2E19040
EDCB10 LXD     TAG2+1,2             BLOCK D,E      USE S2 DOTAG.        F2E19050
EDCB20 ORS     DOTAGZ+6,2           PLACE LOC. INTO WD 7.               F2E19060
       CLA     L(TIX)               COMPILE                             F2E19070
       STO     CIL01                TIX.                                F2E19080
       CLA     ERTX02               COMPILE                             F2E19090
       STA     CIL01                TIX DECREMENT.                      F2E19100
       TSX     CIL023,4                                                 F2E19110
       TSX     CIT,4                                                    F2E19120
       LXD     EDCB5,4                                                  F2E19130
       TRA     1,4                                                      F2E19140
       REM *************************************************************F2E19150
       REM BCDE COMPILES TXI-SXD-TIX INSTRUCTIONS AND MAKES PROPER TABLEF2E19160
       REM ENTRIES IN DOTAG AND TGA WHEN BLOCK B,C,D, OR E IS VARIABLE. F2E19170
BCDE   SXD     BCDE2,4                                                  F2E19180
       TSX     CILV,4               OBTAIN LOC. FOR FIRST INST.         F2E19190
       CLA     CIL00                MAKE LOCATION ENTRY INTO            F2E19200
       ANA     ADMSK                APPENDED TAG WORD.                  F2E19210
       TSX     TGA,4                                                    F2E19220
       CLA     L(TXI)               PLACE OPERATION IN                  F2E19230
       STO     CIL01                COMPILED INSTRUCTIN.                F2E19240
       TSX     CIL23,4              FILL OUT REMAINING WORDS.           F2E19250
       TSX     CIT,4                                                    F2E19260
       TSX     CSXD,4                                                   F2E19270
       LXD     BLKNUM,2                                                 F2E19280
       TXL     BCDE5,2,2            TEST FOR BLOCKS B OR C.             F2E19290
       CLA     CIL00                BLOCK D OR E.                       F2E19300
       LXD     TAG2+1,1             PLACE LOC. OF SXD INST.             F2E19310
       ANA     ADMSK                INTO DOTAG ENTRY FOR                F2E19320
       ALS     12                   CENTER SUBSCRIPT.                   F2E19330
       ORS     DOTAGZ+6,1                                               F2E19340
BCDE2  TXL     BCDE9,,0             BLOCKS D,E CONTINUE                 F2E19350
BCDE5  CLA     CIL00                BLOCK B OR C .                      F2E19360
       LXD     TAG2,1               PLACE LOC. FOR SXD OF               F2E19370
       ANA     ADMSK                REMAINING TWO BLOCKS.               F2E19380
       ALS     12                   DISTINGUISH BETWEEN BLOCK B, C.     F2E19390
       TXH     BCDE8,2,1                                                F2E19400
       ALS     6                                                        F2E19410
BCDE8  ORS     DOTAGZ+6,1                                               F2E19420
BCDE9  PXD     0,2                  BLOCK NUMBER MUST BE                F2E19430
       ALS     14                   STORED IN PROPER POS.               F2E19440
       LXA     POSIND,1             OF TAG 4 WORD.                      F2E19450
       TXL     BCDE10-1,1,1                                             F2E19460
       TXL     BCDE10,1,2           IF POSITION IS LEFT,                F2E19470
       CAL     BIT8                 PLACE A ONE IN BIT 7 OF TAG4        F2E19480
       TRA     BCDE10               TO INDICATE BLOCK D SPECIAL.        F2E19490
       ARS     3                                                        F2E19500
BCDE10 LXD     XTG,2                                                    F2E19510
       ORS     TAGZ+3,2                                                 F2E19520
       TSX     CILV,4               OBTAIN LOC. FOR THIRD               F2E19530
       CLA     L(TIX)               INST. AND OPERATION PART            F2E19540
       STO     CIL01                FOR 2ND WORD.                       F2E19550
       TSX     CIL23,4              FILL OUT REMAINING WORDS.           F2E19560
       TSX     CIT,4                                                    F2E19570
       LXD     BCDE2,4                                                  F2E19580
       TRA     1,4                                                      F2E19590
       REM *************************************************************F2E19600
       REM NBITS ISOLATES THE VARIABLE PARAMETER BITS FOR A GIVEN DOTAG.F2E19610
NBITS  CLA     DOTAGZ,2             ROUTINE FOR ISOLATING               F2E19620
       ARS     15                   THE N BITS OF A DO.                 F2E19630
       ANA     L(7)                                                     F2E19640
       STO     N1N2N3                                                   F2E19650
       TRA     1,4                                                      F2E19660
       REM *************************************************************F2E19670
       REM CIL23 FILLS OUT THE ADDRESS AND TAG NAME WORDS FOR A COMPILEDF2E19680
       REM INSTRUCTION WHEN THE ADDRESS IS TO BE THE NEXT SEQUENTIAL INSF2E19690
       REM TRUCTION AND THE LOCATION WORD IS FILLED ELSEWHERE.          F2E19700
CIL23  CLA     BCD15                THIS ROUTINE PLACES TAG IN          F2E19710
       STO     CIL02                TAG WD. OF CIL03 AND 1              F2E19720
       CLA     TAG3                 IN DECREMENT FOR THE                F2E19730
       ANA     ADMSK                RELATIVE PART,                      F2E19740
       ORA     $L1DEC               PLACES THE LOCATION IN              F2E19750
       STO     CIL03                THE ADDRESS WORD CIL02 .            F2E19760
       TRA     1,4                                                      F2E19770
       REM *************************************************************F2E19780
       REM CILNAM ENTERS ONLY THE TAG NAME.                             F2E19790
CILNAM CLA     TAG3                 THIS ROUTINE                        F2E19800
       ANA     ADMSK                ENTERS THE                          F2E19810
       STO     CIL03                TAG NAME                            F2E19820
       TRA     1,4                  IN CIL.                             F2E19830
       REM *************************************************************F2E19840
       REM CDORO TAKES COEF. AND DIM. AND FILLS OUT ORO.                F2E19850
CDORO  SXD     CDORO1,4                                                 F2E19860
       LXD     AX,2                                                     F2E19870
       MSE     100                                                      F2E19880
CDORO1 TXH     CDORO1+1,,0          WHICH SUB IS IT.                    F2E19890
       TXL     CDORO3,2,2           S2 OR S3, TRA.                      F2E19900
       CLA     $WRKSC               S1,                                 F2E19910
       SUB     $L1DEC               IS C1 MORE THAN 1.                  F2E19920
       TZE     1,4                  C1=1, RETURN.                       F2E19930
       PSE     100                  C1 NOT = 1, TURN ON                 F2E19940
       CLA     $WRKSC               SENSE LIGHT, ISOLATE C1.            F2E19950
       TRA     CDORO7+1                                                 F2E19960
CDORO3 LDQ     $WRKSC+6             ISOLATE D1.                         F2E19970
       TXL     CDORO5,2,1           WHICH SUB IS IT.                    F2E19980
       MPY     $WRKSC+2             S2, FORM C2D1.                      F2E19990
       TRA     CDORO7                                                   F2E20000
CDORO5 MPY     $WRKSC+4             S3, FORM                            F2E20010
       LRS     18                   C3D1D2.                             F2E20020
       MPY     $WRKSC+7                                                 F2E20030
CDORO7 ALS     17                   ASSIGN SYMBOL                       F2E20040
       TSX     $FXCON,4             FOR G AND PUT                       F2E20050
       STO     ORO00+19             IN ORO + 19.                        F2E20060
       LXD     CDORO1,4             RESTORE LINKAGE,                    F2E20070
       LXD     AX,2                 PUT AX POSITION IN                  F2E20080
       TRA     1,4                  I.R. B AND RETURN.                  F2E20090
       REM *************************************************************F2E20100
       REM AORO, BORO, CORO, DORO, AND EORO ARE CALLED TO MAKE APPROPRIAF2E20110
       REM COMPILING TABLE (ORO) ENTRIES AND TO CALLL ROUTINES TO MAKE  F2E20120
       REM COMPUTATIONS AND COMPILE INSTRUCTIONS TO INTIALIZE VARIABLE DF2E20130
       REM DECREMENTS FOR BLOCKS A, B, C, D, AND E RESPECTIVELY.        F2E20140
AORO   SXD     AORO5,4                                                  F2E20150
       CLA     TAG2+3,1             LOCATION IS                         F2E20160
       PDX     0,2                  SPECIFIED IN ORO +14                F2E20170
       CLA     DOTAGZ,2             BY COMBINING TETLOC                 F2E20180
       ANA     ADMSK                WITH PROPER BETA.                   F2E20190
       ALS     18                                                       F2E20200
       ORA     TETLOC                                                   F2E20210
       STO     ORO00+14                                                 F2E20220
       CLA     DOTAGZ+4,2                                               F2E20230
       STO     ORO00                                                    F2E20240
       LXD     AX,1                                                     F2E20250
       TXL     AORO10,1,2           S2 OR S3.                           F2E20260
       CLA     $WRKSC               S1, IS                              F2E20270
       SUB     $L1DEC               C1=1.                               F2E20280
       TZE     AORO30               YES                                 F2E20290
       ADD     $L1DEC               NO, ASSIGN                          F2E20300
       TSX     $FXCON,4             SYMBOL FOR C1.                      F2E20310
       STO     ORO00+19                                                 F2E20320
AORO5  TXL     AORO40,,0                                                F2E20330
AORO10 TXL     AORO20,1,1           IS SUB S2.                          F2E20340
       LDQ     $WRKSC+2             YES, FOR C2D1.                      F2E20350
       MPY     $WRKSC+6             IF S2 IS A                          F2E20360
       ALS     17                   DUPE, ADD C1.                       F2E20370
       STO     ERAORO                                                   F2E20380
       LDQ     TAG4                                                     F2E20390
       LLS     25                                                       F2E20400
       LBT                                                              F2E20410
       TRA     AORO14               NO DUPES.                           F2E20420
       CLA     $WRKSC                                                   F2E20430
       ADD     ERAORO                                                   F2E20440
       STO     ERAORO                                                   F2E20450
AORO14 CLA     ERAORO               CONTAINS C2D1, ETC.                 F2E20460
       TSX     $FXCON,4             ASSIGN SYMBOL FOR                   F2E20470
       STO     ORO00+19             G AND PUT IN ORO+19                 F2E20480
       TRA     AORO40                                                   F2E20490
AORO20 LDQ     $WRKSC+4             S3, FORM                            F2E20500
       MPY     $WRKSC+6             C3D1D2.                             F2E20510
       LRS     18                                                       F2E20520
       MPY     $WRKSC+7                                                 F2E20530
       ALS     17                                                       F2E20540
       STO     ERAORO                                                   F2E20550
       LDQ     TAG4                 CHECK DUPES                         F2E20560
       LLS     26                   AND MAKE G                          F2E20570
       LBT                          ADJUSTMENTS                         F2E20580
       TRA     AORO24               ACCORDINGLY.                        F2E20590
       ARS     1                                                        F2E20600
       LBT                                                              F2E20610
       TRA     AORO22                                                   F2E20620
       LDQ     $WRKSC+2                                                 F2E20630
       MPY     $WRKSC+6                                                 F2E20640
       ALS     17                                                       F2E20650
       ADD     ERAORO                                                   F2E20660
       STO     ERAORO                                                   F2E20670
AORO22 CLA     TAG4                                                     F2E20680
       ARS     11                                                       F2E20690
       LBT                                                              F2E20700
       TRA     AORO24                                                   F2E20710
       CLA     $WRKSC                                                   F2E20720
       ADD     ERAORO                                                   F2E20730
       STO     ERAORO                                                   F2E20740
AORO24 CLA     ERAORO                                                   F2E20750
       TSX     $FXCON,4             ASSIGN SYMBOL FOR                   F2E20760
       STO     ORO00+19             G FOR S3.                           F2E20770
       TRA     AORO40                                                   F2E20780
AORO30 LXA     L(2),1               SUB IS S1, C1=1.                    F2E20790
       CLA     K2AORO               COMPILE CLA, STD.                   F2E20800
       TSX     LXC,4                                                    F2E20810
       TRA     AORO50                                                   F2E20820
AORO40 LXA     L(4),1               COMPILE LDQ,MPY, STD.               F2E20830
       CLA     K1AORO                                                   F2E20840
       TSX     LXC,4                                                    F2E20850
AORO50 LXD     AORO5,4              RESTORE LINKAGE.                    F2E20860
       TRA     1,4                                                      F2E20870
       REM *************************************************************F2E20880
BORO   SXD     $LINKC,4             FOR B BLOCK                         F2E20890
       LDQ     $WRKSC+2             COMPUTE G AS                        F2E20900
       MPY     $WRKSC+6             C2D1. PLACE                         F2E20910
       ALS     17                   THIS AND C1                         F2E20920
       STO     ORO00+19             IN ORO.                             F2E20930
       CLA     $WRKSC                                                   F2E20940
       STO     ORO00+20                                                 F2E20950
       LXA     L(2),1               INITIALIZE N3X                      F2E20960
       SXD     N3X,1                POS. TO S2.                         F2E20970
       LXA     $L(3),1              INITIALIZE XX                       F2E20980
       SXD     XX,1                 POS. TO S1.                         F2E20990
       TSX     PC,4                                                     F2E21000
       LXD     $LINKC,4                                                 F2E21010
       TRA     1,4                                                      F2E21020
       REM *************************************************************F2E21030
CORO   SXD     CORO05,4                                                 F2E21040
       LDQ     $WRKSC+6             FORM C3D1D2 AND                     F2E21050
       MPY     $WRKSC+7             STORE IN                            F2E21060
       LRS     18                   ORO+19                              F2E21070
       MPY     $WRKSC+4             FOR USE BY                          F2E21080
       ALS     17                   PC IN COMPUTING                     F2E21090
       STO     ORO00+19             BLOCK C DECREMENTS.                 F2E21100
       CLA     TAG4                 TEST                                F2E21110
       ARS     9                    FOR                                 F2E21120
       LBT                          DUPES.                              F2E21130
CORO05 TXL     CORO10,,0            NO DUPES.                           F2E21140
       LDQ     $WRKSC+6             IF DUPES, FORM                      F2E21150
       MPY     $WRKSC+2             C2D1, ADD TO                        F2E21160
       ALS     17                   ORO+19 , AND STORE                  F2E21170
       ADD     ORO00+19             IN ORO+19 FOR                       F2E21180
       STO     ORO00+19             USE BY PC.                          F2E21190
CORO10 CLA     $WRKSC               STORE C1 IN                        *F2E21200
       STO     ORO00+20             ORO+20 FOR PC.                      F2E21210
       LXA     L(1),1               SET N3X POSITION                   *F2E21220
       SXD     N3X,1                TO S3,                              F2E21230
       LXA     $L(3),1              XX POSITION TO S1.                  F2E21240
       SXD     XX,1                 AND CALL PC TO COMPUTE              F2E21250
       TSX     PC,4                 AND COMPILE BLKC INIT.              F2E21260
       LXD     CORO05,4             RESTORE LINKAGE AND                 F2E21270
       TRA     1,4                  RETURN TO MAIN ROUTINE.             F2E21280
       REM *************************************************************F2E21290
DORO   SXD     DORO5,4              BLOCK D NORMAL.                     F2E21300
       LDQ     $WRKSC+4             COMPUTES C3D1D2, G1                 F2E21310
       MPY     $WRKSC+6             AND C2D1, G2 IF DUPE.               F2E21320
       LRS     18                   EXIST IN THE CASE                   F2E21330
       MPY     $WRKSC+7             110 C1 ADDED TO G2.                 F2E21340
       ALS     17                   IN THE CASE 101                     F2E21350
       STO     ORO00+19             C1 ADDED TO G1.                     F2E21360
       LDQ     $WRKSC+2                                                 F2E21370
       MPY     $WRKSC+6                                                 F2E21380
       ALS     17                                                       F2E21390
       STO     ORO00+20                                                 F2E21400
       LXD     XTG,4                                                    F2E21410
       CLA     TAGZ+3,4             DOES CARRY EXIST                    F2E21420
       ANA     CRMSK                FOR TWO INNER DOS.                  F2E21430
       TZE     *+2                  NO.                                 F2E21440
       SXD     CTEST,4              YES, SET INDICATOR.                 F2E21450
       CLA     TAG4                                                     F2E21460
       ARS     9                                                        F2E21470
       ANA     L(7)                                                     F2E21480
       TZE     DORO20                                                   F2E21490
       LBT                                                              F2E21500
DORO5  TXL     DORO10,,0                                                F2E21510
       CLA     $WRKSC                                                   F2E21520
       ADD     ORO00+19                                                 F2E21530
       STO     ORO00+19                                                 F2E21540
       TRA     DORO20                                                   F2E21550
DORO10 CLA     $WRKSC                                                   F2E21560
       ADD     ORO00+20                                                 F2E21570
       STO     ORO00+20                                                 F2E21580
DORO20 LXA     L(1),1               SET N3X POS. TO S3,                 F2E21590
       SXD     N3X,1                                                    F2E21600
       LXA     L(2),1               XX POS. TO S2.                      F2E21610
       SXD     XX,1                                                     F2E21620
       TSX     PC,4                 MAKE COMPUTATIONS AND COMPILE       F2E21630
       STZ     CTEST                RESET CARRY INDICATOR.              F2E21640
       LXD     DORO5,4              INSTRUCTIONS TO INIT. VAR.          F2E21650
       TRA     1,4                  BLOCK D DECREMENTS.                 F2E21660
CRMSK  OCT     140000000                                                F2E21670
CTEST  PZE                                                              F2E21680
       REM *************************************************************F2E21690
EORO   SXD     ERTN,4                                                   F2E21700
       TSX     DORO,4                                                   F2E21710
       SXD     EFLAG,4                                                  F2E21720
       TSX     CORO,4                                                   F2E21730
       CLA     ORO00+15                                                 F2E21740
       ADD     L(8)                                                     F2E21750
       STO     ORO00+14                                                 F2E21760
       ADD     L(16)                                                    F2E21770
       STO     ORO00+15                                                 F2E21780
       LXA     L(2),1                                                   F2E21790
       CLA     LXCEIP                                                   F2E21800
       TSX     LXC,4                                                    F2E21810
       LXD     ERTN,4                                                   F2E21820
       STZ     EFLAG                                                    F2E21830
       LXD     ERTN,4                                                   F2E21840
       TRA     1,4                                                      F2E21850
EFLAG  PZE                                                              F2E21860
ERTN   PZE                                                              F2E21870
       REM *************************************************************F2E21880
       REM PC IS A SUBROUTINE CALLED BY AORO, BORO, ETC. TO MAKE COMPUTAF2E21890
       REM TIONS  AND TO CALL COMPILING ROUTINES FOR TXI DECREMENT INTIAF2E21900
       REM LIZATION.                                                    F2E21910
PC     SXD     PC04,4                                                   F2E21920
       LXD     N3X,1                                                    F2E21930
       CLA     TAG2+3,1                                                 F2E21940
       PDX     0,2                                                      F2E21950
       CLA     DOTAGZ,2                                                 F2E21960
       ANA     ADMSK                FORM LOCATION                       F2E21970
       ALS     18                   WORDS AND PUT                       F2E21980
       ORA     TETLOC               IN ORO+14                           F2E21990
       STO     ORO00+14             AND ORO+15.                         F2E22000
       ADD     L(16)                                                    F2E22010
       STO     ORO00+15                                                 F2E22020
       CLA     DOTAGZ,2             IS N3 FOR THIS DO                   F2E22030
       ARS     15                   VARIABLE.                           F2E22040
       LBT                                                              F2E22050
PC04   TXL     PC10,,0              NO, PC10.                           F2E22060
       CLA     DOTAGZ+4,2           YES,                                F2E22070
       STO     ORO00                COMPILE                             F2E22080
       CLA     ORO00+19             LDQ L(G), (N3X POS.),               F2E22090
       TSX     $FXCON,4             MPY N3, (N3X POS.),                 F2E22100
       STO     ORO00+19             ALS 17,                             F2E22110
       LXA     L(4),1               STO C(ORO+12)                       F2E22120
       CLA     K1BORO                                                   F2E22130
       TSX     LXC,4                                                    F2E22140
       TRA     PC20                                                     F2E22150
PC10   LDQ     DOTAGZ+4,2           N3 CONSTANT, PUT                    F2E22160
       MPY     ORO00+19             N3G SYMBOL IN                       F2E22170
       LLS     35                   ORO+19                              F2E22180
       TSX     $FXCON,4                                                 F2E22190
       STO     ORO00+19                                                 F2E22200
PC20   LXD     XX,1                 ISOLATE N3 FOR                      F2E22210
PCI    CLA     TAG2+3,1             XX POSITION                         F2E22220
       PDX     0,2                                                      F2E22230
       CLA     DOTAGZ+4,2           DOES N3 = 1.                        F2E22240
       SUB     L(1)                                                     F2E22250
       TNZ     PCI33-3        NO, GO TO PATCH                          $F2E22260
       CLA     DOTAGZ+5,2           YES, IS X CONST.                    F2E22270
       ANA     BIT2                                                     F2E22280
       TZE     PC21                 YES, PC21.                          F2E22290
       TXL     PCI31,1,2            NO, IS POS. S2.                    *F2E22300
       CLA     DOTAGZ+2,2           NO, IS N1 = 1.                      F2E22310
       SUB     L(1)                                                     F2E22320
       TNZ     PCI22                NO, PCI22.                          F2E22330
       CLA     DOTAGZ+3,2           YES, DOES C1 = 1.                   F2E22340
       STO     ORO00+1                                                  F2E22350
       CLA     $WRKSC                                                   F2E22360
       SUB     $L1DEC                                                   F2E22370
       TNZ     PCI21                NO, PCI21.                          F2E22380
       LXA     L(1),1               YES, COMPILE                        F2E22390
       CLA     KLX02                CLA N1,                             F2E22400
       TSX     LXC,4                SUBL(1), AND                        F2E22410
       TRA     PCI33                                                    F2E22420
PCI21  CLA     $WRKSC                                                   F2E22430
       TSX     $FXCON,4             COMPILE                             F2E22440
       STO     ORO00+9              LDQ L(N2)                           F2E22450
       CLA     KLAR3                MPY L(C1)                           F2E22460
       LXA     L(4),1               ALS 17                              F2E22470
       TSX     LXC,4                STO 1) +3.                          F2E22480
       TRA     PC60                                                     F2E22490
PCI22  TSX     OP3,4                COMPILE CLA L(N2-N1)                F2E22500
       CLA     $WRKSC                                                   F2E22510
       SUB     $L1DEC               IS C1=1.                            F2E22520
       TZE     PC60                                                     F2E22530
       CLA     $WRKSC               NO, OBTAIN                          F2E22540
       TSX     $FXCON,4             SYMBOL FOR                          F2E22550
       STO     ORO00+9              C1 AND                              F2E22560
PCI22R LXA     L(1),1               COMPILE                            *F2E22570
       CLA     KLX01I               STO 1)+3                           *F2E22580
       TSX     LXC,4                                                   *F2E22590
       CLA     ORO00+26                                                *F2E22600
       STO     ORO00+1              COMPILE                            *F2E22610
       LXA     L(3),1               LDQ 1)+3,                          *F2E22620
       CLA     KLAR3                MPY ORO00+9,                       *F2E22630
       TSX     LXC,4                ALS 17.                            *F2E22640
       NZT     CTEST                TEST CARRY BETWEEN INNER DOS.      *F2E22650
       TRA     PC60                 NO CARRY.                          *F2E22660
       CLA     $WRKSC               CARRY, COMPILE                     *F2E22670
       TSX     $FXCON,4             SUB L(C1).                         *F2E22680
       STO     ORO00+1                                                 *F2E22690
       LXA     L(1),1                                                  *F2E22700
       CLA     LXCI1                                                   *F2E22710
       TSX     LXC,4                                                   *F2E22720
       TRA     PC60                                                    *F2E22730
PCI31  CLA     ORO00+20             COMPILE                            *F2E22740
       TSX     $FXCON,4             CLA (N2-N1) OR                     *F2E22750
       STO     ORO00+9              CLA N2,                            *F2E22760
       TSX     OP3,4                SUB N1.                            *F2E22770
       NZT     CTEST                TEST CARRY BETWEEN INNER DOS.      *F2E22780
       TRA     PCI22R               NO CARRY.                          *F2E22790
       CLA     ORO00+13             CARRY,                             *F2E22800
       STO     ORO00+27             COMPILE                            *F2E22810
       LXA     L(1),1               ADD L(1).                          *F2E22820
       CLA     KTX05                                                   *F2E22830
       TSX     LXC,4                                                   *F2E22840
       TRA     PCI22R                                                  *F2E22850
       AXT     3,1            PATCH                                    $F2E22860
       TRA     PC21           PATCH--RETURN TO PC21.                   $F2E22870
       PZE                          NOT USED.                          *F2E22880
PCI33  LXA     L(1),1                                                   F2E22890
       CLA     LXCI61                                                   F2E22900
       TSX     LXC,4                                                    F2E22910
       TRA     PC60                                                     F2E22920
  PC21 TSX     PXORO+2,4      IS X CONSTANT.                           $F2E22930
       TRA     PC22                 NO, PC22.                           F2E22940
       TRA     PC30                                                     F2E22950
PC22   LXD     XX,2                                                     F2E22960
       LXA     L(8),1                                                   F2E22970
       CLA     ORO00+20                                                 F2E22980
       TXL     PC23,2,2                                                 F2E22990
       CLA     $WRKSC                                                   F2E23000
       SUB     L1DEC                                                    F2E23010
       TZE     PC24                                                     F2E23020
       ADD     L1DEC                                                    F2E23030
PC23   TSX     $FXCON,4                                                 F2E23040
       STO     ORO00+9                                                  F2E23050
       LDQ     ORO00+26                                                 F2E23060
       CLA     KLAR1                                                    F2E23070
       TXI     PC25,1,4                                                 F2E23080
PC24   LDQ     ORO00+3                                                  F2E23090
       CLA     KLAR2                                                    F2E23100
PC25   STQ     MYORO                                                    F2E23110
       TSX     LXC,4                                                    F2E23120
       TRA     PC60                                                     F2E23130
PC30   NZT     CTEST                TEST FOR CARRY BTWN INNER DOS.      F2E23140
       TRA     PC31                 NO.                                 F2E23150
       LRS     35                   YES, USE                            F2E23160
       MPY     ORO00+20             XN3G                                F2E23170
       ALS     17                   MINUS                               F2E23180
       SUB     $WRKSC               C1 AS DECREMENT.                    F2E23190
       TRA     PC32                                                     F2E23200
PC31   LRS     18                                                       F2E23210
       SUB     DOTAGZ+4,2                                               F2E23220
       LRS     17                                                       F2E23230
       MPY     ORO00+20                                                 F2E23240
       ALS     17                                                       F2E23250
PC32   TSX     $FXCON,4                                                 F2E23260
       STO     ORO00+20                                                 F2E23270
       LXA     L(1),1                                                   F2E23280
       CLA     XK                                                       F2E23290
       TSX     LXC,4                                                    F2E23300
PC60   CLA     EFLAG                                                    F2E23310
       TNZ     PC62+1                                                   F2E23320
       LXD     N3X,1                                                    F2E23330
       CLA     TAG2+3,1             IS                                  F2E23340
       PDX     0,2                  N3                                  F2E23350
       LXA     $L(3),1              OF                                  F2E23360
       CLA     DOTAGZ,2             CURRENT                             F2E23370
       ARS     15                   DO                                  F2E23380
       LBT                          VARIABLE.                           F2E23390
       TRA     PC61                 CONSTANT, PC61.                     F2E23400
       CLA     LXCI8                VARIABLE, COMPILE                   F2E23410
PC62   TSX     LXC,4                STD, ADD N3G, STD.                  F2E23420
       LXD     PC04,4                                                   F2E23430
       TRA     1,4                                                      F2E23440
PC61   CLA     LXCI8P               CONSTANT. COMPILE                   F2E23450
       TRA     PC62                 STD, ADD C(ORO+12), STD.            F2E23460
       REM *************************************************************F2E23470
       REM CIL03I FILLS OUT LOCATION AND TAG NAME WORDS FOR COMPILED INSF2E23480
       REM TRUCTIONS WITHOUT LOCATIONS.                                 F2E23490
CIL03I CLA     L(0)                 PLACE 0 IN LOCATION                 F2E23500
       STO     CIL00                WORD AND TAG IN                     F2E23510
       CLA     TAG3                 TAG WORD OF COMPILED                F2E23520
       ANA     ADMSK                INSTRUCGIN.                         F2E23530
       STO     CIL03                                                    F2E23540
       TRA     1,4                                                      F2E23550
       REM *************************************************************F2E23560
       REM BITP CHECKS SUBSCRIPTS FOR DEFINITION.  IF DEFINED BY RELCON F2E23570
       REM OR DOSUB IT OBTAINS OBJECT PROGRAM SYMBOLS FOR N1 OR S1 RESPEF2E23580
       REM CTIVELY.                                                     F2E23590
BITP   STA     BITP14                                                   F2E23600
       STA     BITP02               INITIALIZE SHIFTS,                  F2E23610
       STA     BITP04               STORE LINKAGE                       F2E23620
       PAX     0,2                  AND PLACE 0,1,2 IN                  F2E23630
       ALS     1                    XB FOR S3, S2, AND                  F2E23640
       PAX     0,1                  S1 RESPECTIVELY.                    F2E23650
       CLA     RELCO                IS THIS A                           F2E23660
BITP02 ARS     **                   RELCON.                             F2E23670
       LBT                          X                                   F2E23680
       TRA     BITP03               NOT RELCON.                         F2E23690
       TRA     BITP30               RELCON.                             F2E23700
BITP03 CLA     DEFDO                IS THIS DEFINED                     F2E23710
BITP04 ARS     **                   BY A DO.                            F2E23720
       LBT                          X                                   F2E23730
       TRA     1,4                  NO, UNDEFINED.                      F2E23740
       CLA     TAG2+2,2             ISOLATE DO                          F2E23750
       PDX     0,2                  INDEX.                              F2E23760
       CLA     N1SBX                IS DO DEFINITION                    F2E23770
BITP14 ARS     **                   CONSTANT.                           F2E23780
       LBT                          X                                   F2E23790
       TRA     1,4                  DO DEFINITION IS CONSTANT.          F2E23800
       CLA     DOTAGZ+2,2           ISOLATE N1 OF DEFINING              F2E23810
       TRA     2,4                  DO.                                 F2E23820
BITP30 CLA     $WRKSC+5,1           RELCON, ISOLATE                     F2E23830
       TRA     2,4                  SUBSCRIPT.                          F2E23840
       REM *************************************************************F2E23850
       REM TESTLO OBTAINS THE TEST LOCATION TO BE THE SYMBOLIC ADDRESS OF2E23860
       REM OF THE STD INITIALIZING INSTRUCTION.                         F2E23870
TESTLO CLA     TAG2+3,2             INITIALIZE INDEX                    F2E23880
       PDX     0,2                  FOR TEST DOTAG.                     F2E23890
       CLA     L(0)                 ISOLATE                             F2E23900
       LDQ     DOTAGZ+6,2           SXD                                 F2E23910
       RQL     3                    LOCATION                            F2E23920
       LGL     6                    AND PUT                             F2E23930
       ALS     3                    IN TETLOC                           F2E23940
       STO     TETLOC               ADDRESS                             F2E23950
       CLA     DOTAGZ,2             PUT TXL                             F2E23960
       ANA     ADMSK                LOCATION                            F2E23970
       ALS     18                   IN TETLOC                           F2E23980
       ORS     TETLOC               DECREMENT.                          F2E23990
       TRA     1,4                                                      F2E24000
       REM *************************************************************F2E24010
       REM PREFACE TO ORO EXAMINES VARIABLIITY OF X QUANTITY.           F2E24020
PXORO  CLA     TAG2+3,1             IF X IS                             F2E24030
       PDX     0,2                  CONSTANT IT IS                      F2E24040
       CLA     DOTAGZ+5,2           LEFT IN THE                         F2E24050
       ANA     BIT2                 DECREMENT OF                        F2E24060
       TNZ     XORO                 ACC.                                F2E24070
       CLA     DOTAGZ+5,2                                               F2E24080
       ANA     ADMSK                                                    F2E24090
       ALS     18                                                       F2E24100
       TRA     2,4                                                      F2E24110
       REM *************************************************************F2E24120
       REM XORO FILLS OUT ORO FOR N1, N2, N3, GIVEN DO IN B AND POS IN AF2E24130
XORO   SXD     XORO32,4                                                 F2E24140
       CLA     DOTAGZ,2                                                 F2E24150
       ARS     15                                                       F2E24160
       ANA     L(7)                                                     F2E24170
       STO     N1N2N3                                                   F2E24180
       CLA     L(ORO)               ORIGIN OF ORO TABLE.                F2E24190
       ADD     L(4)                 CALCULATES ADDRESS                  F2E24200
       TXH     XORO10,1,2           FOR STORING INTO                    F2E24210
       ADD     L(3)                 ORO TABLE.                          F2E24220
XORO10 TXH     XORO20,1,1                                               F2E24230
       ADD     L(17)                                                    F2E24240
XORO20 STA     XORO36               STORE ADRS FOR NS.                  F2E24250
       LXA     L(3),1                                                   F2E24260
XORO30 LDQ     N1N2N3                                                   F2E24270
       RQL     36,1                                                     F2E24280
       CLA     DOTAGZ+2,2                                               F2E24290
       TQP     XORO34               N IS CONSTANT.                      F2E24300
XORO32 TXL     XORO36,,0            N IS VARIABLE.                      F2E24310
XORO34 ALS     18                                                       F2E24320
       TSX     $FXCON,4                                                 F2E24330
XORO36 STO     0,1                                                      F2E24340
       TIX     XORO40,2,1                                               F2E24350
XORO40 TIX     XORO30,1,1                                               F2E24360
       STO     ORO00                                                    F2E24370
       LXD     XORO32,4                                                 F2E24380
       TRA     1,4                                                      F2E24390
       REM *************************************************************F2E24400
       REM THIS ROUTINE EXAMINES A BLOCK OF CONSTANTS AND COMPILES ONE IF2E24410
       REM INSTRUCTION FOR EACH.  THE CALLER INDICATES THE FIRST CONSTANF2E24420
       REM BY A REFERENCE IN THE ACCUMULATOR, AND INDICATES THE NUMBER OF2E24430
       REM OF INSTRUCTIONS IN INDEX REGISTER A.                         F2E24440
LXC    SXD     LXC19,4                                                  F2E24450
       STO     ERLXC                                                    F2E24460
       PXD     0,1                                                      F2E24470
       ARS     18                                                       F2E24480
       ADD     ERLXC                                                    F2E24490
       STA     LXC10                                                    F2E24500
       CLA     LOCIND               TEST TO SEE IF                      F2E24510
       TZE     LXC08                THIS IS THE FIRST                   F2E24520
       SUB     L(1)                 LXD COMPILED. IF SO,                F2E24530
       STO     LOCIND               PLACE A IN                          F2E24540
       LXD     DOIND,2              DECREMENT                           F2E24550
       CLA     DOTAGZ,2             OF LOCATION WORD                    F2E24560
       ANA     DECMSK               FOR FIRST COMPILED                  F2E24570
       STO     CIL00                INSTRUCTION.                        F2E24580
       TRA     LXC10                                                    F2E24590
LXC08  CLA     L(0)                                                     F2E24600
       STO     CIL00                                                    F2E24610
LXC10  LDQ     0,1                  SKELETAL INSTRUCTION.               F2E24620
       LLS     0                                                        F2E24630
       LGL     18                                                       F2E24640
       STQ     CIL01                COMPILE OP. WORD.                   F2E24650
       TMI     LXC20                                                    F2E24660
       STA     LXC15                SYMBOL.ADDR. TYPE INSTRUCTION.      F2E24670
LXC15  CLA     **                                                       F2E24680
       STO     CIL02                SYMBOLIC ADDRESS.                   F2E24690
       CLA     L(0)                 RELATIVE                            F2E24700
       STO     CIL03                ADDRESS.                            F2E24710
       CAL     CIL02                TEST CIL02                          F2E24720
       ANA     6ONES                WORD.                               F2E24730
       TZE     LXC30                FIRST CHARACTER IS ZERO.            F2E24740
       ANA     BIT01                                                    F2E24750
       TNZ     LXC30                FIRST CHARACTER ALPHABETIC.         F2E24760
       CAL     CIL02                FIRST CHARACTER NUMBERIC,           F2E24770
       ALS     18                   PLACE REIGHT HALF OF CIL02          F2E24780
       STD     CIL03                IN CIL03, LEFT HALF                 F2E24790
       CAL     6ONES                IN CIL02.                           F2E24800
       ANS     CIL02                                                    F2E24810
LXC19  TXL     LXC30,,0             SHIFT TYPE INSTRUCTION,             F2E24820
LXC20  ALS     18                                                       F2E24830
       ANA     DECMSK                                                   F2E24840
       STO     CIL03                                                    F2E24850
       CLA     L(0)                                                     F2E24860
       STO     CIL02                                                    F2E24870
LXC30  TSX     CIT,4                                                    F2E24880
       TIX     LXC08,1,1            COUNT COMPILED INSTR. IN BLK.       F2E24890
       LXD     LXC19,4                                                  F2E24900
       TRA     1,4                                                      F2E24910
       REM *************************************************************F2E24920
KLX01          LXI00                                                    F2E24930
KLX01I         LXI00+1                                                  F2E24940
KLX02I         LXI05                                                    F2E24950
KLX02          LXI02                                                    F2E24960
KLX03          LXI16                                                    F2E24970
KLX05          LXI30                                                    F2E24980
KLX03I         LXI10                                                    F2E24990
KLX05I         LXI24                                                    F2E25000
K1AORO         A1C00                                                    F2E25010
KIAORO         A1C01                                                    F2E25020
K2AORO         A1000                                                    F2E25030
K3AORO         A1001                                                    F2E25040
KTX00          TXC00                                                    F2E25050
               TXC08                                                    F2E25060
               TXC18                                                    F2E25070
KTX04          TXC30                                                    F2E25080
KTX05          TXC31                                                    F2E25090
LTX040         TX040                                                    F2E25100
LTX042         TX042                                                    F2E25110
LXCI           XCI                                                      F2E25120
LXCI6          XCI6                                                     F2E25130
LXCIE          XCIE                                                     F2E25140
LXCIE1         XCIE+1                                                   F2E25150
LXCIEP         XCIEP                                                    F2E25160
LXCEIP         XCEIP                                                    F2E25170
XK             XKI                                                      F2E25180
K1BORO         L(BIC)                                                   F2E25190
LX2CI          X2CI                                                     F2E25200
LXCI61         XCI6+1                                                   F2E25210
LXCI8          XCI8                                                     F2E25220
LXCI1          XCI+1                                                    F2E25230
LXI00          14545,2,ORO00+13     CLA                                 F2E25240
               11494,6,ORO00+26     STO                                 F2E25250
LXI02          14545,2,ORO00+1      CLA                                 F2E25260
               11494,6,ORO00+26     STO                                 F2E25270
LXI05          13608,4,ORO00+1      LDQ                                 F2E25280
               18936,4,ORO00+9      MPY                                 F2E25290
       TNX     6386,2,17            ALS 17                              F2E25300
               11494,6,ORO00+26     STO                                 F2E25310
LXI10          13608,4,ORO00+4      LDQ                                 F2E25320
               18936,4,ORO00+7      MPY                                 F2E25330
       TNX     6386,2,17            ALS 17                              F2E25340
               11538,6,ORO00+7      SUB                                 F2E25350
               5396,2,ORO00+26      ADD                                 F2E25360
               11494,6,ORO00+26     STO                                 F2E25370
LXI16          13608,4,ORO00+4      LDQ                                 F2E25380
               18936,4,ORO00+10     MPY                                 F2E25390
       TNX     14962,4,18           LRS                                 F2E25400
               18936,4,ORO00+7      MPY                                 F2E25410
       TNX     6386,2,17            ALS                                 F2E25420
               11538,6,ORO00+7      SUB                                 F2E25430
               5396,2,ORO00+26      ADD                                 F2E25440
               11494,6,ORO00+26     STO                                 F2E25450
LXI24          13608,4,ORO00+21     LDQ                                 F2E25460
               18936,4,ORO00+24     MPY                                 F2E25470
       TNX     6386,2,17            ALS                                 F2E25480
               11538,6,ORO00+24     SUB                                 F2E25490
               5396,2,ORO00+26      ADD                                 F2E25500
               11494,6,ORO00+26     STO                                 F2E25510
LXI30          13608,4,ORO00+21     LDQ                                 F2E25520
               18936,4,ORO00+11     MPY                                 F2E25530
       TNX     14962,4,18           LRS                                 F2E25540
               18936,4,ORO00+24     MPY                                 F2E25550
       TNX     6386,2,17            ALS                                 F2E25560
               11538,6,ORO00+24     SUB                                 F2E25570
               5396,2,ORO00+26      ADD                                 F2E25580
               11494,6,ORO00+26     STO                                 F2E25590
L(BIC)         13608,4,ORO00+19     LDQ                                 F2E25600
               18936,4,ORO00        MPY                                 F2E25610
       TNX     6386,2,17            ALS                                 F2E25620
               11494,6,ORO00+12     STO                                 F2E25630
XCI            14545,2,ORO00+2      CLA                                 F2E25640
               11538,6,ORO00+1      SUB                                 F2E25650
               5396,2,ORO00+3       ADD                                 F2E25660
       TNX     14962,4,35           LRS                                 F2E25670
               19815,2,ORO00+3      DVP                                 F2E25680
               18936,4,ORO00+3      MPY                                 F2E25690
       TNX     14962,4,18           LRS                                 F2E25700
               18936,4,ORO00+9      MPY                                 F2E25710
XCI6   TNX     14578,4,35           LLS                                 F2E25720
               11538,6,ORO00+13     SUB                                 F2E25730
XCI8           11476,6,ORO00+15     STD                                 F2E25740
               5396,2,ORO00+12      ADD                                 F2E25750
               11476,6,ORO00+14     STD                                 F2E25760
A1C00          13608,4,ORO00        LDQ                                 F2E25770
A1C01          18936,4,ORO00+19     MPY                                 F2E25780
       TNX     6386,2,17            ALS                                 F2E25790
               11476,6,ORO00+14     STD                                 F2E25800
A1000          14545,2,ORO00        CLA                                 F2E25810
A1001          11476,6,ORO00+14     STD                                 F2E25820
TXC00          14545,2,ORO00+2      CLA                                 F2E25830
               11538,6,ORO00+1      SUB                                 F2E25840
               5396,2,ORO00+3       ADD                                 F2E25850
       TNX     14962,4,35           LRS                                 F2E25860
               19815,2,ORO00+3      DVP                                 F2E25870
               18936,4,ORO00+3      MPY                                 F2E25880
TXC08          14545,2,ORO00+5      CLA                                 F2E25890
               11538,6,ORO00+4      SUB                                 F2E25900
               5396,2,ORO00+6       ADD                                 F2E25910
       TNX     14962,4,35           LRS                                 F2E25920
               19815,2,ORO00+6      DVP                                 F2E25930
               18936,4,ORO00+6      MPY                                 F2E25940
TXC18          14545,2,ORO00+22     CLA                                 F2E25950
               11538,6,ORO00+21     SUB                                 F2E25960
               5396,2,ORO00+23      ADD                                 F2E25970
       TNX     14962,4,35           LRS                                 F2E25980
               19815,2,ORO00+23     DVP                                 F2E25990
               18936,4,ORO00+23     MPY                                 F2E26000
       TNX     14962,4,18           LRS                                 F2E26010
               18936,4,ORO00+7      MPY                                 F2E26020
       TNX     14962,4,18           LRS                                 F2E26030
               18936,4,ORO00+8      MPY                                 F2E26040
       TNX     14962,4,18           LRS                                 F2E26050
               18936,4,ORO00+11     MPY                                 F2E26060
TXC30  TNX     14578,4,35           LLS                                 F2E26070
TXC31          5396,2,ORO00+27      ADD                                 F2E26080
               11538,6,ORO00+13     SUB                                 F2E26090
TX040  TNX     14962,4,18           LRS                                 F2E26100
               18936,4,ORO00+19     MPY                                 F2E26110
TX042  TNX     14578,4,35           LLS                                 F2E26120
               11476,6,ORO00+14     STD                                 F2E26130
X2CI           14545,2,ORO00+5      CLA                                 F2E26140
               11538,6,ORO00+4      SUB                                 F2E26150
               5396,2,ORO00+6       ADD                                 F2E26160
       TNX     14962,4,35           LRS                                 F2E26170
               19815,2,ORO00+6      DVP                                 F2E26180
               18936,4,ORO00+6      MPY                                 F2E26190
       TNX     14962,4,18           LRS                                 F2E26200
               18936,4,ORO00+20     MPY                                 F2E26210
       TNX     14578,4,35           LLS                                 F2E26220
               11538,6,ORO00+13     SUB                                 F2E26230
XKI            14545,2,ORO00+20     CLA                                 F2E26240
XCIE   TNX     14578,4,35           LLS                                 F2E26250
               11538,6,ORO00+13     SUB                                 F2E26260
               11476,6,ORO00+15     STD                                 F2E26270
               11476,6,ORO00+14     STD                                 F2E26280
XCI8P          11476,6,ORO00+15     STD                                 F2E26290
               5396,2,ORO00+19      ADD                                 F2E26300
               11476,6,ORO00+14     STD                                 F2E26310
LXCI8P         XCI8P                                                    F2E26320
XCIEP          14545,2,ORO00+20     CLA                                 F2E26330
XCEIP          11476,6,ORO00+15     STD                                 F2E26340
               11476,6,ORO00+14     STD                                 F2E26350
KLAR1  PZE     KIII1                                                    F2E26360
KLAR2  PZE     KIII2                                                    F2E26370
KLAR3  PZE     KIII3                                                    F2E26380
KIII1          13608,4,ORO00+3      LDQ  (N3)                           F2E26390
               18936,4,ORO00+9      MPY  (C1)                           F2E26400
       TNX     6386,2,17            ALS  17                             F2E26410
               11494,6,ORO00+26     STO  1)+3                           F2E26420
KIII2          14545,2,ORO00+2      CLA  N2                             F2E26430
               11538,6,ORO00+1      SUB  N1                             F2E26440
               5396,2,ORO00+3       ADD  N3                             F2E26450
       TNX     14962,4,35           LRS  35                             F2E26460
               19815,2,ORO00+3      DVP  (N3)                           F2E26470
               18936,4,MYORO        MPY  (N3) OR 1)+3                   F2E26480
       TNX     14578,4,35           LLS  35                             F2E26490
               11538,6,MYORO        SUB  (N3) OR 1)+3                   F2E26500
KIII3          13608,4,ORO00+1      LDQ  (N2)                           F2E26510
               18936,4,ORO00+9      MPY  (C1)                           F2E26520
       TNX     6386,2,17            ALS  17                             F2E26530
               11538,6,ORO00+9      SUB  (C1)                           F2E26540
MYORO  PZE                                                              F2E26550
DSC6   IORT    DOTAG,,200*M/N*9+1                                       F2E26560
       REM *************************************************************F2E26570
TAG1   PZE                                                              F2E26580
TAG2   PZE                                                              F2E26590
TAG21  PZE                                                              F2E26600
TAG22  PZE                                                              F2E26610
TAG3   PZE                                                              F2E26620
TAG4   PZE                                                              F2E26630
DOTGRC PZE                                                              F2E26640
       PZE                                                              F2E26650
       REM *************************************************************F2E26660
EROP3                                                                   F2E26670
EROP   OCT     100                                                      F2E26680
       REM *************************************************************F2E26690
L(TXI) BCI     1,TXI000                                                 F2E26700
L(PXD) BCI     1,PXD000                                                 F2E26710
L(SXD) BCI     1,SXD000                                                 F2E26720
L(TIX) BCI     1,TIX000                                                 F2E26730
L(TXL) BCI     1,TXL000                                                 F2E26740
L(DED) BCI     1,DED000                                                 F2E26750
L(LXD) BCI     1,LXD000                                                 F2E26760
L(STD) BCI     1,STD000                                                 F2E26770
L(ADD) BCI     1,ADD000                                                 F2E26780
L(SUB) BCI     1,SUB000                                                 F2E26790
L(BSS) BCI     1,BSS000                                                 F2E26800
LMXDTG         200*M/N*9                                                F2E26810
MAXLOC OCT     400                                                      F2E26820
L1DEC  OCT     1000000                                                  F2E26830
DRADS1 OCT     2664                                                     F2E26840
DRADS2         204                                                      F2E26850
DRADS3         2                                                        F2E26860
AD202          202                                                      F2E26870
L(17)          17                                                       F2E26880
L(ORO)         ORO00                                                    F2E26890
ESTORE HTR     0                                                        F2E26900
NOPRET OCT     077777077777                                             F2E26910
L3DEC  OCT     000003000000                                             F2E26920
L(7)           7                                                        F2E26930
BCD15  OCT     170000000000                                             F2E26940
BCD0   OCT     060000000002                                             F2E26950
BCD2   OCT     020000000000                                             F2E26960
BIT01  OCT     600000000000                                             F2E26970
T1MSK  OCT     700000077777                                             F2E26980
6ONES  OCT     770000000000                                             F2E26990
TETMSK OCT     007777000000                                             F2E27000
L(6)           6                                                        F2E27010
L(8)           8                                                        F2E27020
L(K1)  OCT     10                                                       F2E27030
INST20         ADTGA                                                    F2E27040
INST22         MXTGA                                                    F2E27050
INST24         RTX160                                                   F2E27060
INST26         RTX184                                                   F2E27070
INST30         RTX264                                                   F2E27080
INST32         RTX226                                                   F2E27090
LMXTG          1000*M/N*4,,1000*M/N*4                                   F2E27100
LMXTGA         1000*M/N                                                 F2E27110
ALLONE OCT     377777777777                                             F2E27120
LZEKMX         400*M/N                                                  F2E27130
LADMX          1600*M/N                                                 F2E27140
L(1)           1                                                        F2E27150
L(2)           2                                                        F2E27160
L(4)           4                                                        F2E27170
L(3)           3                                                        F2E27180
L(5)           5                                                        F2E27190
L(0)           0                                                        F2E27200
L(16)          16                                                       F2E27210
BIT1   PTW     0                                                        F2E27220
BIT2   PON     0                                                        F2E27230
BIT8   OCT     002000000000                                             F2E27240
ADMSK  OCT     77777                                                    F2E27250
SMSK                                                                    F2E27260
SMSK1  OCT     760                                                      F2E27270
SMSK2  OCT     774                                                      F2E27280
SMSK3  OCT     763                                                      F2E27290
SMSK4  OCT     773                                                      F2E27300
BITMSK OCT     20                                                       F2E27310
       OCT     10                                                       F2E27320
OPMSK  OCT     74030                                                    F2E27330
11BITS OCT     3777                                                     F2E27340
BIT20  OCT     100000                                                   F2E27350
INST2  LXA     L(4),1                                                   F2E27360
INST3  LXA     L(2),1                                                   F2E27370
INST4  TRA     AC224                                                    F2E27380
INST5  TRA     AC228                                                    F2E27390
INST8          AC244                                                    F2E27400
INST10         ADTGA                                                    F2E27410
INST11         AC010                                                    F2E27420
INST12         MXTGA                                                    F2E27430
INST13 TRA     AC155                                                    F2E27440
INST14 TSX     CIL03I,4                                                 F2E27450
6ONESR OCT     77                                                       F2E27460
6TO17  OCT     007777000000                                             F2E27470
24TO35 OCT     7777                                                     F2E27480
BBOX   PZE                                                              F2E27490
CIL00  PZE                                                              F2E27500
CIL01  PZE                                                              F2E27510
CIL02  PZE                                                              F2E27520
CIL03  PZE                                                              F2E27530
ERTGA  PZE                                                              F2E27540
TETTG  PZE                                                              F2E27550
SWICH2 PZE                                                              F2E27560
ERLXC  PZE                                                              F2E27570
AX     PZE                                                              F2E27580
RELCO  PZE                                                              F2E27590
WRKTGA PZE                                                              F2E27600
N3X    PZE                                                              F2E27610
XX     PZE                                                              F2E27620
ADTGX  PZE                                                              F2E27630
WRKRXT PZE                                                              F2E27640
TETTGX PZE                                                              F2E27650
RTXTGX PZE                                                              F2E27660
LOCIND PZE                                                              F2E27670
ERORBX PZE                                                              F2E27680
A      PZE                                                              F2E27690
B      PZE                                                              F2E27700
SWICH  PZE                                                              F2E27710
TEBBOX PZE                                                              F2E27720
DOIND  PZE                                                              F2E27730
DOIND1 PZE                                                              F2E27740
TEABOX PZE                                                              F2E27750
SWICH1 PZE                                                              F2E27760
N3IND  PZE                                                              F2E27770
N1N2N3 PZE                                                              F2E27780
XTG    PZE                                                              F2E27790
POSIND PZE                                                              F2E27800
ER40   PZE                                                              F2E27810
ER41   PZE                                                              F2E27820
ARG    PZE                                                              F2E27830
VCTR   PZE                                                              F2E27840
ERTX01 PZE                                                              F2E27850
ERTX02 PZE                                                              F2E27860
ERTX03 PZE                                                              F2E27870
BLKNUM PZE                                                              F2E27880
SXDTXZ PZE                                                              F2E27890
OREDO  PZE                                                              F2E27900
DEFDO  PZE                                                              F2E27910
N1SBX  PZE                                                              F2E27920
TETLOC PZE                                                              F2E27930
       REM     PATCH TO RTX200 ROUTINE TO ALLOW DECR. MAX. OF 32767 (26)F2E27931
RTX205 CLA     ERTX01                                               (26)F2E27932
       ANA     ADDMSK                                               (26)F2E27933
       TRA     RTX204                                               (26)F2E27934
ENDB   SYN     *+27                                                 (26)F2E27940
       REM *************************************************************F2E27950
ERAORO SYN     ERTX01                                                   F2E27960
ERDRM  SYN     ERTX02                                                   F2E27970
ERAB   SYN     ERTGA                                                    F2E27980
ORO00  SYN     $OR000                                                   F2E27990
ORO13  SYN     ORO00+13                                                 F2E28000
ORO18  SYN     ORO00+18                                                 F2E28010
ADTGMX SYN     ADTAG+400*M/N*4                                          F2E28020
       END     -1                                                      $F2E28030
« March 2024 »
Su Mo Tu We Th Fr Sa
1 2
3 4 5 6 7 8 9
10 11 12 13 14 15 16
17 18 19 20 21 22 23
24 25 26 27 28 29 30
31
 

Powered by Plone CMS, the Open Source Content Management System

This site conforms to the following standards: