*PREFIXED PROLOG TO NORMAL NOTATION - CLAUSE ORDER IS NOT CHANGED .
*
*AUTOR: FELIKS KLUZNIAK.
*
.

+PARENTH -FIND(#) -FIND(#) -IMPAS.
+PARENTH -PAR -LIGNE.
+FIND(*X) -LUB(*X) -/.
+FIND(*X) -FIND(*X).
+PAR -FIND(.) -CLAUSE(.,*NEXT) -NOMORE(*NEXT).
+PAR -PAR.
+NOMORE(#) -/(-(PAR)) -LIGNE.
* CLAUSE'S NEXT IS FIRST NON-BLANK AFTER LAST NIL0  .
+CLAUSE(.,*NEXT) -LU(2)
   -/ -LU(*X) -LITER(*X) -LU(*N) -CLAUSE(*N,*NEXT).
+CLAUSE(N,*NEXT) -LU(I)-LU(L)-LU(0)-ECRIT(.) -LIGNE -LUB(*NEXT) -/.
+CLAUSE(*A,*B) -SORM("ERROR FOUND BY CLAUSE ")
   -SORT(*A) -SORM(" & ") -SORT(*B) -STOP.
+LITER(-) -/ -LIT(-).
+LITER(+) -/ -LIT(+).
+LITER(*X) -SORM("ERROR FOUND BY LITERAL ") -ECRIT(*X) -STOP.
+LIT(*C) -ECRIT(*C) -LU(1) -/ -LU(*F) -PRED(*F).
+LIT(*C) -SORM("BAD N-ARITY OF ") -ECRIT(*C) -STOP.
* PRED IS GIVEN FIRST CHAR,STOPS ON LAST ARG'S LAST.
+PRED(*F) -CHIFFRE(*F) -/ -SORM("*") -ECRIT(*F).
+PRED(*F) -NAME(*F,*N) -ARGS(*N).
* NAME'S SECOND ARG IS N-ARITY .
+NAME(*C,*C) -CHIFFRE(*C) -/.
+NAME(*C,*N) -ECRIT(*C) -LU(*CH) -NAME(*CH,*N).
+ARGS(0) -/.
+ARGS(*N) -SORM("(") -ARG(*N) -SORM(")").
+ARG(*N) -LU(*C) -PRED(*C) -COMMA(*N).
+ARG(*N) -MOINS(*N,1,*M) -ARG(*M).
+COMMA(1) -/(-(ARG(*N))).
+COMMA(*N) -SORM(",") -IMPAS.
* END OF PARANT.


-PARENTH!